Skip to contentSkip to conversation

piglit support build without x11

PATCH Superseded [email protected] 2 participants 10 messages Jan 15, 2019 – Feb 27, 2019

v1 of 3 Superseded Latest is v3 →

lore
Share & tools
lore
#0 lore raw

cover piglit support build without x11

Fixes bug: [YOCTO #6077]

To support piglit without x11 by disable PIGLIT_BUILD_GL_TESTS, but the result is piglit can use without x11, but only small part of it can be used. Most of testcase will be skipped.

Changqing Li (2):
waffle: supprt build waffle without x11
piglit: support build piglit without x11

 meta/recipes-graphics/piglit/piglit_git.bb   | 12 +++++++-----
 meta/recipes-graphics/waffle/waffle_1.5.2.bb |  5 +----
 2 files changed, 8 insertions(+), 9 deletions(-)
Signature · 1 line
2.7.4
#1 lore raw

PATCH 1/2 waffle: supprt build waffle without x11

From: Changqing Li <[email protected]>

glx depend on x11, so only enable glx when DISTRO_FEATURES enabled x11. build waffle support gbm platform when x11 is not enabled

---
 meta/recipes-graphics/waffle/waffle_1.5.2.bb | 5 +----
 1 file changed, 1 insertion(+), 4 deletions(-)
meta/recipes-graphics/waffle/waffle_1.5.2.bb +1 -4
index 43c3edc..21ae77a 100644
@@ -15,10 +15,7 @@ inherit cmake distro_features_check lib_package
 
 # This should be overridden per-machine to reflect the capabilities of the GL
 # stack.
-PACKAGECONFIG ??= "glx"
-
-# libx11 requires x11 in DISTRO_FEATURES.
-REQUIRED_DISTRO_FEATURES = "${@bb.utils.contains('PACKAGECONFIG', 'glx', 'x11', '', d)}"
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'glx', 'gbm', d)}"
 
 # virtual/libgl requires opengl in DISTRO_FEATURES.
 REQUIRED_DISTRO_FEATURES += "${@bb.utils.contains('DEPENDS', 'virtual/${MLPREFIX}libgl', 'opengl', '', d)}"
Signature · 1 line
2.7.4
#2 lore raw

Re: [PATCH 1/2] waffle: supprt build waffle without x11

Quoted 1 line · On Tue, 15 Jan 2019 at 05:29, <[email protected]> wrote:

+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'glx', 'gbm', d)}"

Should this be:

PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'glx', '', d)} gbm"

ie always gbm, and glx if X11 is available?

Ross

#3 lore raw

Re: [PATCH 1/2] waffle: supprt build waffle without x11

Quoted 6 lines · Ross

Should this be:

PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'glx', '', d)} gbm"

ie always gbm, and glx if X11 is available?

Actually whist we're here, respect the wayland DISTRO_FEATURE too? And enable egl out of the box? Turn on as much as possible, basically.

Ross

#4 lore raw

PATCH 2/2 piglit: support build piglit without x11

In reply to [email protected]

From: Changqing Li <[email protected]>

1. Only depend on X11_DEPS when DISTRO_FEATURES enabled x11
2. test PIGLIT_BUILD_GL_TESTS depend on glx library, so depend on x11, so disable it when x11 is not enabled.
3. mesa-demos depend on libGL.so which is provide by recipe mesa, but when x11 is disabled, libGL.so is not generated. so we can only depend on this when x11 is enabled

---
 meta/recipes-graphics/piglit/piglit_git.bb | 12 +++++++-----
 1 file changed, 7 insertions(+), 5 deletions(-)
meta/recipes-graphics/piglit/piglit_git.bb +7 -5
index 622e046..fbeca0e 100644
@@ -17,11 +17,10 @@ PV = "1.0+gitr${SRCPV}"
 
 S = "${WORKDIR}/git"
 
-DEPENDS = "libpng virtual/libx11 libxkbcommon libxrender waffle virtual/libgl libglu python3-mako-native python3-numpy-native python3-six-native virtual/egl"
+X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
+DEPENDS = "libpng waffle libxkbcommon virtual/libgl python3-mako-native python3-numpy-native python3-six-native virtual/egl ${X11_DEPS}"
 
 inherit cmake pkgconfig python3native distro_features_check bash-completion
-# depends on virtual/libx11
-REQUIRED_DISTRO_FEATURES = "x11"
 
 # depends on virtual/libgl
 REQUIRED_DISTRO_FEATURES += "opengl"
