Skip to contentSkip to conversation

Migrate GUPnP to meta-multimedia

PATCH Superseded Ross Burton 3 participants 11 messages Dec 20, 2012 – Dec 21, 2012

v1 of 2 Superseded Latest is v2 →

lore
Share & tools
lore
#0 lore raw

The GUPnP stack isn't used by anything in oe-core, and fits in better in meta-multimedia.

Migrate all of the recipes, add some missing ones, and upgrade as much as possible.

Ross

#1 lore raw

PATCH 1/6 gssdp: add 0.12.2.1 and 0.13.2

---
 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc   |   16 ++++++++++++++++
 .../recipes-connectivity/gupnp/gssdp_0.12.2.1.bb       |    5 +++++
 .../recipes-connectivity/gupnp/gssdp_0.13.2.bb         |    8 ++++++++
 3 files changed, 29 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
meta-multimedia/recipes-connectivity/gupnp/gssdp.inc new file +16 -0
new file mode 100644
index 0000000..51befd9
@@ -0,0 +1,16 @@
+SUMMARY = "Resource discovery and announcement over SSDP"
+DESCRIPTION = "GSSDP implements resource discovery and announcement over SSDP (Simpe Service Discovery Protocol)."
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7"
+DEPENDS = "glib-2.0 libsoup-2.4 gobject-introspection-stub vala-stub-native"
+
+inherit autotools pkgconfig
+
+PACKAGES =+ "gssdp-tools"
+
+FILES_gssdp-tools = "${bindir}/gssdp* ${datadir}/gssdp/*.glade"
+
+EXTRA_OECONF = "--disable-introspection"
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)}"
+PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk,gtk+"
meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb new file +5 -0
new file mode 100644
index 0000000..29cc721
@@ -0,0 +1,5 @@
+require gssdp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.12/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "8ac3a544ef0dcf8caaf7c249d2a50dc2"
+SRC_URI[sha256sum] = "928aa257815d044fdbfc740f5799530d41897947b5d7854173f636b36d728414"
meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb new file +8 -0
new file mode 100644
index 0000000..c308fa0
@@ -0,0 +1,8 @@
+require gssdp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.13/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "758ed423cdd258a9a22d59c321b535ed"
+SRC_URI[sha256sum] = "8f663f8a72b66254f5c20a3610ff853ac8d00bf6f253828e37e51579caa34dce"
+
+# This is a development release so don't prefer it
+DEFAULT_PREFERENCE = "-1"
Signature · 1 line
1.7.10
#2 lore raw

Re: [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2

Quoted 16 lines · Ross Burton
---
 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc   |   16 ++++++++++++++++
 .../recipes-connectivity/gupnp/gssdp_0.12.2.1.bb       |    5 +++++
 .../recipes-connectivity/gupnp/gssdp_0.13.2.bb         |    8 ++++++++
 3 files changed, 29 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
meta-multimedia/recipes-connectivity/gupnp/gssdp.inc new file +0 -0
new file mode 100644
index 0000000..51befd9

meta-multimedia/recipes-connectivity/gupnp/gssdp.inc line 5

Quoted 5 lines
meta-multimedia/recipes-connectivity/gupnp/gssdp.inc new file +5 -0
@@ -0,0 +1,16 @@
+SUMMARY = "Resource discovery and announcement over SSDP"
+DESCRIPTION = "GSSDP implements resource discovery and announcement over SSDP (Simpe Service Discovery Protocol)."
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7"
+DEPENDS = "glib-2.0 libsoup-2.4 gobject-introspection-stub vala-stub-native"

vala-stub-native does not exist afaik, why not use vala-native?

Quoted 44 lines
meta-multimedia/recipes-connectivity/gupnp/gssdp.inc new file +11 -0
+
+inherit autotools pkgconfig
+
+PACKAGES =+ "gssdp-tools"
+
+FILES_gssdp-tools = "${bindir}/gssdp* ${datadir}/gssdp/*.glade"
+
+EXTRA_OECONF = "--disable-introspection"
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)}"
+PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk,gtk+"
meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb new file +5 -0
new file mode 100644
index 0000000..29cc721
@@ -0,0 +1,5 @@
+require gssdp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.12/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "8ac3a544ef0dcf8caaf7c249d2a50dc2"
+SRC_URI[sha256sum] = "928aa257815d044fdbfc740f5799530d41897947b5d7854173f636b36d728414"
meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb new file +8 -0
new file mode 100644
index 0000000..c308fa0
@@ -0,0 +1,8 @@
+require gssdp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.13/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "758ed423cdd258a9a22d59c321b535ed"
+SRC_URI[sha256sum] = "8f663f8a72b66254f5c20a3610ff853ac8d00bf6f253828e37e51579caa34dce"
+
+# This is a development release so don't prefer it
+DEFAULT_PREFERENCE = "-1"
Signature · 7 lines
1.7.10


