Skip to contentSkip to conversation

vulkan-validation-layers: add new recipe v1.2.182.0

PATCH In review Vincent Davis Jr 2 participants 3 messages Jun 9, 2023 Arm i.MX and Layerscape

lore
Share & tools
lore
#0 lore raw

PATCH 1/2 vulkan-validation-layers: add new recipe v1.2.182.0

Add a recipe to build the Khronos official Vulkan validation layers that can assist developers in verifying that their applications correctly use the Vulkan APIs.

Using vulkan version v1.2.182.0 to be compatible with other recipes in meta-freescale layer.

---
 .../vulkan-validation-layers_1.2.182.0.bb     | 52 +++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 recipes-downgrade/vulkan/vulkan-validation-layers_1.2.182.0.bb
recipes-downgrade/vulkan/vulkan-validation-layers_1.2.182.0.bb new file +52 -0
new file mode 100644
index 00000000..abcaf5dc
@@ -0,0 +1,52 @@
+SUMMARY = "Vulkan Validation layers"
+DESCRIPTION = "Khronos official Vulkan validation layers to assist developers \
+in verifying that their applications correctly use the Vulkan API"
+HOMEPAGE = "https://www.khronos.org/vulkan/"
+BUGTRACKER = "https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+SECTION = "libs"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=8df9e8826734226d08cb412babfa599c"
+
+SRC_URI = "git://[email protected]/KhronosGroup/Vulkan-ValidationLayers.git;branch=sdk-1.2.182;protocol=https"
+SRCREV = "91fcffa8eca1a9573c8d736a54a028035ed4e06c"
+
+S = "${WORKDIR}/git"
+
+REQUIRED_DISTRO_FEATURES = "vulkan"
+
+DEPENDS = "vulkan-headers vulkan-loader spirv-headers spirv-tools glslang"
+
+# BUILD_TESTS            - Not required for OE builds
+# BUILD_WERROR           - There are too many compiler warnings/errors due to upgrades in version
+#                          of clang. Requiring a number of patches from upstream. Disable compiler
+#                          -Werror to bypass build issues.
+# USE_ROBIN_HOOD_HASHING - Provides substantial performance improvements on all platforms.
+#                          Yocto project doesn't contain a recipe for package so disabled it.
+EXTRA_OECMAKE = "\
+    -DBUILD_TESTS=OFF \
+    -DBUILD_WERROR=OFF \
+    -DUSE_ROBIN_HOOD_HASHING=OFF \
+    -DGLSLANG_INSTALL_DIR=${STAGING_LIBDIR} \
+    -DVULKAN_HEADERS_INSTALL_DIR=${STAGING_DATADIR} \
+    -DSPIRV_HEADERS_INSTALL_DIR=${STAGING_DATADIR} \
+    "
+
+PACKAGECONFIG[x11] = "-DBUILD_WSI_XLIB_SUPPORT=ON -DBUILD_WSI_XCB_SUPPORT=ON, -DBUILD_WSI_XLIB_SUPPORT=OFF -DBUILD_WSI_XCB_SUPPORT=OFF, libxcb libx11 libxrandr"
+PACKAGECONFIG[wayland] = "-DBUILD_WSI_WAYLAND_SUPPORT=ON, -DBUILD_WSI_WAYLAND_SUPPORT=OFF, wayland"
+
+PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'x11 wayland', d)}"
+
+inherit cmake features_check pkgconfig
+
+FILES:${PN} += "${datadir}/vulkan"
+
+SOLIBS = ".so"
+FILES_SOLIBSDEV = ""
+
+# These recipes need to be updated in lockstep with each other:
+# glslang, vulkan-headers, vulkan-loader, vulkan-tools,
+# vulkan-validation-layers, spirv-headers, spirv-tools
+# The tags versions should always be sdk-x.y.z, as this is what
+# upstream considers a release.
+UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"
Signature · 1 line
2.34.1
#1 lore raw

PATCH 2/2 imx-base: set PREFERRED_VERSION_vulkan-validation-layers