@@ -32,8 +31,10 @@ REQUIRED_DISTRO_FEATURES += "opengl"
 export TEMP = "${B}/temp/"
 do_compile[dirs] =+ "${B}/temp/"
 
-PACKAGECONFIG ??= ""
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'opengl', '', d)}"
 PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
+PACKAGECONFIG[opengl] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,,"
+
 
 do_configure_prepend() {
    if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
@@ -48,7 +49,8 @@ RDEPENDS_${PN} = "waffle waffle-bin python3 python3-mako python3-json \
 	python3-misc \
 	python3-unixadmin python3-xml python3-multiprocessing \
 	python3-six python3-shell python3-io \
-	python3-netserver mesa-demos bash \
+	python3-netserver bash \
+	${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)} \
 	"
 
 INSANE_SKIP_${PN} += "dev-so already-stripped"
Signature · 1 line
2.7.4
#5 lore raw

Re: [PATCH 2/2] piglit: support build piglit without x11

meta/recipes-graphics/piglit/piglit_git.bb PV = "1.0+gitr${SRCPV}" · line 21

Quoted 2 lines · On Tue, 15 Jan 2019 at 05:29, <[email protected]> wrote:
meta/recipes-graphics/piglit/piglit_git.bb +2 -0
+X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
+DEPENDS = "libpng waffle libxkbcommon virtual/libgl python3-mako-native python3-numpy-native python3-six-native virtual/egl ${X11_DEPS}"

This...

Quoted 1 line

+ ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)} \

...and this are basically the buildtime and runtime dependencies for the 'opengl' packageconfig, so they should be in the PACKAGECONFIG[opengl] line.

Also if you rename [opengl] to [x11] and then you can just use bb.utils.filter().

Ross

#6 lore raw

v2 cover piglit support build without x11

From: Changqing Li <[email protected]>

To support piglit without x11 by disable PIGLIT_BUILD_GL_TESTS, but the result is piglit can use without x11, but only small part of it can be used. Most of testcase will be skipped.

Changqing Li (2):
waffle: supprt build waffle without x11
piglit: support build piglit without x11

 meta/recipes-graphics/piglit/piglit_git.bb   | 13 ++++++++-----
 meta/recipes-graphics/waffle/waffle_1.5.2.bb |  7 +++----
 2 files changed, 11 insertions(+), 9 deletions(-)
Signature · 1 line
2.7.4
#7 lore raw

PATCH v2 1/2 waffle: supprt build waffle without x11

From: Changqing Li <[email protected]>

respect DISTRO_FEATURES to make waffle support different platform, gbm platform is supported by default.

---
 meta/recipes-graphics/waffle/waffle_1.5.2.bb | 7 +++----
 1 file changed, 3 insertions(+), 4 deletions(-)
meta/recipes-graphics/waffle/waffle_1.5.2.bb +3 -4
index 43c3edc..31572f2 100644
@@ -15,10 +15,9 @@ inherit cmake distro_features_check lib_package
 
 # This should be overridden per-machine to reflect the capabilities of the GL
 # stack.
-PACKAGECONFIG ??= "glx"
-
-# libx11 requires x11 in DISTRO_FEATURES.
-REQUIRED_DISTRO_FEATURES = "${@bb.utils.contains('PACKAGECONFIG', 'glx', 'x11', '', d)}"
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'glx x11-egl', '', d)} \
+                   ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland', '', d)} \
+                   gbm"
 
 # virtual/libgl requires opengl in DISTRO_FEATURES.
 REQUIRED_DISTRO_FEATURES += "${@bb.utils.contains('DEPENDS', 'virtual/${MLPREFIX}libgl', 'opengl', '', d)}"
Signature · 1 line
2.7.4
#8 lore raw

PATCH v2 2/2 piglit: support build piglit without x11

In reply to [email protected]

From: Changqing Li <[email protected]>

* test PIGLIT_BUILD_GL_TESTS depend on glx library, so depend on x11, so respect the DISTRO_FEATURES, only enable it when x11 is enabled.
* mesa-demos depend on libGL.so which is provide by recipe mesa, but when x11 is disabled, libGL.so is not generated. so we can only rdepend on this when x11 is enabled
* add x11 PACKAGECONFIG to add correct config/depend/rdepend

---
 meta/recipes-graphics/piglit/piglit_git.bb | 13 ++++++++-----
 1 file changed, 8 insertions(+), 5 deletions(-)
