Skip to contentSkip to conversation

Call tracing/debug code in VFP preempt code

PATCH New Stephen Boyd 1 participant 3 messages Mar 4, 2013

Subsystems (3)
lore
Share & tools
lore
#0 lore raw

cover Call tracing/debug code in VFP preempt code

The VFP preempt enable/disable code doesn't call into the tracers and also doesn't participate in the preempt debugging code. This patchset fixes that by making calls to the C functions from assembly when appropriate.

Stephen Boyd (2):
ARM: Consolidate preempt enable/disable assembly into macros
ARM: Enable tracing around vfp preemption enable/disable

 arch/arm/kernel/entry-header.S | 31 +++++++++++++++++++++++++++++++
 arch/arm/vfp/entry.S           | 20 +++-----------------
 arch/arm/vfp/vfphw.S           | 14 ++------------
 3 files changed, 36 insertions(+), 29 deletions(-)
Signature · 2 lines
The Qualcomm Innovation Center, Inc. is a member of the Code Aurora Forum,
hosted by The Linux Foundation
#1 lore raw

PATCH 1/2 ARM: Consolidate preempt enable/disable assembly into macros

We duplicate the same few preempt enable and disable assembly instructions in multiple places in the vfp code. Move the code to a macro in entry-header.S so that we can modify the preempt enable/disable assembly in one place in the future.

---
 arch/arm/kernel/entry-header.S | 17 +++++++++++++++++
 arch/arm/vfp/entry.S           | 20 +++-----------------
 arch/arm/vfp/vfphw.S           | 14 ++------------
 3 files changed, 22 insertions(+), 29 deletions(-)
arch/arm/kernel/entry-header.S +17 -0
index 9a8531e..130e6a6 100644
@@ -163,6 +163,23 @@
 	.endm
 #endif	/* !CONFIG_THUMB2_KERNEL */
 
