libproxy: PACKAGECONFIGisation

PATCH In review Andre McCurdy 3 participants 7 messages Feb 8, 2016 – Feb 9, 2016

Share & tools

Andre McCurdy

author

2016-02-08 20:35 UTC #0 lore raw

cover libproxy: PACKAGECONFIGisation

Andre McCurdy (2):
libproxy: replace PACKAGECONFIG equivalent with the real thing
libproxy: add PACKAGECONFIG control for gnome3

 meta/recipes-support/libproxy/libproxy_0.4.11.bb | 31 ++++++++++++++++--------
 1 file changed, 21 insertions(+), 10 deletions(-)

Signature · 1 line

1.9.1

Andre McCurdy

author

2016-02-08 20:35 UTC #1 lore raw

PATCH 1/2 libproxy: replace PACKAGECONFIG equivalent with the real thing

No change in functionality, just use PACKAGECONFIG instead of python.

Signed-off-by Andre McCurdy <[email protected]>

---
 meta/recipes-support/libproxy/libproxy_0.4.11.bb | 29 ++++++++++++++++--------
 1 file changed, 19 insertions(+), 10 deletions(-)

meta/recipes-support/libproxy/libproxy_0.4.11.bb +19 ~~-10~~

index 9db5231..a523857 100644
@@ -6,29 +6,38 @@ LICENSE = "LGPLv2.1+"
 LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
                     file://utils/proxy.c;beginline=1;endline=18;md5=55152a1006d7dafbef32baf9c30a99c0"
 
-DEPENDS = "gconf glib-2.0"
+DEPENDS = "glib-2.0"
 
 SRC_URI = "${DEBIAN_MIRROR}/main/libp/${BPN}/${BPN}_${PV}.orig.tar.gz \
            file://0001-test-Include-sys-select.h-for-select.patch \
           "
+
 SRC_URI[md5sum] = "3cd1ae2a4abecf44b3f24d6639d2cd84"
 SRC_URI[sha256sum] = "dc3f33de54163718f82b3e7c496a7de97f8862578414b8ecaad3cbfe4821864b"
 
 inherit cmake pkgconfig
 
-EXTRA_OECMAKE = "-DWITH_WEBKIT=no -DWITH_GNOME=yes -DWITH_KDE4=no \
-	      -DWITH_PYTHON=no -DWITH_PERL=no -DWITH_MOZJS=no -DWITH_NM=no -DLIB_INSTALL_DIR=${libdir} -DLIBEXEC_INSTALL_DIR=${libexecdir}"
+PACKAGECONFIG ?= " \
+    ${@ '' if incompatible_license_contains('GPLv3', 'x', '', d) == 'x' or bb.utils.contains('DISTRO_FEATURES', 'x11', 'x', '', d) == '' else 'gnome' } \
+"
 
-FILES_${PN} += "${libdir}/${BPN}/${PV}/modules"
-FILES_${PN}-dev += "${datadir}/cmake"
+PACKAGECONFIG[gnome] = "-DWITH_GNOME=yes,-DWITH_GNOME=no,gconf"
+
+EXTRA_OECMAKE += " \
+    -DWITH_KDE4=no \
+    -DWITH_MOZJS=no \
+    -DWITH_NM=no \
+    -DWITH_PERL=no \
+    -DWITH_PYTHON=no \
+    -DWITH_WEBKIT=no \
+    -DLIB_INSTALL_DIR=${libdir} \
+    -DLIBEXEC_INSTALL_DIR=${libexecdir} \
+"
 
 do_configure_prepend() {
 	export HOST_SYS=${HOST_SYS}
 	export BUILD_SYS=${BUILD_SYS}
 }
 
-python() {
-    if incompatible_license_contains("GPLv3", "x", "", d) == "x" or bb.utils.contains("DISTRO_FEATURES", "x11", "x", "", d) == "":
-        d.setVar("EXTRA_OECMAKE", d.getVar("EXTRA_OECMAKE", False).replace("-DWITH_GNOME=yes", "-DWITH_GNOME=no"))
-        d.setVar("DEPENDS", " ".join(i for i in d.getVar("DEPENDS", False).split() if i != "gconf"))
-}
+FILES_${PN} += "${libdir}/${BPN}/${PV}/modules"
+FILES_${PN}-dev += "${datadir}/cmake"

Signature · 1 line

1.9.1

