Skip to contentSkip to conversation

libmpdclient: new recipe

PATCH New Max Kellermann 1 participant 7 messages Sep 24, 2018

lore
Share & tools
lore
#0 lore raw

PATCH v4 1/7 libmpdclient: new recipe

From: Max Kellermann <[email protected]>

---
 .../musicpd/libmpdclient_2.15.bb              | 19 +++++++++++++++++++
 1 file changed, 19 insertions(+)
 create mode 100644 meta-multimedia/recipes-multimedia/musicpd/libmpdclient_2.15.bb
meta-multimedia/recipes-multimedia/musicpd/libmpdclient_2.15.bb new file +19 -0
new file mode 100644
index 000000000..c78344c66
@@ -0,0 +1,19 @@
+SUMMARY = "C client library for the Music Player Daemon"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=06b9dfd2f197dc514d8ef06549684b77"
+HOMEPAGE = "https://www.musicpd.org/libs/libmpdclient/"
+
+inherit meson
+
+SRC_URI = " \
+    git://github.com/MusicPlayerDaemon/libmpdclient \
+"
+SRCREV = "7754ffdfb9371cd398371cb2670a54e9e1e623e2"
+S = "${WORKDIR}/git"
+
+do_install_append() {
+    # libmpdclient's Vala bindings are outdated and unmaintained; it
+    # is likely that nobody will ever use them, so let's not install
+    # them
+    rm -rf ${D}${datadir}/vala
+}
Signature · 1 line
2.19.0
#1 lore raw

PATCH v4 2/7 mpc: new recipe

From: Max Kellermann <[email protected]>

---
 .../recipes-multimedia/musicpd/mpc_0.30.bb       | 16 ++++++++++++++++
 1 file changed, 16 insertions(+)
 create mode 100644 meta-multimedia/recipes-multimedia/musicpd/mpc_0.30.bb
meta-multimedia/recipes-multimedia/musicpd/mpc_0.30.bb new file +16 -0
new file mode 100644
index 000000000..6fac5b2e7
@@ -0,0 +1,16 @@
+SUMMARY = "A minimalist command line interface to the Music Player Daemon"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+HOMEPAGE = "https://www.musicpd.org/clients/mpc/"
+
+inherit meson
+
+DEPENDS += " \
+    libmpdclient \
+"
+
+SRC_URI = " \
+    git://github.com/MusicPlayerDaemon/mpc \
+"
+SRCREV = "6fc4e639152daeebb19e0fdfb277252acc734fc5"
+S = "${WORKDIR}/git"
Signature · 1 line
2.19.0
#2 lore raw

PATCH v4 3/7 ncmpc: new recipe

In reply to Max Kellermann

From: Max Kellermann <[email protected]>

---
 .../recipes-multimedia/musicpd/ncmpc_0.32.bb  | 23 +++++++++++++++++++
 1 file changed, 23 insertions(+)
 create mode 100644 meta-multimedia/recipes-multimedia/musicpd/ncmpc_0.32.bb
meta-multimedia/recipes-multimedia/musicpd/ncmpc_0.32.bb new file +23 -0
new file mode 100644
index 000000000..936596a25
@@ -0,0 +1,23 @@
+SUMMARY = "A curses client for the Music Player Daemon"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+HOMEPAGE = "https://www.musicpd.org/clients/ncmpc/"
+
+inherit meson
+
+DEPENDS += " \
+    gettext-native \
+    glib-2.0 \
+    ncurses \
+    libmpdclient \
+"
+
+# We're using a 0.32 pre-release commit which contains a fix for a
+# build failure.
+PV = "0.32~git${SRCPV}"
+
+SRC_URI = " \
+    git://github.com/MusicPlayerDaemon/ncmpc \
+"
+SRCREV = "1150f7931de7588643437069dd798724dc1ceb47"
+S = "${WORKDIR}/git"
Signature · 1 line
2.19.0
#3 lore raw

PATCH v4 4/7 mpd: update 0.20.21

In reply to Max Kellermann

From: Max Kellermann <[email protected]>

---
 .../musicpd/{mpd_0.20.18.bb => mpd_0.20.21.bb}                | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)
 rename meta-multimedia/recipes-multimedia/musicpd/{mpd_0.20.18.bb => mpd_0.20.21.bb} (95%)
meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.21.bb renamed from meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.18.bb +2 -2
similarity index 95%
rename from meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.18.bb
rename to meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.21.bb
index 6754f347e..ab54fe80c 100644
@@ -46,8 +46,8 @@ SRC_URI = " \
     http://www.musicpd.org/download/${BPN}/0.20/${BP}.tar.xz \
     file://mpd.conf.in \
 "
-SRC_URI[md5sum] = "8dc87ba95473fd738f2aff9bd69cc212"
-SRC_URI[sha256sum] = "6a582dc2ae90b94ff3853f9ffd7d80b2c2b5fe2e2c35cb1da0b36f3f3dfad434"
+SRC_URI[md5sum] = "d93c3c86f5e0fc56cc2e1020f80f8b66"
+SRC_URI[sha256sum] = "8322764dc265c20f05c8c8fdfdd578b0722e74626bef56fcd8eebfb01acc58dc"
 
 EXTRA_OECONF = "enable_bzip2=yes"
 EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--with-systemdsystemunitdir=${systemd_unitdir}/system/', '--without-systemdsystemunitdir', d)}"
Signature · 1 line
2.19.0
#4 lore raw

PATCH v4 5/7 mpd: sort PACKAGECONFIGs

In reply to Max Kellermann

From: Max Kellermann <[email protected]>

---
 meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.21.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)
meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.21.bb +1 -1
index ab54fe80c..67a0c9ff8 100644
@@ -54,9 +54,9 @@ EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--with-syst
 
 PACKAGECONFIG[audiofile] = "--enable-audiofile,--disable-audiofile,audiofile"
 PACKAGECONFIG[cdioparanoia] = "--enable-cdio-paranoia,--disable-cdio-paranoia,libcdio-paranoia"
-PACKAGECONFIG[mad] = "--enable-mad,--disable-mad,libmad"
 PACKAGECONFIG[id3tag] = "--enable-id3,--disable-id3,libid3tag"
 PACKAGECONFIG[lame] = "--enable-lame-encoder,--disable-lame-encoder,lame"