+	.macro preempt_enable_no_resched, tsk, cnt
+#ifdef CONFIG_PREEMPT_COUNT
+	get_thread_info	\tsk
+	ldr	\cnt, [\tsk, #TI_PREEMPT]	@ get preempt count
+	sub	\cnt, \cnt, #1			@ decrement it
+	str	\cnt, [\tsk, #TI_PREEMPT]
+#endif
+	.endm
+
+	.macro preempt_disable, tsk, cnt
+#ifdef CONFIG_PREEMPT_COUNT
+	ldr	\cnt, [\tsk, #TI_PREEMPT]	@ get preempt count
+	add	\cnt, \cnt, #1			@ increment it
+	str	\cnt, [\tsk, #TI_PREEMPT]
+#endif
+	.endm
+
 /*
  * These are the registers used in the syscall handler, and allow us to
  * have in theory up to 7 arguments to a function - r0 to r6.
arch/arm/vfp/entry.S +3 -17
index 323ce1a..e528709 100644
@@ -22,11 +22,7 @@
 @  IRQs disabled.
 @
 ENTRY(do_vfp)
-#ifdef CONFIG_PREEMPT_COUNT
-	ldr	r4, [r10, #TI_PREEMPT]	@ get preempt count
-	add	r11, r4, #1		@ increment it
-	str	r11, [r10, #TI_PREEMPT]
-#endif
+	preempt_disable r10, r4
 	enable_irq
  	ldr	r4, .LCvfp
 	ldr	r11, [r10, #TI_CPU]	@ CPU number
@@ -35,12 +31,7 @@ ENTRY(do_vfp)
 ENDPROC(do_vfp)
 
 ENTRY(vfp_null_entry)
-#ifdef CONFIG_PREEMPT_COUNT
-	get_thread_info	r10
-	ldr	r4, [r10, #TI_PREEMPT]	@ get preempt count
-	sub	r11, r4, #1		@ decrement it
-	str	r11, [r10, #TI_PREEMPT]
-#endif
+	preempt_enable_no_resched r10, r4
 	mov	pc, lr
 ENDPROC(vfp_null_entry)
 
@@ -53,12 +44,7 @@ ENDPROC(vfp_null_entry)
 
 	__INIT
 ENTRY(vfp_testing_entry)
-#ifdef CONFIG_PREEMPT_COUNT
-	get_thread_info	r10
-	ldr	r4, [r10, #TI_PREEMPT]	@ get preempt count
-	sub	r11, r4, #1		@ decrement it
-	str	r11, [r10, #TI_PREEMPT]
-#endif
+	preempt_enable_no_resched r10, r4
 	ldr	r0, VFP_arch_address
 	str	r5, [r0]		@ known non-zero value
 	mov	pc, r9			@ we have handled the fault
arch/arm/vfp/vfphw.S +2 -12
index dd5e56f..8bae250 100644
@@ -168,12 +168,7 @@ vfp_hw_state_valid:
 					@ else it's one 32-bit instruction, so
 					@ always subtract 4 from the following
 					@ instruction address.
-#ifdef CONFIG_PREEMPT_COUNT
-	get_thread_info	r10
-	ldr	r4, [r10, #TI_PREEMPT]	@ get preempt count
-	sub	r11, r4, #1		@ decrement it
-	str	r11, [r10, #TI_PREEMPT]
-#endif
+	preempt_enable_no_resched r10, r4
 	mov	pc, r9			@ we think we have handled things
 
 
@@ -192,12 +187,7 @@ look_for_VFP_exceptions:
 	@ not recognised by VFP
 
 	DBGSTR	"not VFP"
-#ifdef CONFIG_PREEMPT_COUNT
-	get_thread_info	r10
-	ldr	r4, [r10, #TI_PREEMPT]	@ get preempt count
-	sub	r11, r4, #1		@ decrement it
-	str	r11, [r10, #TI_PREEMPT]
-#endif
+	preempt_enable_no_resched r10, r4
 	mov	pc, lr
 
 process_exception:
Signature · 2 lines
The Qualcomm Innovation Center, Inc. is a member of the Code Aurora Forum,
hosted by The Linux Foundation
#2 lore raw

PATCH 2/2 ARM: Enable tracing around vfp preemption enable/disable

In reply to Stephen Boyd

The VFP code enables and disables preemption but doesn't call into the tracer except for in the VFP bounce code to say that preemption has been enabled again. Trace the preemption disable and enable calls made in assembly so that we can accurately measure how long preemption is disabled while handling VFP exceptions.

---
 arch/arm/kernel/entry-header.S | 14 ++++++++++++++
 1 file changed, 14 insertions(+)
arch/arm/kernel/entry-header.S +14 -0
index 130e6a6..75bcb18 100644
@@ -165,19 +165,33 @@
 
 	.macro preempt_enable_no_resched, tsk, cnt
 #ifdef CONFIG_PREEMPT_COUNT
+#if defined(CONFIG_DEBUG_PREEMPT) || defined(CONFIG_PREEMPT_TRACER)
+	stmdb   sp!, {r0-r3, ip, lr}
+	mov	r0, #1
+	bl	sub_preempt_count
+	ldmia	sp!, {r0-r3, ip, lr}
+#else
 	get_thread_info	\tsk
 	ldr	\cnt, [\tsk, #TI_PREEMPT]	@ get preempt count
 	sub	\cnt, \cnt, #1			@ decrement it
 	str	\cnt, [\tsk, #TI_PREEMPT]
 #endif
+#endif
 	.endm
 
 	.macro preempt_disable, tsk, cnt
 #ifdef CONFIG_PREEMPT_COUNT
+#if defined(CONFIG_DEBUG_PREEMPT) || defined(CONFIG_PREEMPT_TRACER)
+	stmdb   sp!, {r0-r3, ip, lr}
+	mov	r0, #1
+	bl	add_preempt_count
+	ldmia	sp!, {r0-r3, ip, lr}
+#else
 	ldr	\cnt, [\tsk, #TI_PREEMPT]	@ get preempt count
 	add	\cnt, \cnt, #1			@ increment it
 	str	\cnt, [\tsk, #TI_PREEMPT]
 #endif
+#endif
 	.endm
 
 /*
Signature · 2 lines
The Qualcomm Innovation Center, Inc. is a member of the Code Aurora Forum,
hosted by The Linux Foundation