Skip to contentSkip to conversation

logrotate: Add systemd support

PATCH In review Romain Perier 2 participants 2 messages Apr 13, 2017

lore
Share & tools
lore
#0 lore raw

PATCH v3 1/1 logrotate: Add systemd support

Currently, this recipe only supports daily scheduling via a cron job. This commit adds support for systemd in the recipe, with the corresponding services backported from upstream. When the distro feature is enabled the systemd variant will be used. The timer granularity and its accuracy are also configurable.

---

Changes in v3:
- After a discussion with RP, that's preferable to integrate systemd support in the recipe of logrotate 3.9. QA testing will be passed on it, then we will see if this patch can be merged or delayed to master-next.
- I have backported systemd service and timer from upstream directly
- The bump to 3.11 will wait

 .../logrotate/logrotate/logrotate.service          | 10 ++++++++
 .../logrotate/logrotate/logrotate.timer            | 10 ++++++++
 meta/recipes-extended/logrotate/logrotate_3.9.1.bb | 27 ++++++++++++++++++++--
 3 files changed, 45 insertions(+), 2 deletions(-)
 create mode 100644 meta/recipes-extended/logrotate/logrotate/logrotate.service
 create mode 100644 meta/recipes-extended/logrotate/logrotate/logrotate.timer
meta/recipes-extended/logrotate/logrotate/logrotate.service new file +10 -0
new file mode 100644
index 0000000..cf8d3f4
@@ -0,0 +1,10 @@
+[Unit]
+Description=Rotate log files
+ConditionACPower=true
+
+[Service]
+Type=oneshot
+ExecStart=/usr/sbin/logrotate /etc/logrotate.conf
+Nice=19
+IOSchedulingClass=best-effort
+IOSchedulingPriority=7
meta/recipes-extended/logrotate/logrotate/logrotate.timer new file +10 -0
new file mode 100644
index 0000000..297c2e4
@@ -0,0 +1,10 @@
+[Unit]
+Description=Periodic rotation of log files
+
+[Timer]
+OnCalendar=daily
+AccuracySec=12h
+Persistent=true
+
+[Install]
+WantedBy=timers.target
meta/recipes-extended/logrotate/logrotate_3.9.1.bb +25 -2
index c938d9f..2c254e8 100644
@@ -23,6 +23,8 @@ SRC_URI = "https://github.com/${BPN}/${BPN}/archive/r3-9-1.tar.gz \
            file://act-as-mv-when-rotate.patch \
            file://update-the-manual.patch \
            file://disable-check-different-filesystems.patch \
+           ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'file://logrotate.service', '', d)} \
+           ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'file://logrotate.timer', '', d)} \
             "
 
 SRC_URI[md5sum] = "8572b7c2cf9ade09a8a8e10098500fb3"
@@ -58,12 +60,33 @@ do_compile_prepend() {
     rm -f ${B}/.depend
 }
 
+inherit systemd
+
+SYSTEMD_AUTO_ENABLE = "disable"
+SYSTEMD_SERVICE_${PN} = "\
+    ${PN}.service \
+    ${PN}.timer \
+"
+
+LOGROTATE_SYSTEMD_TIMER_BASIS ?= "daily"
+LOGROTATE_SYSTEMD_TIMER_ACCURACY ?= "12h"
+
 do_install(){
     oe_runmake install DESTDIR=${D} PREFIX=${D} MANDIR=${mandir}
     mkdir -p ${D}${sysconfdir}/logrotate.d
-    mkdir -p ${D}${sysconfdir}/cron.daily
     mkdir -p ${D}${localstatedir}/lib
     install -p -m 644 examples/logrotate-default ${D}${sysconfdir}/logrotate.conf
-    install -p -m 755 examples/logrotate.cron ${D}${sysconfdir}/cron.daily/logrotate
     touch ${D}${localstatedir}/lib/logrotate.status
+
+    # Install systemd unit files
+    if [ "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)}" = "systemd" ]; then
+        install -d ${D}${systemd_system_unitdir}
+        install -m 0644 ${WORKDIR}/logrotate.service ${D}${systemd_system_unitdir}/logrotate.service
+        install -m 0644 ${WORKDIR}/logrotate.timer ${D}${systemd_system_unitdir}/logrotate.timer
+        sed -i -e 's,OnCalendar=.*$,OnCalendar=${LOGROTATE_SYSTEMD_TIMER_BASIS},g' ${D}${systemd_system_unitdir}/logrotate.timer
+        sed -i -e 's,AccuracySec=.*$,AccuracySec=${LOGROTATE_SYSTEMD_TIMER_ACCURACY},g' ${D}${systemd_system_unitdir}/logrotate.timer
+    else
+        mkdir -p ${D}${sysconfdir}/cron.daily
+        install -p -m 0755 examples/logrotate.cron ${D}${sysconfdir}/cron.daily/logrotate
+    fi
 }