+PACKAGECONFIG[mad] = "--enable-mad,--disable-mad,libmad"
 PACKAGECONFIG[smb] = "--enable-smbclient,--disable-smbclient,samba"
 
 do_configure_prepend() {
Signature · 1 line
2.19.0
#5 lore raw

PATCH v4 6/7 mpd: make lots of plugins optional

In reply to Max Kellermann

From: Max Kellermann <[email protected]>

The new options are enabled by default to avoid breaking existing configurations.

---
 .../recipes-multimedia/musicpd/mpd_0.20.21.bb | 44 +++++++++----------
 1 file changed, 22 insertions(+), 22 deletions(-)
meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.21.bb +22 -22
index 67a0c9ff8..ebae8a521 100644
@@ -6,37 +6,15 @@ HOMEPAGE ="http://www.musicpd.org"
 inherit autotools useradd systemd pkgconfig
 
 DEPENDS += " \
-    alsa-lib \
-    libsamplerate0 \
-    libsndfile1 \
-    libvorbis \
-    libogg \
-    faad2 \
-    ffmpeg \
     curl \
     sqlite \
-    bzip2 \
     ${@bb.utils.filter('DISTRO_FEATURES', 'pulseaudio', d)} \
     tcp-wrappers \
-    openal-soft \
     yajl \
-    jack \
-    faad2 \
-    flac \
-    libao \
-    fluidsynth \
-    libcdio \
-    wavpack \
-    libopus \
-    mpg123 \
-    libmms \
-    libmodplug \
     boost \
     icu \
     dbus \
     expat \
-    zlib \
-    libupnp \
 "
 
 # While this item does not require it, it depends on mpg123 which does
@@ -52,12 +30,34 @@ SRC_URI[sha256sum] = "8322764dc265c20f05c8c8fdfdd578b0722e74626bef56fcd8eebfb01a
 EXTRA_OECONF = "enable_bzip2=yes"
 EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--with-systemdsystemunitdir=${systemd_unitdir}/system/', '--without-systemdsystemunitdir', d)}"
 
+PACKAGECONFIG ??= "aac alsa ao bzip2 ffmpeg flac fluidsynth iso9660 jack libsamplerate mms mpg123 modplug sndfile upnp openal opus vorbis wavpack zlib"
+
+PACKAGECONFIG[aac] = "--enable-aac,--disable-aac,faad2"
+PACKAGECONFIG[alsa] = "--enable-alsa,--disable-alsa,alsa-lib"
+PACKAGECONFIG[ao] = "--enable-ao,--disable-ao,libao"
 PACKAGECONFIG[audiofile] = "--enable-audiofile,--disable-audiofile,audiofile"
+PACKAGECONFIG[bzip2] = "--enable-bzip2,--disable-bzip2,bzip2"
 PACKAGECONFIG[cdioparanoia] = "--enable-cdio-paranoia,--disable-cdio-paranoia,libcdio-paranoia"
+PACKAGECONFIG[ffmpeg] = "--enable-ffmpeg,--disable-ffmpeg,ffmpeg"
+PACKAGECONFIG[flac] = "--enable-flac,--disable-flac,flac"
+PACKAGECONFIG[fluidsynth] = "--enable-fluidsynth,--disable-fluidsynth,fluidsynth"
 PACKAGECONFIG[id3tag] = "--enable-id3,--disable-id3,libid3tag"
+PACKAGECONFIG[iso9660] = "--enable-iso9660,--disable-iso9660,libcdio"
+PACKAGECONFIG[jack] = "--enable-jack,--disable-jack,jack"
 PACKAGECONFIG[lame] = "--enable-lame-encoder,--disable-lame-encoder,lame"
+PACKAGECONFIG[libsamplerate] = "--enable-lsr,--disable-lsr,libsamplerate0"
 PACKAGECONFIG[mad] = "--enable-mad,--disable-mad,libmad"
+PACKAGECONFIG[mms] = "--enable-mms,--disable-mms,libmms"
+PACKAGECONFIG[mpg123] = "--enable-mpg123,--disable-mpg123,mpg123"
+PACKAGECONFIG[modplug] = "--enable-modplug,--disable-modplug,libmodplug"
 PACKAGECONFIG[smb] = "--enable-smbclient,--disable-smbclient,samba"
+PACKAGECONFIG[sndfile] = "--enable-sndfile,--disable-sndfile,libsndfile1"
+PACKAGECONFIG[upnp] = "--enable-upnp,--disable-upnp,libupnp"
+PACKAGECONFIG[openal] = "--enable-openal,--disable-openal,openal-soft"
+PACKAGECONFIG[opus] = "--enable-opus,--disable-opus,libopus libogg"
+PACKAGECONFIG[vorbis] = "--enable-vorbis,--disable-vorbis,libvorbis libogg"
+PACKAGECONFIG[wavpack] = "--enable-wavpack,--disable-wavpack,wavpack"
+PACKAGECONFIG[zlib] = "--enable-zlib,--disable-zlib,zlib"
 
 do_configure_prepend() {
     sed -i -e 's|libsystemd-daemon|libsystemd|' ${S}/configure.ac
Signature · 1 line
2.19.0
#6 lore raw

PATCH v4 7/7 mpd: drop LICENSE_FLAGS="commercial"

In reply to Max Kellermann

From: Max Kellermann <[email protected]>

The mpg123 LICENSE_FLAGS have been removed in oe-core commit b0bc82a5f238db82425b3b146e269bc6605cbdce, so we can remove it from MPD as well.

---
 meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.21.bb | 3 ---
 1 file changed, 3 deletions(-)
meta-multimedia/recipes-multimedia/musicpd/mpd_0.20.21.bb +0 -3
index ebae8a521..c0d4c8c2b 100644
@@ -17,9 +17,6 @@ DEPENDS += " \
     expat \
 "
 
-# While this item does not require it, it depends on mpg123 which does
-LICENSE_FLAGS = "commercial"
-
 SRC_URI = " \
     http://www.musicpd.org/download/${BPN}/0.20/${BP}.tar.xz \
     file://mpd.conf.in \
Signature · 1 line
2.19.0