Skip to contentSkip to conversation

x11-volatiles: register x11 volatile directories

PATCH New [email protected] 1 participant 1 message Oct 30, 2025

lore
Share & tools
lore
#0 lore raw

PATCH v2 1/1 x11-volatiles: register x11 volatile directories

From: Randolph Sapp <[email protected]>

Add a volatiles entry for popular x11 and adjacent utilities. This is designed to mimic the systemd tmpfiles.d entries and prevent any one user from creating these directories with permissions that may negatively impact multi-user environments.

---

v2:

	Drop bin_package and use allarch as requested. Manually specify 
	do_configure[noexec] = "1"
	do_compile[noexec] = "1"

	To match old behavior.
 meta/conf/distro/include/maintainers.inc      |  1 +
 .../x11-common/x11-volatiles.bb               | 23 +++++++++++++++++++
 .../x11-common/x11-volatiles/02_x11           |  6 +++++
 .../xorg-xserver/xserver-xorg_21.1.18.bb      |  2 ++
 .../xwayland/xwayland_24.1.8.bb               |  2 +-
 5 files changed, 33 insertions(+), 1 deletion(-)
 create mode 100644 meta/recipes-graphics/x11-common/x11-volatiles.bb
 create mode 100644 meta/recipes-graphics/x11-common/x11-volatiles/02_x11
meta/conf/distro/include/maintainers.inc +1 -0
index c4142e2b72..6902bc0c44 100644
@@ -886,6 +886,7 @@ RECIPE_MAINTAINER:pn-wic-tools = "Unassigned <[email protected]>"
 RECIPE_MAINTAINER:pn-wireless-regdb = "Unassigned <[email protected]>"
 RECIPE_MAINTAINER:pn-wpa-supplicant = "Unassigned <[email protected]>"
 RECIPE_MAINTAINER:pn-wpebackend-fdo = "Unassigned <[email protected]>"
+RECIPE_MAINTAINER:pn-x11-volatiles = "Unassigned <[email protected]>"
 RECIPE_MAINTAINER:pn-x11perf = "Unassigned <[email protected]>"
 RECIPE_MAINTAINER:pn-x264 = "Unassigned <[email protected]>"
 RECIPE_MAINTAINER:pn-xauth = "Unassigned <[email protected]>"
meta/recipes-graphics/x11-common/x11-volatiles.bb new file +23 -0
new file mode 100644
index 0000000000..3eddc12152
@@ -0,0 +1,23 @@
+SUMMARY = "Xserver Volatile Directories"
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0-only;md5=801f80980d171dd6425610833a22dbe6"
+SECTION = "x11"
+
+SRC_URI = "file://02_x11"
+
+S = "${UNPACKDIR}"
+
+inherit allarch features_check
+
+REQUIRED_DISTRO_FEATURES = "x11"
+CONFLICT_DISTRO_FEATURES = "systemd"
+
+do_install() {
+	install -d ${D}${sysconfdir}/default/volatiles
+	install -m 0644 ${UNPACKDIR}/02_x11 ${D}${sysconfdir}/default/volatiles
+}
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+FILES:${PN} += "${sysconfdir}/default/volatiles"
meta/recipes-graphics/x11-common/x11-volatiles/02_x11 new file +6 -0
new file mode 100644
index 0000000000..35c3698479
@@ -0,0 +1,6 @@
+# Volatile entries to match systemd
+# https://github.com/systemd/systemd/blob/main/tmpfiles.d/x11.conf
+d root root 1777 /tmp/.X11-unix none
+d root root 1777 /tmp/.ICE-unix none
+d root root 1777 /tmp/.XIM-unix none
+d root root 1777 /tmp/.font-unix none
meta/recipes-graphics/xorg-xserver/xserver-xorg_21.1.18.bb +2 -0
index 14c45be432..3c8cb0173f 100644
@@ -26,3 +26,5 @@ RCONFLICTS:${PN} = "${PN}-extension-dri \
                     ${PN}-extension-extmod \
                     ${PN}-extension-dbe \
                    "
+
+RDEPENDS:${PN} += "${@bb.utils.contains("DISTRO_FEATURES", "systemd", "", "x11-volatiles", d)}"
meta/recipes-graphics/xwayland/xwayland_24.1.8.bb +1 -1
index 900da524b3..a621af1a7f 100644
@@ -47,4 +47,4 @@ do_install:append() {
 
 FILES:${PN} += "${libdir}/xorg/protocol.txt"
 
-RDEPENDS:${PN} += "xkbcomp"
+RDEPENDS:${PN} += "xkbcomp ${@bb.utils.contains("DISTRO_FEATURES", "systemd", "", "x11-volatiles", d)}"
Signature · 1 line
2.51.1