_______________________________________________
Openembedded-devel mailing list
[email protected]
http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel
Signature · 1 line
Martin 'JaMa' Jansa     jabber: [email protected]
#3 lore raw

Re: [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2

Quoted 1 line · Martin Jansa

vala-stub-native does not exist afaik, why not use vala-native?

Whoops, that patch didn't go anywhere did it.

commit 2471e89fe8b535c9fb4a1e15cb910d7d14b463b3

Author: Ross Burton <[email protected]>
Date:   Thu Dec 20 12:40:17 2012 +0000

vala-stub: add a stub for vala-native

Some packages have optional support for Vala but require vala.m4 to provide VALA_PROG_VAPIGEN so that autoreconf works.

vala-stub provides a dummy VALA_PROG_VAPIGEN which doesn't do
anything, so the
configure script runs and believes that vala isn't present.

(pending for oe-core)

For software that's written in C but has optional Vala bindings you need Vala to configure even if you're going to turn it off. A stub macro that lets configure run is all you need if you don't want to build all of Vala (for example because you don't want to pull all of meta-oe into your project).

I meant to change that to vala-native once I'd added the provides to vala-stub, V2 shortly.

Ross

#4 lore raw

Re: [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2

Quoted 2 lines · Ross
Quoted 1 line · Martin Jansa

vala-stub-native does not exist afaik, why not use vala-native?

V2 sent, Vala is a pointless dependency for the GUPnP stack as it requires gobject-introspection first, so we'll be building vala just to get an autoconf macro that is never used.

Avoid the vala-stub debate now by simply commenting out that macro for now.

Ross

#5 lore raw

Re: [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2

In reply to Ross Burton

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Op 20-12-12 13:52, Ross Burton schreef:

Quoted 21 lines

meta-multimedia/recipes-connectivity/gupnp/gssdp.inc | 16
++++++++++++++++ .../recipes-connectivity/gupnp/gssdp_0.12.2.1.bb |
5 +++++ .../recipes-connectivity/gupnp/gssdp_0.13.2.bb | 8
++++++++ 3 files changed, 29 insertions(+) create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb

(quoted diff) +0 -0

b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc new file mode 100644 index 0000000..51befd9 --- /dev/null +++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc @@ -0,0 +1,16 @@ +SUMMARY = "Resource discovery and announcement over SSDP" +DESCRIPTION = "GSSDP implements resource discovery and announcement over SSDP (Simpe Service Discovery Protocol)." +LICENSE = "LGPLv2" +LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7" +DEPENDS = "glib-2.0 libsoup-2.4 gobject-introspection-stub vala-stub-native" +

(quoted diff) +3 -0
+inherit autotools pkgconfig + +PACKAGES =+ "gssdp-tools" + 
+FILES_gssdp-tools = "${bindir}/gssdp* ${datadir}/gssdp/*.glade" + 
+EXTRA_OECONF = "--disable-introspection" + +PACKAGECONFIG ??=
Quoted 2 lines

"${@base_contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)}" +PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk,gtk+"

Minor nit: variables are grouped by task and ordered by task order, so FILES/PACKAGES/R* goes below EXTRA_OECONF/do_configure/do_compile/do_install

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
Comment: GPGTools - http://gpgtools.org

iD8DBQFQ1FDpMkyGM64RGpERAh9SAJ0Yg4G0MXH+zAfMEoEfNAB42YGu4gCfbhpC y6er7oRE3tVTjJekedFm02Q=
=fT9I
-----END PGP SIGNATURE-----

#6 lore raw

PATCH 2/6 gupnp: add 0.18.4 and 0.19.3

In reply to Ross Burton
---
 .../recipes-connectivity/gupnp/gupnp.inc            |   19 +++++++++++++++++++
 .../recipes-connectivity/gupnp/gupnp_0.18.4.bb      |    8 ++++++++
 .../recipes-connectivity/gupnp/gupnp_0.19.3.bb      |   10 ++++++++++
 3 files changed, 37 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp.inc
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb
meta-multimedia/recipes-connectivity/gupnp/gupnp.inc new file +19 -0
new file mode 100644
index 0000000..91eae15
@@ -0,0 +1,19 @@
+SUMMARY = "UPnP framework"
+DESCRIPTION = "GUPnP is an elegant, object-oriented open source framework for creating UPnP  devices and control points, written in C using GObject and libsoup. The GUPnP API is intended to be easy to use, efficient and flexible. It provides the same set of features as libupnp, but shields the developer from most of UPnP's internals."
+LICENSE = "LGPLv2+"
+
+DEPENDS = "e2fsprogs gssdp libsoup-2.4 libxml2 gnome-icon-theme gobject-introspection-stub"
+
+EXTRA_OECONF = "--disable-introspection"
+
+inherit autotools pkgconfig
+
+FILES_${PN} = "${libdir}/*.so.*"
+FILES_${PN}-dev += "${bindir}/gupnp-binding-tool"
+
+SYSROOT_PREPROCESS_FUNCS += "gupnp_sysroot_preprocess"
+
+gupnp_sysroot_preprocess () {
+	install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
+	install -m 755 ${D}${bindir}/gupnp-binding-tool ${SYSROOT_DESTDIR}${bindir_crossscripts}/
+}
meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb new file +8 -0
new file mode 100644
index 0000000..4fb1d05
@@ -0,0 +1,8 @@
+require gupnp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.18/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "0e15fa26be7b1a0255e6dec07c285527"
+SRC_URI[sha256sum] = "6b437d5711b212292c6080626b97480268310da636a6cf937ad6119291af78a1"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+                    file://libgupnp/gupnp.h;beginline=1;endline=20;md5=28c49b17d623afc3335efc2e511879e1"
meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb new file +10 -0
new file mode 100644
index 0000000..bab74b8
@@ -0,0 +1,10 @@
+require gupnp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.19/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "8165c3ad3d16576a0a99250b75df23f8"
+SRC_URI[sha256sum] = "0d3097c419e1f8af0ff8ee91318d75e8896b3b92924cb1a5cf93010795a7118b"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+                    file://libgupnp/gupnp.h;beginline=1;endline=20;md5=d78a69d9b6e63ee2dc72e7b674d97520"
+
+DEFAULT_PREFERENCE = "-1"
Signature · 1 line
1.7.10
#7 lore raw

PATCH 3/6 gupnp-av: add 0.10.3 and 0.11.6

In reply to Ross Burton
---
 meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc      |    6 ++++++
 .../recipes-connectivity/gupnp/gupnp-av_0.10.3.bb            |    8 ++++++++
 .../recipes-connectivity/gupnp/gupnp-av_0.11.6.bb            |   10 ++++++++++
 3 files changed, 24 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb
meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc new file +6 -0
new file mode 100644
index 0000000..32cef94
@@ -0,0 +1,6 @@
+SUMMARY = "Helpers for AV applications using UPnP"
+DESCRIPTION = "GUPnP-AV is a collection of helpers for building AV (audio/video) applications using GUPnP."
+LICENSE = "LGPLv2"
+DEPENDS = "gupnp"
+
+inherit autotools pkgconfig
meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb new file +8 -0
new file mode 100644
index 0000000..5f8e73a
@@ -0,0 +1,8 @@
+require gupnp-av.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.10/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "2c57e56b201765b2297946d8d99bd01c"
+SRC_URI[sha256sum] = "d0dbb727d87bc9f2dc834455d14a30700b16b41a57e9dcde2e822b378ca8f1e2"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+                    file://libgupnp-av/gupnp-av.h;beginline=1;endline=22;md5=d344132a8766641fcb11213ff5982086"
meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb new file +10 -0
new file mode 100644
index 0000000..b402dd8
@@ -0,0 +1,10 @@
+require gupnp-av.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.11/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "ee200393207323f0b594f11d6184556c"
+SRC_URI[sha256sum] = "401991336babb18c4ebed16e75e0b4d3e5848cff7bb878bbfd54a5d15203c4cc"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+                    file://libgupnp-av/gupnp-av.h;beginline=1;endline=22;md5=2b47b7b5f799d2ebabe62b895e848820"
+
+DEFAULT_PREFERENCE = "-1"
Signature · 1 line
1.7.10
#8 lore raw

PATCH 4/6 gupnp-dlna: add 0.9.2

In reply to Ross Burton
---
 .../recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb   |   18 ++++++++++++++++++
 1 file changed, 18 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb
meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb new file +18 -0
new file mode 100644
index 0000000..1748e35
@@ -0,0 +1,18 @@
+SUMMARY = "Helpers for AV applications using DLNA"
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
+                    file://libgupnp-dlna/gupnp-dlna-profile.h;beginline=1;endline=22;md5=1b85459f65cb1e73a885ca137aab6274"
+
+DEPENDS = "libxml2 glib-2.0"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.9/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "d972f9b03f0f3793cb895eb034ea314f"
+SRC_URI[sha256sum] = "c28d5650604c7da4f193e6b85049a4885f3a01f1996df768d55b5cb898a9fc53"
+
+inherit autotools pkgconfig
+
+# The GStreamer metadata backend requires GStreamer 1.0, so skip this until we
+# have that packaged.
+EXTRA_OECONF = "--disable-gstreamer-metadata-backend"
+
+FILES_${PN} += "${datadir}/gupnp-dlna-2.0/dlna-profiles"
Signature · 1 line
1.7.10
#9 lore raw

PATCH 5/6 gupnp-igd: add 0.2.2

In reply to Ross Burton
---
 .../recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb        |   14 ++++++++++++++
 1 file changed, 14 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb
meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb new file +14 -0
new file mode 100644
index 0000000..112bc4b
@@ -0,0 +1,14 @@
+SUMMARY = "Helpers for interacting with Internet Gateway Devices over UPnP"
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
+                    file://libgupnp-igd/gupnp-simple-igd.c;beginline=1;endline=21;md5=aa292c0d9390463a6e1055dc5fc68e80"
+
+DEPENDS = "glib-2.0 gupnp"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.2/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "f881323304185c02634034e3bda714ba"
+SRC_URI[sha256sum] = "73b6a98a0f13b29b34c3bfc07f99f78b1319211cb95a8585752873af2b9067d3"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-introspection --disable-python"
Signature · 1 line
1.7.10
#10 lore raw

PATCH 6/6 gupnp-tools: add 0.8.1

In reply to Ross Burton
---
 .../recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb         |   11 +++++++++++
 1 file changed, 11 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb
meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb new file +11 -0
new file mode 100644
index 0000000..7a26453
@@ -0,0 +1,11 @@
+DESCRIPTION = "Tools for GUPnP"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://src/network-light/main.c;beginline=1;endline=21;md5=033bf37c030780c5a72165846b3003f6"
+DEPENDS = "gupnp gupnp-av gtk+ gnome-icon-theme"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.8/${BPN}-${PV}.tar.bz2"
+SRC_URI[md5sum] = "cafc2a4f2d1a91a8c1228799073d1d7d"
+SRC_URI[sha256sum] = "57d5ca899f8da7e4ae69e5f98d75d1603aa7f388022f9ccb357f90abb22b75b6"
+
+inherit autotools pkgconfig
Signature · 1 line
1.7.10