Skip to contentSkip to conversation

support: add libmxml 3.3.1 recipe

PATCH In review Clément Péron 3 participants 4 messages Apr 21, 2023

lore
Share & tools
lore
#0 lore raw

PATCH v2 1/2 support: add libmxml 3.3.1 recipe

libmxml is required by new version of gator-daemon as it has been removed from the package and is now an explicit dependency.

This is a duplicate of the recipe present in meta-oe layer.

---
 .../recipes-support/libmxml/libmxml_3.3.1.bb  | 33 +++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 meta-arm/recipes-support/libmxml/libmxml_3.3.1.bb
meta-arm/recipes-support/libmxml/libmxml_3.3.1.bb new file +33 -0
new file mode 100644
index 00000000..b81050b2
@@ -0,0 +1,33 @@
+DESCRIPTION = "Tiny XML Library"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
+HOMEPAGE = "https://www.msweet.org/mxml/"
+BUGTRACKER = "https://github.com/michaelrsweet/mxml/issues"
+
+SRC_URI = "git://github.com/michaelrsweet/mxml.git;nobranch=1;protocol=https"
+SRCREV = "fd47c7d115191c8a6bce2c781ffee41e179530f2"
+S = "${WORKDIR}/git"
+
+inherit autotools
+
+PACKAGECONFIG ??= "threads"
+PACKAGECONFIG[threads] = "--enable-threads,--disable-threads"
+
+# Package does not support out of tree builds.
+B = "${S}"
+
+# MXML uses autotools but it explicitly states it does not support autoheader.
+EXTRA_AUTORECONF = "--exclude=autopoint,autoheader"
+
+do_configure:prepend() {
+    # Respect optimization CFLAGS specified by OE.
+    sed -e 's/-Os -g//' -i ${S}/configure.ac
+
+    # Enable verbose compilation output. This is required for extra QA checks to work.
+    sed -e '/.SILENT:/d' -i ${S}/Makefile.in
+}
+
+do_install() {
+    # Package uses DSTROOT instread of standard DESTDIR to specify install location.
+    oe_runmake install DSTROOT=${D}
+}
Signature · 1 line
2.40.0
#1 lore raw

PATCH v2 2/2 gator-daemon: bump to 8.4.0

Gator Daemon moved to CMake build system so update the recipe

Remove Apache-2.0 license as mxml has been moved out of this package

Drop patches that has been merged

---
 .../0001-Include-missing-cstdint.patch        | 32 -------------------
 .../0001-daemon-mxml-Define-_GNU_SOURCE.patch | 31 ------------------
 ...-daemon_7.8.0.bb => gator-daemon_8.4.0.bb} | 21 ++++--------
 3 files changed, 7 insertions(+), 77 deletions(-)
 delete mode 100644 meta-arm/recipes-devtools/gator-daemon/gator-daemon/0001-Include-missing-cstdint.patch
 delete mode 100644 meta-arm/recipes-devtools/gator-daemon/gator-daemon/0001-daemon-mxml-Define-_GNU_SOURCE.patch
 rename meta-arm/recipes-devtools/gator-daemon/{gator-daemon_7.8.0.bb => gator-daemon_8.4.0.bb} (51%)
