Skip to contentSkip to conversation

Revert "update-rc.d: disable update-rc.d.bbclass when systemd enabled"

PATCH In review Ross Burton 2 participants 3 messages Feb 7, 2013 – Feb 8, 2013

lore
Share & tools
lore
#0 lore raw

PATCH 1/1 Revert "update-rc.d: disable update-rc.d.bbclass when systemd enabled"

This was just wrong - when systemd is being used there'll still be packages that use SysV-style init scripts, which systemd supports fine.

This reverts commit b94227f7290796f6ebbe5c5ff1680b9b689022b1.

---
 meta/classes/update-rc.d.bbclass      |   90 ++++++++++++++++++++++++++++++++-
 meta/classes/update-rc.d_real.bbclass |   89 --------------------------------
 2 files changed, 89 insertions(+), 90 deletions(-)
 delete mode 100644 meta/classes/update-rc.d_real.bbclass
meta/classes/update-rc.d.bbclass +89 -1
index 34f9838..83816d6 100644
@@ -1 +1,89 @@
-inherit ${@base_contains('DISTRO_FEATURES','sysvinit','update-rc.d_real','',d)}
+UPDATERCPN ?= "${PN}"
+
+DEPENDS_append = " update-rc.d-native"
+UPDATERCD = "update-rc.d"
+UPDATERCD_virtclass-cross = ""
+UPDATERCD_class-native = ""
+UPDATERCD_class-nativesdk = ""
+
+RDEPENDS_${UPDATERCPN}_append = " ${UPDATERCD}"
+
+INITSCRIPT_PARAMS ?= "defaults"
+
+INIT_D_DIR = "${sysconfdir}/init.d"
+
+updatercd_postinst() {
+if test "x$D" != "x"; then
+	OPT="-r $D"
+else
+	OPT="-s"
+fi
+update-rc.d $OPT ${INITSCRIPT_NAME} ${INITSCRIPT_PARAMS}
+}
+
+updatercd_prerm() {
+if test "x$D" = "x"; then
+	${INIT_D_DIR}/${INITSCRIPT_NAME} stop
+fi
+}
+
+updatercd_postrm() {
+if [ "$D" != "" ]; then
+	update-rc.d -f -r $D ${INITSCRIPT_NAME} remove
+else
+	update-rc.d ${INITSCRIPT_NAME} remove
+fi
+}
+
+
+def update_rc_after_parse(d):
+    if d.getVar('INITSCRIPT_PACKAGES') == None:
+        if d.getVar('INITSCRIPT_NAME') == None:
+            raise bb.build.FuncFailed, "%s inherits update-rc.d but doesn't set INITSCRIPT_NAME" % d.getVar('FILE')
+        if d.getVar('INITSCRIPT_PARAMS') == None:
+            raise bb.build.FuncFailed, "%s inherits update-rc.d but doesn't set INITSCRIPT_PARAMS" % d.getVar('FILE')
+
+python __anonymous() {
+    update_rc_after_parse(d)
+}
+
+python populate_packages_prepend () {
+    def update_rcd_package(pkg):
+        bb.debug(1, 'adding update-rc.d calls to postinst/postrm for %s' % pkg)
+        localdata = bb.data.createCopy(d)
+        overrides = localdata.getVar("OVERRIDES", True)
+        localdata.setVar("OVERRIDES", "%s:%s" % (pkg, overrides))
+        bb.data.update_data(localdata)
+
+        """
+        update_rc.d postinst is appended here because pkg_postinst may require to
+        execute on the target. Not doing so may cause update_rc.d postinst invoked
+        twice to cause unwanted warnings.
+        """ 
+        postinst = localdata.getVar('pkg_postinst', True)
+        if not postinst:
+            postinst = '#!/bin/sh\n'
+        postinst += localdata.getVar('updatercd_postinst', True)
+        d.setVar('pkg_postinst_%s' % pkg, postinst)
+
+        prerm = localdata.getVar('pkg_prerm', True)
+        if not prerm:
+            prerm = '#!/bin/sh\n'
+        prerm += localdata.getVar('updatercd_prerm', True)
+        d.setVar('pkg_prerm_%s' % pkg, prerm)
+
+        postrm = localdata.getVar('pkg_postrm', True)
+        if not postrm:
+                postrm = '#!/bin/sh\n'
+        postrm += localdata.getVar('updatercd_postrm', True)
+        d.setVar('pkg_postrm_%s' % pkg, postrm)
+
+    pkgs = d.getVar('INITSCRIPT_PACKAGES', True)
+    if pkgs == None:
+        pkgs = d.getVar('UPDATERCPN', True)
+        packages = (d.getVar('PACKAGES', True) or "").split()
+        if not pkgs in packages and packages != []:
+            pkgs = packages[0]
+    for pkg in pkgs.split():
+        update_rcd_package(pkg)
+}
meta/classes/update-rc.d_real.bbclass deleted +0 -89

89 lines not on this page · raw message

Signature · 1 line
1.7.10.4
#1 lore raw
Quoted 4 lines · Ross Burton

This was just wrong - when systemd is being used there'll still be packages that
use SysV-style init scripts, which systemd supports fine.

I understand this. But there should be a way to remove all init scripts for configurations where systemd is not in compatible mode.

Signature · 2 lines
*Andrei Gherzan*
m: +40.744.478.414 |  f: +40.31.816.28.12
#2 lore raw
Quoted 2 lines · Andrei Gherzan

I understand this. But there should be a way to remove all init scripts for configurations where systemd is not in compatible mode.

Yes, and in my current branch which adds a systemd class, if a recipe inherits both systemd and update-rcd, update-rcd turns itself off.

Ross