---
 conf/machine/include/imx-base.inc | 7 ++++---
 1 file changed, 4 insertions(+), 3 deletions(-)
conf/machine/include/imx-base.inc +4 -3
index 18fe65f6..d88ea44a 100644
@@ -534,9 +534,10 @@ PREFERRED_VERSION_libdrm:mx7-nxp-bsp ??= "2.4.114.imx"
 PREFERRED_VERSION_libdrm:mx8-nxp-bsp ??= "2.4.114.imx"
 PREFERRED_VERSION_libdrm:mx9-nxp-bsp ??= "2.4.114.imx"
 
-PREFERRED_VERSION_vulkan-headers:imxvulkan ??= "1.2.182.0"
-PREFERRED_VERSION_vulkan-loader:imxvulkan  ??= "1.2.182.0"
-PREFERRED_VERSION_vulkan-tools:imxvulkan   ??= "1.2.182.0"
+PREFERRED_VERSION_vulkan-headers:imxvulkan           ??= "1.2.182.0"
+PREFERRED_VERSION_vulkan-loader:imxvulkan            ??= "1.2.182.0"
+PREFERRED_VERSION_vulkan-tools:imxvulkan             ??= "1.2.182.0"
+PREFERRED_VERSION_vulkan-validation-layers:imxvulkan ??= "1.2.182.0"
 
 # Use i.MX optee Version
 PREFERRED_VERSION_optee-os:mx8-nxp-bsp     ??= "3.19.0.imx"
Signature · 1 line
2.34.1
#2 lore raw

Re: [meta-freescale] [PATCH 2/2] imx-base: set PREFERRED_VERSION_vulkan-validation-layers

Vincent,

thank you for sending the patches. Please open a pull request so we discuss it there.

Em sex., 9 de jun. de 2023 às 17:56, Vincent Davis Jr <[email protected]> escreveu:

Quoted 39 lines
---
 conf/machine/include/imx-base.inc | 7 ++++---
 1 file changed, 4 insertions(+), 3 deletions(-)
conf/machine/include/imx-base.inc +4 -4
index 18fe65f6..d88ea44a 100644
@@ -534,9 +534,10 @@ PREFERRED_VERSION_libdrm:mx7-nxp-bsp ??= "2.4.114.imx"
 PREFERRED_VERSION_libdrm:mx8-nxp-bsp ??= "2.4.114.imx"
 PREFERRED_VERSION_libdrm:mx9-nxp-bsp ??= "2.4.114.imx"
 
-PREFERRED_VERSION_vulkan-headers:imxvulkan ??= "1.2.182.0"
-PREFERRED_VERSION_vulkan-loader:imxvulkan  ??= "1.2.182.0"
-PREFERRED_VERSION_vulkan-tools:imxvulkan   ??= "1.2.182.0"
+PREFERRED_VERSION_vulkan-headers:imxvulkan           ??= "1.2.182.0"
+PREFERRED_VERSION_vulkan-loader:imxvulkan            ??= "1.2.182.0"
+PREFERRED_VERSION_vulkan-tools:imxvulkan             ??= "1.2.182.0"
+PREFERRED_VERSION_vulkan-validation-layers:imxvulkan ??= "1.2.182.0"
 
 # Use i.MX optee Version
 PREFERRED_VERSION_optee-os:mx8-nxp-bsp     ??= "3.19.0.imx"
--

2.34.1

-=-=-=-=-=-=-=-=-=-=-=-
Links: You receive all messages sent to this group. View/Reply Online (#24919):
https://lists.yoctoproject.org/g/meta-freescale/message/24919
Mute This Topic: https://lists.yoctoproject.org/mt/99437621/3617537
Group Owner: [email protected]
Unsubscribe: https://lists.yoctoproject.org/g/meta-freescale/unsub [ [email protected]]
-=-=-=-=-=-=-=-=-=-=-=-

Signature · 3 lines
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9 9981-7854          Mobile: +1 (347) 903-9750