Skip to contentSkip to conversation

bossa-native: Add Arduino variant of the bossa flashing tool

PATCH New Andrei Gherzan 1 participant 2 messages Jan 24, 2022

lore
Share & tools
lore
#0 lore raw

PATCH 1/2 bossa-native: Add Arduino variant of the bossa flashing tool

From: Stefan Schmidt <[email protected]>

This native recipe will be used to streamline the flashing of out Arduino Nano 33 BLE target. Until now we have pointed to the full Arduino IDE to get it installed and setting the PATH correctly before any flashing would work. Having the tool supplied under the hood for flashing will simplify documentation and support.

---
 .../bossa/bossa-native_git.bb                 | 23 +++++++++++++++++++
 1 file changed, 23 insertions(+)
 create mode 100644 meta-zephyr-core/recipes-devtools/bossa/bossa-native_git.bb
meta-zephyr-core/recipes-devtools/bossa/bossa-native_git.bb new file +23 -0
new file mode 100644
index 0000000..b645ecf
@@ -0,0 +1,23 @@
+SUMMARY = "Arduino variant of the BOSSA flashing tool"
+HOMEPAGE = "https://github.com/arduino/BOSSA"
+SECTION = "devel"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=bcf9399f7b9b96149837290bcdc3ad39"
+
+SRC_URI = "git://github.com/arduino/BOSSA.git;protocol=https;branch=nrf"
+
+PV = "1.9.1+git${SRCPV}"
+SRCREV = "89f3556a761833522cd93c199581265ad689310b"
+
+S = "${WORKDIR}/git"
+
+inherit native
+
+do_compile() {
+    # We only compile the bossac commandline tool, not the graphical version.
+    oe_runmake bossac
+}
+
+do_install() {
+    install -D -m 0755 ${B}/bin/bossac ${D}${bindir}/bossac
+}
Signature · 1 line
2.25.1
#1 lore raw

PATCH 2/2 zephyr-flash-bossac.bbclass: Use internal bossac tool instead looking up PATH

From: Stefan Schmidt <[email protected]>

Instead of looking in PATH on the host to find bossac we now depend on the native variant we build and set the path to our yocto build tool.

---
 meta-zephyr-core/classes/zephyr-flash-bossac.bbclass | 9 ++++-----
 1 file changed, 4 insertions(+), 5 deletions(-)
meta-zephyr-core/classes/zephyr-flash-bossac.bbclass +4 -5
index 50222d5..51f2dd3 100644
@@ -1,17 +1,17 @@
 #@DESCRIPTION: class file to flash boards like Arduino Nano BLE which depends on bossac for flashing
 
+DEPENDS += "bossa-native"
+
 python do_flash_usb() {
     import shutil
     import subprocess
     import serial.tools.list_ports
 
-    # Note: make sure the installed bossac is set to PATH before running flash_usb()
     # Check if bossac is avaiable for flashing
-    origbbenv = d.getVar("BB_ORIGENV", False)
-    bossac_path = shutil.which("bossac", path=origbbenv.getVar('PATH'))
+    bossac_path = shutil.which("bossac")
 
     if not bossac_path:
-       bb.fatal("ERROR: bossac not found, please install first and add to PATH")
+       bb.fatal("ERROR: bossac not found.")
 
     board = d.getVar('BOARD')
 
@@ -47,4 +47,3 @@ python do_flash_usb() {
 addtask do_flash_usb after do_deploy
 
 do_flash_usb[nostamp] = "1"
-do_flash_usb[vardepsexclude] = "BB_ORIGENV"
Signature · 1 line
2.25.1