meta/recipes-graphics/piglit/piglit_git.bb +8 -5
index 622e046..0737d02 100644
@@ -17,11 +17,12 @@ PV = "1.0+gitr${SRCPV}"
 
 S = "${WORKDIR}/git"
 
-DEPENDS = "libpng virtual/libx11 libxkbcommon libxrender waffle virtual/libgl libglu python3-mako-native python3-numpy-native python3-six-native virtual/egl"
+X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
+X11_RDEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)}"
+
+DEPENDS = "libpng waffle libxkbcommon virtual/libgl python3-mako-native python3-numpy-native python3-six-native virtual/egl"
 
 inherit cmake pkgconfig python3native distro_features_check bash-completion
-# depends on virtual/libx11
-REQUIRED_DISTRO_FEATURES = "x11"
 
 # depends on virtual/libgl
 REQUIRED_DISTRO_FEATURES += "opengl"
@@ -32,8 +33,10 @@ REQUIRED_DISTRO_FEATURES += "opengl"
 export TEMP = "${B}/temp/"
 do_compile[dirs] =+ "${B}/temp/"
 
-PACKAGECONFIG ??= ""
+PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
 PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
+PACKAGECONFIG[x11] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,${X11_DEPS}, ${X11_RDEPS}"
+
 
 do_configure_prepend() {
    if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
@@ -48,7 +51,7 @@ RDEPENDS_${PN} = "waffle waffle-bin python3 python3-mako python3-json \
 	python3-misc \
 	python3-unixadmin python3-xml python3-multiprocessing \
 	python3-six python3-shell python3-io \
-	python3-netserver mesa-demos bash \
+	python3-netserver bash \
 	"
 
 INSANE_SKIP_${PN} += "dev-so already-stripped"
Signature · 1 line
2.7.4
#9 lore raw

Re: [PATCH V2 2/2] piglit: support build piglit without x11

ping

Quoted 56 lines · On 1/16/19 11:04 AM, [email protected] wrote:

From: Changqing Li <[email protected]>

* test PIGLIT_BUILD_GL_TESTS depend on glx library, so depend on x11, so respect the DISTRO_FEATURES, only enable it when x11 is enabled.
* mesa-demos depend on libGL.so which is provide by recipe mesa, but when x11 is disabled, libGL.so is not generated. so we can only rdepend on this when x11 is enabled
* add x11 PACKAGECONFIG to add correct config/depend/rdepend

---
  meta/recipes-graphics/piglit/piglit_git.bb | 13 ++++++++-----
  1 file changed, 8 insertions(+), 5 deletions(-)
meta/recipes-graphics/piglit/piglit_git.bb +8 -5
index 622e046..0737d02 100644
@@ -17,11 +17,12 @@ PV = "1.0+gitr${SRCPV}"
 
  S = "${WORKDIR}/git"
 
-DEPENDS = "libpng virtual/libx11 libxkbcommon libxrender waffle virtual/libgl libglu python3-mako-native python3-numpy-native python3-six-native virtual/egl"
+X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
+X11_RDEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)}"
+
+DEPENDS = "libpng waffle libxkbcommon virtual/libgl python3-mako-native python3-numpy-native python3-six-native virtual/egl"
 
  inherit cmake pkgconfig python3native distro_features_check bash-completion
-# depends on virtual/libx11
-REQUIRED_DISTRO_FEATURES = "x11"
 
  # depends on virtual/libgl
  REQUIRED_DISTRO_FEATURES += "opengl"
@@ -32,8 +33,10 @@ REQUIRED_DISTRO_FEATURES += "opengl"
  export TEMP = "${B}/temp/"
  do_compile[dirs] =+ "${B}/temp/"
 
-PACKAGECONFIG ??= ""
+PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
  PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
+PACKAGECONFIG[x11] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,${X11_DEPS}, ${X11_RDEPS}"
+
 
  do_configure_prepend() {
     if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
@@ -48,7 +51,7 @@ RDEPENDS_${PN} = "waffle waffle-bin python3 python3-mako python3-json \
  	python3-misc \
  	python3-unixadmin python3-xml python3-multiprocessing \
  	python3-six python3-shell python3-io \
-	python3-netserver mesa-demos bash \
+	python3-netserver bash \
  	"
 
  INSANE_SKIP_${PN} += "dev-so already-stripped"
Signature · 3 lines
BRs

Sandy(Li Changqing)