Signature · 1 line
2.9.3
#1 lore raw

meta/recipes-extended/logrotate/logrotate/logrotate.service line 7

Quoted 11 lines · Romain Perier
meta/recipes-extended/logrotate/logrotate/logrotate.service new file +7 -0
@@ -0,0 +1,10 @@
+[Unit]
+Description=Rotate log files
+ConditionACPower=true
+
+[Service]
+Type=oneshot
+ExecStart=/usr/sbin/logrotate /etc/logrotate.conf

Hard-coding these paths breaks anyone who wants to change them, use symbols and replace them at build time.

meta/recipes-extended/logrotate/logrotate/logrotate.service line 8

Quoted 2 lines
meta/recipes-extended/logrotate/logrotate/logrotate.service new file +1 -0
+SYSTEMD_AUTO_ENABLE = "disable"

What's the rationale for disabling logrotate by default? The cron script in the sysv case isn't disabled out of the box from what I can tell, so that's a behavioural change based on init.

meta/recipes-extended/logrotate/logrotate/logrotate.service line 10

Quoted 3 lines
meta/recipes-extended/logrotate/logrotate/logrotate.service new file +2 -0
+LOGROTATE_SYSTEMD_TIMER_BASIS ?= "daily"
+LOGROTATE_SYSTEMD_TIMER_ACCURACY ?= "12h"

Do these really need to be variables in the recipe?

+ # Install systemd unit files

Quoted 14 lines

+ if [ "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd',
'', d)}" = "systemd" ]; then

meta/recipes-extended/logrotate/logrotate/logrotate.service new file +2 -0
+        install -d ${D}${systemd_system_unitdir}
+        install -m 0644 ${WORKDIR}/logrotate.service

${D}${systemd_system_unitdir}/logrotate.service
+ install -m 0644 ${WORKDIR}/logrotate.timer
${D}${systemd_system_unitdir}/logrotate.timer
+ sed -i -e 's,OnCalendar=.*$,OnCalendar=${LOGROTATE_SYSTEMD_TIMER_BASIS},g'
${D}${systemd_system_unitdir}/logrotate.timer
+ sed -i -e 's,AccuracySec=.*$,AccuracySec=${LOGROTATE_SYSTEMD_TIMER_ACCURACY},g'
${D}${systemd_system_unitdir}/logrotate.timer

meta/recipes-extended/logrotate/logrotate/logrotate.service new file +3 -0
+    else
+        mkdir -p ${D}${sysconfdir}/cron.daily
+        install -p -m 0755 examples/logrotate.cron
Quoted 3 lines

${D}${sysconfdir}/cron.daily/logrotate
+ fi

This breaks if the DISTRO_FEATURES contains both sysvinit and systemd (so packages should contain the systemd and sysv integration), and different images are generated that use either sysvinit or systemd. With this the cron hooks won't be added but if the package is used under sysv they'll be needed.

Not that I have a good idea for how to solve this. Maybe the cron should check the timer unit isn't running?

Ross