Skip to contentSkip to conversation

crash-trace: add recipe for crash trace extension module

PATCH New Wang Mingyu 1 participant 2 messages Jul 20

lore
Share & tools
lore
#0 lore raw

PATCH 1/1 crash-trace: add recipe for crash trace extension module

From: Wang Mingyu <[email protected]>

Add a new recipe for crash-trace, a crash utility extension that displays kernel tracing data and traced events prior to a panic.

---
 .../recipes-kernel/crash/crash-trace_git.bb   | 65 +++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 meta-oe/recipes-kernel/crash/crash-trace_git.bb
meta-oe/recipes-kernel/crash/crash-trace_git.bb new file +65 -0
new file mode 100644
index 0000000000..b54ef79ab5
@@ -0,0 +1,65 @@
+SUMMARY = "trace extension module for crash"
+DESCRIPTION = "Displays kernel tracing data and traced events that occurred prior to a panic."
+
+HOMEPAGE = "https://github.com/fujitsu/crash-trace"
+SECTION = "devel"
+
+LICENSE = "GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+DEPENDS = "crash zlib readline ncurses"
+RDEPENDS:${PN} = "crash"
+
+SRC_URI = "git://github.com/fujitsu/crash-trace.git;branch=master;protocol=https"
+SRCREV = "2106a9d04020192f6f286171a060c4d2300059b7"
+PV = "3.0+git"
+
+TARGET_CC_ARCH:append = " ${SELECTED_OPTIMIZATION}"
+
+# crash 7.1.3 and before don't support mips64/riscv64
+COMPATIBLE_HOST:riscv64 = "null"
+COMPATIBLE_HOST:riscv32 = "null"
+COMPATIBLE_HOST:mipsarchn64 = "null"
+COMPATIBLE_HOST:mipsarchn32 = "null"
+
+python () {
+    arch = d.getVar('TARGET_ARCH')
+    makefile_arch = ""
+    if arch.startswith('x86_64'):
+        makefile_arch = "X86_64"
+    elif arch == 'aarch64':
+        makefile_arch = "ARM64"
+    elif arch == 'i686':
+        makefile_arch = "i686"
+    elif arch == 'i586':
+        makefile_arch = "X86"
+
+    d.setVar('TARGET_ARCH_FOR_MAKEFILE', makefile_arch)
+}
+
+EXTRA_OEMAKE = 'TARGET=${TARGET_ARCH_FOR_MAKEFILE}'
+
+do_configure() {
+    :
+}
+
+do_compile:prepend() {
+    sed -i -E 's,^([ \t]*)gcc ,\1${CC} ${CFLAGS} ,' ${S}/Makefile
+    sed -i 's,INCDIR=/usr/include/crash,INCDIR=${STAGING_INCDIR}/crash,' ${S}/Makefile
+    sed -i 's|-o trace.so|${LDFLAGS} -o trace.so|' ${S}/Makefile
+}
+
+ARM_INSTRUCTION_SET = "arm"
+
+COMPATIBLE_HOST:libc-musl = 'null'
+
+do_install () {
+    install -d ${D}${libdir}/crash/extensions/
+
+    install -m 0644 ${S}/trace.so ${D}/${libdir}/crash/extensions/
+}
+
+FILES:${PN} += " \
+    ${libdir}/crash/extensions/ \
+"
+
Signature · 1 line
2.43.0
#1 lore raw

PATCH 1/1 tigervnc: Fix do_configure Error

From: Wang Mingyu <[email protected]>

update version of xorg-xserver according to oe-core
WARNING: tigervnc-1.16.2-r0 do_configure: TigerVNC xorg-server version (21.1.23) is different from oe-core's xorg-xserver version (21.1.24)

---
 meta-oe/recipes-graphics/tigervnc/tigervnc_1.16.2.bb | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)
meta-oe/recipes-graphics/tigervnc/tigervnc_1.16.2.bb +2 -2
index bbe0f5c5af..c96ba2f40f 100644
@@ -26,10 +26,10 @@ SRC_URI = "git://github.com/TigerVNC/tigervnc.git;branch=master;protocol=https \
 
 # Keep sync with xorg-server in oe-core
 XORG_PN ?= "xorg-server"
-XORG_PV ?= "21.1.23"
+XORG_PV ?= "21.1.24"
 SRC_URI += "${XORG_MIRROR}/individual/xserver/${XORG_PN}-${XORG_PV}.tar.xz;name=xorg"
 XORG_S = "${UNPACKDIR}/${XORG_PN}-${XORG_PV}"
-SRC_URI[xorg.sha256sum] = "e39832e5617dadaf072fdf9f0e19e5d2e1c2a13607ac280bac1aba9f8fe14634"
+SRC_URI[xorg.sha256sum] = "1a4eb36ca65cc3b1b936566d677a9786e13c11cd5806e951ac55f3f5ce3984af"
 
 # It is the directory containing the Xorg source for the
 # machine on which you are building TigerVNC.
Signature · 1 line
2.43.0