Skip to contentSkip to conversation

ti-display-sharing-fw: remove deprecated firmware

PATCH New Denys Dmytriyenko 2 participants 4 messages Aug 20, 2020 – Aug 26, 2020

lore
Share & tools
lore
#0 lore raw

PATCH 1/3 ti-display-sharing-fw: remove deprecated firmware

From: Denys Dmytriyenko <[email protected]>

Display sharing is not supported in K5.4+ and corresponding FW is now obsolete.

---
 .../ti-display-sharing-fw_git.bb                   | 48 ----------------------
 1 file changed, 48 deletions(-)
 delete mode 100644 recipes-bsp/ti-display-sharing-fw/ti-display-sharing-fw_git.bb
recipes-bsp/ti-display-sharing-fw/ti-display-sharing-fw_git.bb deleted +0 -48
deleted file mode 100644
index 9115b6b..0000000
@@ -1,48 +0,0 @@
-SUMMARY = "TI Display Sharing Firmware"
-
-LICENSE = "TI-TFL"
-LIC_FILES_CHKSUM = "file://LICENSE.ti;md5=b5aebf0668bdf95621259288c4a46d76"
-
-PV = "06.01.00.00+git${SRCPV}"
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-
-inherit deploy
-inherit update-alternatives
-
-PROTOCOL = "git"
-BRANCH = "ti-linux-firmware"
-SRCREV = "e7be1ab85266c47236330e2909997d20fc62e312"
-
-SRC_URI = "git://git.ti.com/processor-firmware/ti-linux-firmware.git;protocol=${PROTOCOL};branch=${BRANCH}"
-
-S = "${WORKDIR}/git"
-
-TI_DISP_SHARE_FW_DIR = "${S}/ti-display-sharing/"
-TI_DISP_SHARE_FW_FILENAME = "ti-display-sharing-j721e.bin"
-
-# make sure that lib/firmware, and all its contents are part of the package
-FILES_${PN} += "${base_libdir}/firmware"
-
-do_install() {
-  install -d ${D}${base_libdir}/firmware
-  install -m 0755 ${TI_DISP_SHARE_FW_DIR}/${TI_DISP_SHARE_FW_FILENAME} ${D}${base_libdir}/firmware
-}
-
-TARGET_MAIN_R5FSS0_1 = "j7-main-r5f0_1-fw"
-ALTERNATIVE_${PN} = "j7-main-r5f0_1-fw"
-ALTERNATIVE_LINK_NAME[j7-main-r5f0_1-fw] = "${base_libdir}/firmware/${TARGET_MAIN_R5FSS0_1}"
-ALTERNATIVE_TARGET[j7-main-r5f0_1-fw] = "${base_libdir}/firmware/${TI_DISP_SHARE_FW_FILENAME}"
-ALTERNATIVE_PRIORITY = "9"
-
-# This is used to prevent the build system to strip the executables
-INHIBIT_PACKAGE_STRIP = "1"
-INHIBIT_SYSROOT_STRIP = "1"
-
-# This is used to prevent the build system to split the debug info in a separate file
-INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-# As it likely to be a different arch from the Yocto build, disable checking by adding "arch" to INSANE_SKIP
-INSANE_SKIP_${PN} += "arch"
-
-# we don't want to configure and build the source code
-do_compile[noexec] = "1"
-do_configure[noexec] = "1"
Signature · 1 line
2.7.4
#1 lore raw

PATCH v2 2/3 ti-rtos-metadata: add recipe to fetch and deploy metadata.inc for RTOS FW binary integration

From: Denys Dmytriyenko <[email protected]>

---
v2 - append SRCPV to easily track AUTOREV-ed versions

 recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb | 41 ++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb new file +41 -0