Burton, Ross

2016-02-08 22:56 UTC #2 lore raw

Re: [PATCH 1/2] libproxy: replace PACKAGECONFIG equivalent with the real thing

Quoted 4 lines · Andre McCurdy

'' if incompatible_license_contains('GPLv3', 'x', '', d) == 'x' or bb.utils.contains('DISTRO_FEATURES', 'x11', 'x', '', d) == '' else 'gnome' } \

Instead of returning 'x' or '' and then doing string comparisons, why not just return True or False and let if/or/else do the right thing?

Ross

Andre McCurdy

author

2016-02-09 08:05 UTC #3 lore raw

Re: [PATCH 1/2] libproxy: replace PACKAGECONFIG equivalent with the real thing

Quoted 9 lines · Ross

Quoted 4 lines · Andre McCurdy
'' if incompatible_license_contains('GPLv3', 'x', '', d) == 'x' or bb.utils.contains('DISTRO_FEATURES', 'x11', 'x', '', d) == '' else 'gnome' } \
Instead of returning 'x' or '' and then doing string comparisons, why not just return True or False and let if/or/else do the right thing?

Just trying to preserve the original logic to make it clearer that no functionality is being changed.

The logic can be traced back to Paul Eggleton's original version here:

http://git.openembedded.org/openembedded-core/commit/?id=973351cf2e338f07c11395d494193e9c62857f2d

Quoted 1 line

Ross

Paul Eggleton

2016-02-09 17:29 UTC #4 lore raw

Re: [PATCH 1/2] libproxy: replace PACKAGECONFIG equivalent with the real thing

Quoted 9 lines · On Tue, 09 Feb 2016 00:05:15 Andre McCurdy wrote:

Quoted 7 lines · Ross
Quoted 3 lines · Andre McCurdy
'' if incompatible_license_contains('GPLv3', 'x', '', d) == 'x' or bb.utils.contains('DISTRO_FEATURES', 'x11', 'x', '', d) == '' else 'gnome' } \
Instead of returning 'x' or '' and then doing string comparisons, why not just return True or False and let if/or/else do the right thing?

Quoted 7 lines

Just trying to preserve the original logic to make it clearer that no functionality is being changed.
The logic can be traced back to Paul Eggleton's original version here:
http://git.openembedded.org/openembedded-core/commit/?id=973351cf2e338f07c1
1395d494193e9c62857f2d

Well, slap my wrist then ;)

Ross's suggestion does make it a bit tidier.

Cheers,
Paul

Signature · 2 lines

Paul Eggleton
Intel Open Source Technology Centre

Burton, Ross

2016-02-09 17:31 UTC #5 lore raw

Re: [PATCH 1/2] libproxy: replace PACKAGECONFIG equivalent with the real thing

Quoted 4 lines · Paul Eggleton

Well, slap my wrist then ;)
Ross's suggestion does make it a bit tidier.

I've a follow-up locally that removes all the GPLv3 nonsense as I fixed the need for that back in 2012. :) I'll send it shortly.

Ross

Andre McCurdy

author

2016-02-08 20:35 UTC #6 lore raw

PATCH 2/2 libproxy: add PACKAGECONFIG control for gnome3

In reply to Andre McCurdy

The gnome3 module was previously enabled by default, so enable the gnome3 PACKAGECONFIG option by default too.

Signed-off-by Andre McCurdy <[email protected]>

---
 meta/recipes-support/libproxy/libproxy_0.4.11.bb | 2 ++
 1 file changed, 2 insertions(+)

meta/recipes-support/libproxy/libproxy_0.4.11.bb +2 -0

index a523857..11a23b1 100644
@@ -19,9 +19,11 @@ inherit cmake pkgconfig
 
 PACKAGECONFIG ?= " \
     ${@ '' if incompatible_license_contains('GPLv3', 'x', '', d) == 'x' or bb.utils.contains('DISTRO_FEATURES', 'x11', 'x', '', d) == '' else 'gnome' } \
+    gnome3 \
 "
 
 PACKAGECONFIG[gnome] = "-DWITH_GNOME=yes,-DWITH_GNOME=no,gconf"
+PACKAGECONFIG[gnome3] = "-DWITH_GNOME3=yes,-DWITH_GNOME3=no"
 
 EXTRA_OECMAKE += " \
     -DWITH_KDE4=no \

Signature · 1 line

1.9.1