Skip to contentSkip to conversation

recipes-core: Add a bootstrap Linux image

PATCH Superseded Nishanth Menon 2 participants 15 messages Mar 22, 2022 – Mar 23, 2022

v5 of 6 Superseded Latest is v6 →

lore
Share & tools
lore
#0 lore raw

v5 cover recipes-core: Add a bootstrap Linux image

Board bringups are typically painful. however, over the years, folks know of minimal debug tools that are pretty effective in helping debug basic peripherals. Lets create a reusable packagegroup balancing the tools from wisdom from various folks vs the size of the resultant package.

We would like to base such a system on more simplistic sysvinit (no offence systemd, you are still our fav), as it has a much smaller footprint.

The board startup is best done with a minimal u-boot and kernel device tree configurations.

Dependency (for patch #12, depends on https://lore.kernel.org/all/[email protected]/ )

Changes since V4:
* Fixes formatting EoL in Documentation in tisdk-core-bundle (patch #7)
* Fixes build breakage for tisdk-core-image (patch #2)

V4: https://lore.kernel.org/all/[email protected]/
V3: https://lore.kernel.org/all/[email protected]/
V2: https://lore.kernel.org/all/[email protected]/
V1: https://lore.kernel.org/all/[email protected]/

Nishanth Menon (12):
Revert "tisdk-tiny-image: remove packagedata task breaking initramfs
packaging"
tisdk-tiny-image: Split common components into include file
tisdk-tiny-image: Add some usability notes
tisdk-base-image: Reformat documentation and clarify usage
tisdk-default-image: Reformat documentation and clarify usage
tisdk-thinlinux-image: Reformat documentation
tisdk-core-bundle: Add documentation to clarify usage
packagegroups: Add a new bootstrap package group
recipes-core: images: Add a basic bootstrap base image
recipes-bsp: Create a bootstrap-initrd package
recipes-core: images: Introduce tisdk-bootstrap-image
images: Build tisdk-bootstrap-image with tisdk-core-bundle

 .../bootstrap-initrd/bootstrap-initrd_1.0.bb  | 22 ++++++++
 .../recipes-core/images/arago-tiny-image.inc  |  9 ++++
 .../recipes-core/images/tisdk-base-image.bb   |  6 ++-
 .../images/tisdk-bootstrap-base-image.bb      | 22 ++++++++
 .../images/tisdk-bootstrap-image.bb           | 22 ++++++++
 .../recipes-core/images/tisdk-core-bundle.bb  |  7 +++
 .../recipes-core/images/tisdk-core-bundle.inc |  2 +-
 .../images/tisdk-default-image.bb             |  5 +-
 .../images/tisdk-thinlinux-image.bb           |  6 ++-
 .../recipes-core/images/tisdk-tiny-image.bb   | 23 ++++----
 .../packagegroup-arago-bootstrap.bb           | 53 +++++++++++++++++++
 11 files changed, 162 insertions(+), 15 deletions(-)
 create mode 100644 meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb
 create mode 100644 meta-arago-distro/recipes-core/images/arago-tiny-image.inc
 create mode 100644 meta-arago-distro/recipes-core/images/tisdk-bootstrap-base-image.bb
 create mode 100644 meta-arago-distro/recipes-core/images/tisdk-bootstrap-image.bb
 create mode 100644 meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-bootstrap.bb
Signature · 1 line
2.31.1
#1 lore raw

PATCH v5 1/12 Revert "tisdk-tiny-image: remove packagedata task breaking initramfs packaging"

This reverts commit a75e468a372d4f5c2c32a179d4d2219899b5190c.

Commit a75e468a372d ("tisdk-tiny-image: remove packagedata task breaking initramfs packaging") as discussed in [1] is no longer necessary as the offending patches have been reverted in dunfell.

[1] https://lists.yoctoproject.org/g/meta-arago/message/13624

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 meta-arago-distro/recipes-core/images/tisdk-tiny-image.bb | 2 --
 1 file changed, 2 deletions(-)
meta-arago-distro/recipes-core/images/tisdk-tiny-image.bb +0 -2
index c0ef8f247ee7..28da0b60cc35 100644
@@ -13,6 +13,4 @@ IMAGE_INSTALL = " \
 	${ARAGO_TINY_IMAGE_EXTRA_INSTALL} \
 "
 
-deltask do_packagedata
-
 export IMAGE_BASENAME = "tisdk-tiny-image"
Signature · 1 line
2.31.1
#2 lore raw

PATCH v5 2/12 tisdk-tiny-image: Split common components into include file

In reply to Nishanth Menon

Lets split the common pieces for creating a tiny image into an include file. This can then be used to incrementally build additional images as well.

---
Changes since V4:
* IMAGES_FEATURES_remove has been split up allowing for follow on images to control package-management differently.

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 .../recipes-core/images/arago-tiny-image.inc          |  9 +++++++++
 .../recipes-core/images/tisdk-tiny-image.bb           | 11 ++++-------
 2 files changed, 13 insertions(+), 7 deletions(-)
 create mode 100644 meta-arago-distro/recipes-core/images/arago-tiny-image.inc
meta-arago-distro/recipes-core/images/arago-tiny-image.inc new file +9 -0
new file mode 100644
index 000000000000..958dd8bb9399
@@ -0,0 +1,9 @@
+ARAGO_SYSVINIT = "1"
+
+require arago-image.inc
+
+IMAGE_FEATURES_remove = "splash"
+
+IMAGE_INSTALL = " \
+	packagegroup-arago-sysvinit-boot \
+"
meta-arago-distro/recipes-core/images/tisdk-tiny-image.bb +4 -7
index 28da0b60cc35..0500964695a8 100644
@@ -1,15 +1,12 @@
-ARAGO_SYSVINIT = "1"
+ARAGO_TINY_IMAGE_EXTRA_INSTALL ?= ""
 
-require arago-image.inc
+require arago-tiny-image.inc
 
-IMAGE_FEATURES_remove = "package-management splash"
+IMAGE_FEATURES_remove = "package-management"
 
 IMAGE_FSTYPES += "cpio cpio.xz"
 
-ARAGO_TINY_IMAGE_EXTRA_INSTALL ?= ""
-
-IMAGE_INSTALL = " \
-	packagegroup-arago-sysvinit-boot \
+IMAGE_INSTALL += " \
 	${ARAGO_TINY_IMAGE_EXTRA_INSTALL} \
 "
 
Signature · 1 line
2.31.1
#3 lore raw

PATCH v5 3/12 tisdk-tiny-image: Add some usability notes

In reply to Nishanth Menon

Lets clarify the usage of tiny image as something meant as a building block and not something that folks can directly use.

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 .../recipes-core/images/tisdk-tiny-image.bb            | 10 ++++++++++
 1 file changed, 10 insertions(+)
meta-arago-distro/recipes-core/images/tisdk-tiny-image.bb +10 -0
index 0500964695a8..528efa2746b4 100644
@@ -1,3 +1,13 @@
+SUMMARY = "Arago TI SDK super minimal base image for initramfs"
+
+DESCRIPTION = "Image meant for basic boot of linux kernel. Intended as\
+ bare system, this image does not package the kernel in the\
+ standard /boot folder in rootfs. Instead, it provides a base\
+ rootfs allowing kernel to be deployed elsewhere\
+ (tftp/separate boot partition/jtag log etc..) and boot\
+ the image.\
+"
+
 ARAGO_TINY_IMAGE_EXTRA_INSTALL ?= ""
 
 require arago-tiny-image.inc
Signature · 1 line
2.31.1
#4 lore raw

PATCH v5 4/12 tisdk-base-image: Reformat documentation and clarify usage

In reply to Nishanth Menon

Reformat the documentation to indicate the summary and description in a standardized manner.

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 meta-arago-distro/recipes-core/images/tisdk-base-image.bb | 6 ++++--
 1 file changed, 4 insertions(+), 2 deletions(-)
meta-arago-distro/recipes-core/images/tisdk-base-image.bb +4 -2
index 76668831354f..8698816df52d 100644
@@ -1,5 +1,7 @@
-# Arago TI SDK base image with test tools
-# Suitable for initramfs
+SUMMARY = " Arago TI SDK base image with test tools"
+
+DESCRIPTION = "Arago SDK base image suitable for initramfs containing\
+ comprehensive test tools."
 
 require arago-image.inc
 
Signature · 1 line
2.31.1
#5 lore raw

PATCH v5 5/12 tisdk-default-image: Reformat documentation and clarify usage

In reply to Nishanth Menon

Reformat the documentation to indicate the summary and description in a standardized manner.

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 meta-arago-distro/recipes-core/images/tisdk-default-image.bb | 5 ++++-
 1 file changed, 4 insertions(+), 1 deletion(-)
meta-arago-distro/recipes-core/images/tisdk-default-image.bb +4 -1
index 152f8572afcb..a84e752c0402 100644
@@ -1,4 +1,7 @@
-# Arago TI SDK full filesystem image
+SUMMARY = "Arago TI SDK full filesystem image"
+
+DESCRIPTION = "Complete Arago TI SDK filesystem image containing complete\
+ applications and packages to entitle the SoC."
 
 require arago-image.inc
 
Signature · 1 line
2.31.1
#6 lore raw

PATCH v5 6/12 tisdk-thinlinux-image: Reformat documentation

In reply to Nishanth Menon

Reformat the documentation to indicate the summary and description in a standardized manner.

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 .../recipes-core/images/tisdk-thinlinux-image.bb            | 6 ++++--
 1 file changed, 4 insertions(+), 2 deletions(-)
meta-arago-distro/recipes-core/images/tisdk-thinlinux-image.bb +4 -2
index aa732df6b509..dc073d72d063 100644
@@ -1,5 +1,7 @@
-# Arago TI Thin Linux image
-# Minimal bootable image with container to start the next complex system up.
+SUMMARY = "Arago TI SDK Thin Linux image"
+
+DESCRIPTION = "Minimal bootable image with container to start the next\
+ complex system up."
 
 require arago-image.inc
 
Signature · 1 line
2.31.1
#7 lore raw

PATCH v5 7/12 tisdk-core-bundle: Add documentation to clarify usage

In reply to Nishanth Menon

Add documentation to the core-bundle to explain the usage and intent of the build configuration.

---
Changes since V4:
* Added EoL \ to ensure that the documentation is proper (oops..)

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 meta-arago-distro/recipes-core/images/tisdk-core-bundle.bb | 7 +++++++
 1 file changed, 7 insertions(+)
meta-arago-distro/recipes-core/images/tisdk-core-bundle.bb +7 -0
index 253bfbb68657..9ebcbb0e7e69 100644
@@ -1,3 +1,10 @@
+SUMMARY = "Installer package for TI SDK - NOT for direct use on target"
+
+DESCRIPTION = "This creates an installer including all the default images\
+ recommended including source, binaries, filesystems, etc.\
+ for TI SDK. This is meant to be used on the host system.\
+"
+
 require tisdk-core-bundle.inc
 
 DEPLOY_SPL_NAME_omapl138 = ""
Signature · 1 line
2.31.1
#8 lore raw

PATCH v5 8/12 packagegroups: Add a new bootstrap package group

In reply to Nishanth Menon

Lets try and create a minimal package group for board bringup. Lets call this basic system necessary for board bringup as "bootstrap".

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 .../packagegroup-arago-bootstrap.bb           | 53 +++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-bootstrap.bb
meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-bootstrap.bb new file +53 -0
new file mode 100644
index 000000000000..9d961c282c5d
@@ -0,0 +1,53 @@
+SUMMARY = "Task to install additional utilities for initial board bringup"
+LICENSE = "MIT"
+PR = "r0"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+UTILS = " \
+	 arm-benchmarks \
+	 evtest \
+	 memtester \
+	 nbench-byte \
+	 pcitest \
+	 serialcheck \
+	 yavta \
+	 hdparm \
+	 i2c-tools \
+	 libdrm-tests \
+	 rt-tests \
+	 iozone3 \
+	 mtd-utils-ubifs-tests \
+	 net-tools \
+	 ethtool  \
+	 pciutils \
+	 rng-tools \
+	 stress-ng \
+	 iperf \
+	 lmbench \
+	 usbutils \
+	 devmem2 \
+	 phytool \
+"
+
+UTILS_append_ti33x = " \
+    omapconf \
+"
+
+UTILS_append_ti43x = " \
+    omapconf \
+"
+
+UTILS_append_omap-a15 = " \
+    omapconf \
+"
+
+UTILS_append_k3 = " \
+    k3conf \
+"
+
+RDEPENDS_${PN} = "\
+    ${UTILS} \
+"
Signature · 1 line
2.31.1
#9 lore raw

PATCH v5 9/12 recipes-core: images: Add a basic bootstrap base image

In reply to Nishanth Menon

Since we do not wish to modify the tiny-image from anything but really tiny, lets use that infrastructure and add the bootstrap package group to create initramfs (not exactly a completely usable system) which can be used for basic board bringup.

This generates cpio around 36-40MB which should be usually fine for even smaller systems (Ofcourse, this is much larger than tiny-image which is around 6MB size). The packages are organized per size to allow easier customization if desired.

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/#t

 .../images/tisdk-bootstrap-base-image.bb      | 22 +++++++++++++++++++
 1 file changed, 22 insertions(+)
 create mode 100644 meta-arago-distro/recipes-core/images/tisdk-bootstrap-base-image.bb
meta-arago-distro/recipes-core/images/tisdk-bootstrap-base-image.bb new file +22 -0
new file mode 100644
index 000000000000..8b7f10c9f343
@@ -0,0 +1,22 @@
+SUMMARY = "Arago TI SDK bootstrap base image for initramfs"
+
+DESCRIPTION = "Image meant for basic system verification of linux kernel.\
+ Intended as basic test system, this image does not package the kernel\
+ in the standard /boot folder in rootfs. Instead, it provides a base\
+ rootfs with enough basic board bringup utilities allowing kernel to be\
+ deployed elsewhere (tftp/separate boot partition/jtag log etc..) and\
+ maybe used for basic platform bringup (bootstrap) activities.\
+"
+
+require arago-tiny-image.inc
+
+IMAGE_FSTYPES += "cpio cpio.xz"
+
+ARAGO_BOOTSTRAP_IMAGE_EXTRA_INSTALL ?= ""
+
+IMAGE_INSTALL += " \
+	packagegroup-arago-bootstrap \
+	${ARAGO_BOOTSTRAP_IMAGE_EXTRA_INSTALL} \
+"
+
+export IMAGE_BASENAME = "tisdk-bootstrap-base-image"
Signature · 1 line
2.31.1
#10 lore raw

PATCH v5 10/12 recipes-bsp: Create a bootstrap-initrd package

In reply to Nishanth Menon

Lets create an bootstrap-initrd package that installs the cpio generated in the correct locations.

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 .../bootstrap-initrd/bootstrap-initrd_1.0.bb  | 22 +++++++++++++++++++
 1 file changed, 22 insertions(+)
 create mode 100644 meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb
meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb new file +22 -0
new file mode 100644
index 000000000000..2a53efcd9062
@@ -0,0 +1,22 @@
+SUMMARY = "Prebuilt initramfs with apps for bootstraping new board"
+
+LICENSE = "GPLv2"
+
+CLEANBROKEN = "1"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+S = "${WORKDIR}"
+
+BOOSTRAP_IMAGE="tisdk-bootstrap-base-image"
+
+TARGET = "bootstrap-rootfs-${MACHINE}.cpio"
+
+do_install() {
+	install -d ${D}/boot
+	install -m 0644 ${DEPLOY_DIR_IMAGE}/${BOOSTRAP_IMAGE}-${MACHINE}.cpio  ${D}/boot/${TARGET}
+}
+
+FILES_${PN} = "/boot"
+
+do_install[depends] = "${BOOSTRAP_IMAGE}:do_image_complete"
Signature · 1 line
2.31.1
#11 lore raw

Re: [master/dunfell PATCH V5 10/12] recipes-bsp: Create a bootstrap-initrd package

Quoted 19 lines · Nishanth Menon

Lets create an bootstrap-initrd package that installs the cpio generated in the correct locations.

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 .../bootstrap-initrd/bootstrap-initrd_1.0.bb  | 22 +++++++++++++++++++
 1 file changed, 22 insertions(+)
 create mode 100644 meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb
meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb new file +0 -0
new file mode 100644
index 000000000000..2a53efcd9062

meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb line 3

Quoted 3 lines
meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb new file +3 -0
@@ -0,0 +1,22 @@
+SUMMARY = "Prebuilt initramfs with apps for bootstraping new board"
+
+LICENSE = "GPLv2"

I was wondering about the same question I raised in another thread about the license[1]:

Default license for OpenEmbedded metadata is MIT, not GPLv2. Any specific reason for the change?

[1] https://patchwork.yoctoproject.org/project/ti/patch/[email protected]/

Quoted 21 lines
meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb new file +18 -0
+CLEANBROKEN = "1"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+S = "${WORKDIR}"
+
+BOOSTRAP_IMAGE="tisdk-bootstrap-base-image"
+
+TARGET = "bootstrap-rootfs-${MACHINE}.cpio"
+
+do_install() {
+	install -d ${D}/boot
+	install -m 0644 ${DEPLOY_DIR_IMAGE}/${BOOSTRAP_IMAGE}-${MACHINE}.cpio  ${D}/boot/${TARGET}
+}
+
+FILES_${PN} = "/boot"
+
+do_install[depends] = "${BOOSTRAP_IMAGE}:do_image_complete"
Signature · 1 line
2.31.1
Signature · 4 lines
Regards,
Denys Dmytriyenko <[email protected]>
PGP: 0x420902729A92C964 - https://denix.org/0x420902729A92C964
Fingerprint: 25FC E4A5 8A72 2F69 1186  6D76 4209 0272 9A92 C964
#12 lore raw

Re: [master/dunfell PATCH V5 10/12] recipes-bsp: Create a bootstrap-initrd package

Quoted 27 lines · Denys Dmytriyenko
Quoted 19 lines · Nishanth Menon

Lets create an bootstrap-initrd package that installs the cpio generated in the correct locations.

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 .../bootstrap-initrd/bootstrap-initrd_1.0.bb  | 22 +++++++++++++++++++
 1 file changed, 22 insertions(+)
 create mode 100644 meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb
meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb new file +0 -0
new file mode 100644
index 000000000000..2a53efcd9062

meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb line 3

Quoted 3 lines
meta-arago-distro/recipes-bsp/bootstrap-initrd/bootstrap-initrd_1.0.bb new file +3 -0
@@ -0,0 +1,22 @@
+SUMMARY = "Prebuilt initramfs with apps for bootstraping new board"
+
+LICENSE = "GPLv2"

I was wondering about the same question I raised in another thread about the license[1]:

Quoted 4 lines

Default license for OpenEmbedded metadata is MIT, not GPLv2. Any specific reason for the change?

[1] https://patchwork.yoctoproject.org/project/ti/patch/[email protected]/

Aaah.. Thanks for pointing it out.. no specific reason why I picked GPLV2 other than that as a kernel dev, that is what comes to mind as default ;)..

It should follow the standard convention of MIT.

Let me know if I need to send a V6 with the fixup, I am guessing switching it over to LICENSE = "MIT" should do the job.. (I'd rather be explicit).

Signature · 3 lines
Regards,
Nishanth Menon
Key (0xDDB5849D1736249D) / Fingerprint: F8A2 8693 54EB 8232 17A3  1A34 DDB5 849D 1736 249D
#13 lore raw

PATCH v5 11/12 recipes-core: images: Introduce tisdk-bootstrap-image

In reply to Nishanth Menon

Lets introduce tisdk-bootstrap-image which now consists of a completely bootable system with minimal initramfs that can be used to boot up a system. We also will create a rootfs that matches with the initramfs to allow users who use mmc and other boot media to have access to the same debug tools for a new platform bringup

---
Changes since V4: None

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 .../images/tisdk-bootstrap-image.bb           | 22 +++++++++++++++++++
 1 file changed, 22 insertions(+)
 create mode 100644 meta-arago-distro/recipes-core/images/tisdk-bootstrap-image.bb
meta-arago-distro/recipes-core/images/tisdk-bootstrap-image.bb new file +22 -0
new file mode 100644
index 000000000000..b41f09fb0ec7
@@ -0,0 +1,22 @@
+SUMMARY = "Arago TI SDK bootstrap image usable for board bringup"
+
+DESCRIPTION = "This image is a complete package containing a rootfs\
+ and an initrd with platform test utilities that can be used for new\
+ platform bringup activities. Typically one would use the bootstrap\
+ initrd till the storage media access is debugged, following which one\
+ would switch over to using the storage media of choice with the same\
+ content.\
+"
+
+require arago-tiny-image.inc
+
+ARAGO_BOOTSTRAP_IMAGE_EXTRA_INSTALL ?= ""
+
+IMAGE_INSTALL += " \
+	packagegroup-arago-bootstrap \
+	kernel-base \
+	bootstrap-initrd \
+	${ARAGO_BOOTSTRAP_IMAGE_EXTRA_INSTALL} \
+"
+
+export IMAGE_BASENAME = "tisdk-bootstrap-image"
Signature · 1 line
2.31.1
#14 lore raw

PATCH v5 12/12 images: Build tisdk-bootstrap-image with tisdk-core-bundle

In reply to Nishanth Menon

Add tisdk-bootstrap-image to the list of TARGET_IMAGES for tisdk-core-bundle.

---
Changes since V4: None
* Note the change required for this to work is done in #2 in the series.
should address https://lore.kernel.org/yocto-meta-arago/20220322134750.4tragiw5vpxdxko7@outrank/

V4: https://lore.kernel.org/yocto-meta-arago/[email protected]/

 meta-arago-distro/recipes-core/images/tisdk-core-bundle.inc | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)
meta-arago-distro/recipes-core/images/tisdk-core-bundle.inc +1 -1
index 5ce688ef24b7..db73abd27fc2 100644
@@ -32,7 +32,7 @@ DTB_FILTER_am65xx = "am65"
 DTB_FILTER_j7 = "j721e"
 
 # List of target side images to build for the SDK
-TARGET_IMAGES = "tisdk-base-image tisdk-default-image tisdk-thinlinux-image"
+TARGET_IMAGES = "tisdk-base-image tisdk-default-image tisdk-thinlinux-image tisdk-bootstrap-image"
 
 # dra71 lcard requires an initramfs with modules for NFS boot
 TARGET_IMAGES_append_dra7xx-evm = " netboot-initrd"
Signature · 1 line
2.31.1