new file mode 100644
index 0000000..d49d7d8
@@ -0,0 +1,41 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9"
+
+COMPATIBLE_MACHINE = "k3"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+inherit nopackages deploy
+
+PLAT_SFX = ""
+PLAT_SFX_j7 = "/j721e"
+PLAT_SFX_j7200-evm = "/j7200"
+PLAT_SFX_am65xx = "/am65xx"
+
+# Use weak assignment to set defaults to TI_RTOS_METADATA_* variables
+TI_RTOS_METADATA_URI ?= "git://git.ti.com/processor-sdk/coresdk_rtos_releases.git"
+TI_RTOS_METADATA_PROTOCOL ?= "git"
+TI_RTOS_METADATA_SRCREV ?= "2290c123a0c4ba4804d794c39532296a9c7b9587"
+TI_RTOS_METADATA_BRANCH ?= "master"
+TI_RTOS_METADATA_DIR ?= "${PLAT_SFX}"
+TI_RTOS_METADATA_FILE ?= "${S}${TI_RTOS_METADATA_DIR}/metadata.inc"
+
+PV = "1.0.0+git${SRCPV}"
+
+S = "${WORKDIR}/git"
+
+SRC_URI = "${TI_RTOS_METADATA_URI};branch=${TI_RTOS_METADATA_BRANCH};protocol=${TI_RTOS_METADATA_PROTOCOL}"
+SRCREV = "${TI_RTOS_METADATA_SRCREV}"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+do_install[noexec] = "1"
+
+do_deploy () {
+	install -d ${DEPLOYDIR}
+	install -m 0644 ${TI_RTOS_METADATA_FILE} ${DEPLOYDIR}/
+}
+
+addtask deploy before do_build after do_compile
Signature · 1 line
2.7.4
#2 lore raw

PATCH v2 3/3 ti-rtos-firmware: add recipe for RTOS FW binary integration

In reply to Denys Dmytriyenko

From: Denys Dmytriyenko <[email protected]>

---
v2 - make use of file prefix and suffix more generic for nightlies

 recipes-ti/ti-rtos-bin/files/empty         |  1 +
 recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb | 76 ++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)
 create mode 100644 recipes-ti/ti-rtos-bin/files/empty
 create mode 100644 recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb
recipes-ti/ti-rtos-bin/files/empty new file +1 -0
new file mode 100644
index 0000000..c6cac69
@@ -0,0 +1 @@
+empty
recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb new file +76 -0

76 lines not on this page · raw message

Signature · 1 line
2.7.4
#3 lore raw

Re: [EXTERNAL] [meta-ti] [dunfell/master][PATCH v2 3/3] ti-rtos-firmware: add recipe for RTOS FW binary integration

Quoted 31 lines · Denys Dmytriyenko

From: Denys Dmytriyenko <[email protected]>

---
v2 - make use of file prefix and suffix more generic for nightlies

  recipes-ti/ti-rtos-bin/files/empty         |  1 +
  recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb | 76 ++++++++++++++++++++++++++++++
  2 files changed, 77 insertions(+)

create mode 100644 recipes-ti/ti-rtos-bin/files/empty create mode 100644 recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb

recipes-ti/ti-rtos-bin/files/empty new file +1 -0
new file mode 100644
index 0000000..c6cac69
@@ -0,0 +1 @@
+empty
recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb new file +6 -0
new file mode 100644
index 0000000..9bfbe74
@@ -0,0 +1,76 @@
+SUMMARY = "TI RTOS prebuilt binary firmware images"
+
+LICENSE = "TI-TFL"
+LIC_FILES_CHKSUM = "file://${COREBASE}/../meta-ti/licenses/TI-TFL;md5=a1b59cb7ba626b9dbbcbf00f3fbc438a"
+
+COMPATIBLE_MACHINE = "k3"

recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb line 16

Quoted 10 lines
recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb new file +10 -0
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+inherit deploy
+
+# First, let's try including metadata.inc that could be fetched and deployed
+# by ti-rtos-metadata earlier and provide new set of CORESDK_RTOS_* variables
+include ${DEPLOY_DIR_IMAGE}/metadata.inc

What controls this dependency? Is it possible to have parsing depend on a recipe task?