meta-arm/recipes-devtools/gator-daemon/gator-daemon/0001-Include-missing-cstdint.patch deleted +0 -32
deleted file mode 100644
index 294f804f..00000000
@@ -1,32 +0,0 @@
-From 87745a6cad0f7819ac8f8d3826f5e228ebd843c5 Mon Sep 17 00:00:00 2001
-From: Khem Raj <[email protected]>
-Date: Thu, 2 Feb 2023 16:39:26 -0800
-Subject: [PATCH] Include missing <cstdint>
-
-gcc 13 moved some includes around and as a result <cstdint> is no
-longer transitively included [1]. Explicitly include it
-for uintXX_t.
-
-[1] https://gcc.gnu.org/gcc-13/porting_to.html#header-dep-changes
-
-Upstream-Status: Submitted [https://github.com/ARM-software/gator/pull/40]
-Signed-off-by: Khem Raj <[email protected]>
----
- daemon/xml/CurrentConfigXML.h | 1 +
- 1 file changed, 1 insertion(+)
-
-diff --git a/daemon/xml/CurrentConfigXML.h b/daemon/xml/CurrentConfigXML.h
-index 0b239fd..d9047e3 100644
---- a/daemon/xml/CurrentConfigXML.h
-+++ b/daemon/xml/CurrentConfigXML.h
-@@ -1,6 +1,7 @@
- /* Copyright (C) 2020-2021 by Arm Limited. All rights reserved. */
- #pragma once
- 
-+#include <cstdint>
- #include <set>
- #include <string>
- 
--- 
-2.39.1
-
meta-arm/recipes-devtools/gator-daemon/gator-daemon/0001-daemon-mxml-Define-_GNU_SOURCE.patch deleted +0 -31
deleted file mode 100644
index d2460434..00000000
@@ -1,31 +0,0 @@
-From 04e2e924c3ab8da41343277746804dbcd7bf520d Mon Sep 17 00:00:00 2001
-From: Khem Raj <[email protected]>
-Date: Sat, 13 Aug 2022 16:49:52 -0700
-Subject: [PATCH] daemon/mxml: Define _GNU_SOURCE
-
-This file uses vasprintf() which is defined only with _GNU_SOURCE
-feature macro is on.
-
-Upstream-Status: Pending
-
-Signed-off-by: Khem Raj <[email protected]>
----
- daemon/mxml/mxml-string.c | 2 ++
- 1 file changed, 2 insertions(+)
-
-diff --git a/daemon/mxml/mxml-string.c b/daemon/mxml/mxml-string.c
-index 678aeb9..c9cd153 100644
---- a/daemon/mxml/mxml-string.c
-+++ b/daemon/mxml/mxml-string.c
-@@ -13,6 +13,8 @@
-  * Include necessary headers...
-  */
- 
-+#define _GNU_SOURCE
-+
- #include "config.h"
- 
- 
--- 
-2.37.2
-
meta-arm/recipes-devtools/gator-daemon/gator-daemon_8.4.0.bb renamed from meta-arm/recipes-devtools/gator-daemon/gator-daemon_7.8.0.bb +7 -14
similarity index 51%
rename from meta-arm/recipes-devtools/gator-daemon/gator-daemon_7.8.0.bb
rename to meta-arm/recipes-devtools/gator-daemon/gator-daemon_8.4.0.bb
index 6188b07e..586b3ce8 100644
@@ -8,28 +8,21 @@ HOMEPAGE = "https://github.com/ARM-software/gator"
 # configuration requirement specified here:
 # https://github.com/ARM-software/gator#kernel-configuration
 
-LICENSE = "GPL-2.0-only & LGPL-2.1-or-later & Apache-2.0"
+LICENSE = "GPL-2.0-only & LGPL-2.1-or-later"
 LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
                     file://libsensors/COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c \
-                    file://mxml/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
                     file://k/perf_event.h;endline=14;md5=e548bf30a60b2ed11ef2dcf7bfdac230 \
                    "
 
-SRCREV = "6a944e7ee1f1c3ab9b2a57efd24c58503122db02"
-SRC_URI = "git://github.com/ARM-software/gator.git;protocol=http;branch=main;protocol=https \
-           file://0001-daemon-mxml-Define-_GNU_SOURCE.patch;striplevel=2 \
-           file://0001-Include-missing-cstdint.patch;striplevel=2 \
-          "
+SRCREV = "75662ba2dc2e1c7a17cff640a35629dca99c5b79"
+SRC_URI = "git://github.com/ARM-software/gator.git;protocol=http;branch=main;protocol=https"
 
 S = "${WORKDIR}/git/daemon"
 
+DEPENDS = "boost libmxml pkgconfig-native protobuf protobuf-native"
+
 COMPATIBLE_HOST = "aarch64.*-linux"
 
-EXTRA_OEMAKE = "'CFLAGS=${CFLAGS} ${TARGET_CC_ARCH} -D_DEFAULT_SOURCE -DETCDIR=\"${sysconfdir}\"' \
-                'LDFLAGS=${LDFLAGS} ${TARGET_CC_ARCH}' 'CROSS_COMPILE=${TARGET_PREFIX}' \
-                'CXXFLAGS=${CXXFLAGS} ${TARGET_CC_ARCH} -fno-rtti' CC='${CC}' CXX='${CXX}' V=1"
+inherit cmake
 
-do_install() {
-        install -d ${D}${sbindir}
-        install -m 0755 ${S}/gatord ${D}${sbindir}/gatord
-}
+EXTRA_OECMAKE += "-DENABLE_VCPKG=OFF -DGATOR_INSTALL_PREFIX=./bin"
Signature · 1 line
2.40.0
#2 lore raw
In reply to Clément Péron
Quoted 6 lines · Clément Péron via lists.yoctoproject.org

libmxml is required by new version of gator-daemon as it has been removed from the package and is now an explicit dependency.

This is a duplicate of the recipe present in meta-oe layer.

I get Denys’s objection to *requiring* meta-oe in meta-arm, but I don’t want to start copying recipes from meta-oe every time we need something from there.

I feel a better solution here would be to use dynamic-layers in meta-arm. Denys, would you be okay with that?

Ross

#3 lore raw
Quoted 6 lines · Ross Burton
Quoted 5 lines · Clément Péron via lists.yoctoproject.org

libmxml is required by new version of gator-daemon as it has been removed from the package and is now an explicit dependency.

Quoted 8 lines
Quoted 1 line

This is a duplicate of the recipe present in meta-oe layer.

I get Denys’s objection to *requiring* meta-oe in meta-arm, but I don’t want to start copying recipes from meta-oe every time we need something from there.

I feel a better solution here would be to use dynamic-layers in meta-arm. Denys, would you be okay with that?

Placing gator-daemon into dynamic-layers? Sure, meta-ti BSP is currently not using it, so the dependency won't be affected. Not sure about other BSPs depending on meta-arm though, but overall it's probably the most flexible soltion.

Signature · 1 line
Denys