Quoted 62 lines
recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb new file +60 -0
+
+# Set some defaults for when metadata.inc is not available
+DEFAULT_RTOS_FAMILY = "jacinto"
+DEFAULT_RTOS_VERSION = "07_01_00_02"
+DEFAULT_RTOS_VERSION_DOT = "07.01.00.02"
+
+DEFAULT_RTOS_SOC = "undefined"
+DEFAULT_RTOS_SOC_j7 = "j721e"
+DEFAULT_RTOS_SOC_j7200-evm = "j7200"
+DEFAULT_RTOS_SOC_am65xx = "am65xx"
+
+DEFAULT_RTOS_WEBLINK = "undefined"
+DEFAULT_RTOS_WEBLINK_j7 = "https://software-dl.ti.com/jacinto7/esd/processor-sdk-rtos-jacinto7/firmware/${CORESDK_RTOS_VERSION}"
+DEFAULT_RTOS_WEBLINK_am65xx = "https://software-dl.ti.com/processor-sdk-rtos/esd/AM65X/firmware/${CORESDK_RTOS_VERSION}"
+
+DEFAULT_FIRMWARE_FILE = "coresdk_rtos_${CORESDK_RTOS_SOC}_${CORESDK_RTOS_VERSION}_firmware.tar.xz"
+
+DEFAULT_FIRMWARE_URL = "file://empty"
+DEFAULT_FIRMWARE_URL_k3 = "${CORESDK_RTOS_WEBLINK}/${DEFAULT_FIRMWARE_FILE}"
+
+DEFAULT_FIRMWARE_SHA256SUM = "unknown"
+DEFAULT_FIRMWARE_SHA256SUM_j7 = "e1e2eb0086a28468f1bb4b796571dcf1bfa23aedbb092bd02227e777a078afe3"
+DEFAULT_FIRMWARE_SHA256SUM_j7200-evm = "218e51739c53e306cc61bbb705b3d8eeae3afb63869f2aa82a4c804f7847bd63"
+DEFAULT_FIRMWARE_SHA256SUM_am65xx = "37188564fbb8420ba9dadb74ecf05b3aac2bf39a0e72c18c23272a141e69ace7"
+
+# Use weak assignment for CORESDK_RTOS_* variables to use defaults if not yet set
+CORESDK_RTOS_FAMILY ?= "${DEFAULT_RTOS_FAMILY}"
+CORESDK_RTOS_VERSION ?= "${DEFAULT_RTOS_VERSION}"
+CORESDK_RTOS_VERSION_DOT ?= "${DEFAULT_RTOS_VERSION_DOT}"
+CORESDK_RTOS_SOC ?= "${DEFAULT_RTOS_SOC}"
+CORESDK_RTOS_WEBLINK ?= "${DEFAULT_RTOS_WEBLINK}"
+CORESDK_RTOS_FIRMWARE_URL ?= "${DEFAULT_FIRMWARE_URL}"
+CORESDK_RTOS_FIRMWARE_SHA256SUM ?= "${DEFAULT_FIRMWARE_SHA256SUM}"
+CORESDK_RTOS_FILE_PREFIX ?= ""
+CORESDK_RTOS_FILE_SUFFIX ?= ""
+
+# Common code below
+S = "${WORKDIR}/lib/"
+
+PV = "${CORESDK_RTOS_VERSION_DOT}"
+
+SRC_URI = "${CORESDK_RTOS_FIRMWARE_URL}${CORESDK_RTOS_FILE_SUFFIX}"
+SRC_URI[sha256sum] = "${CORESDK_RTOS_FIRMWARE_SHA256SUM}"
+
+FILES_${PN} += "${base_libdir}"
+
+do_install() {
+	CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
+	install -d ${D}${base_libdir}
+	cp ${CP_ARGS} ${S} ${D}
+}
+
+FILES_${PN} = "${base_libdir}"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INSANE_SKIP_${PN} += "arch"
+
+do_compile[noexec] = "1"
+do_configure[noexec] = "1"