Skip to contentSkip to conversation

boost-asio: Add recipe

PATCH Superseded Gustav Lindberg 2 participants 2 messages Sep 1 – Sep 2

v5 of 6 Superseded Latest is v6 →

lore
Share & tools
lore
#0 lore raw

PATCH v5 1/1 boost-asio: Add recipe

This is needed to build boost asio as a shared library rather than a header-only library, which is needed to save memory.

---
 .../boost/boost-asio/boost_asio.cpp           |  1 +
 .../boost/boost-asio_1.92.0.bb                | 33 +++++++++++++++++++
 2 files changed, 34 insertions(+)
 create mode 100644 meta/recipes-support/boost/boost-asio/boost_asio.cpp
 create mode 100644 meta/recipes-support/boost/boost-asio_1.92.0.bb
meta/recipes-support/boost/boost-asio/boost_asio.cpp new file +1 -0
new file mode 100644
index 0000000000..bf00c8ff26
@@ -0,0 +1 @@
+#include <boost/asio/impl/src.hpp>
meta/recipes-support/boost/boost-asio_1.92.0.bb new file +33 -0
new file mode 100644
index 0000000000..e275a3b61b
@@ -0,0 +1,33 @@
+SUMMARY = "Boost.Asio shared library shim"
+DESCRIPTION = "Builds libboost_asio as a shared library from boost/asio/impl/src.hpp"
+HOMEPAGE = "https://www.boost.org/doc/libs/1_90_0/doc/html/boost_asio.html"
+
+DEPENDS = "boost"
+
+# Reuse Boost source and licensing metadata.
+require recipes-support/boost/boost-${PV}.inc
+
+SRC_URI += " file://boost_asio.cpp;subdir=${BOOST_P}"
+
+MAJOR_VER = "${@oe.utils.trim_version("${PV}", 1)}"
+
+do_compile() {
+	${CXX} ${CPPFLAGS} ${CXXFLAGS} \
+		-std=c++23 \
+		-DBOOST_ASIO_DYN_LINK=1 \
+		-fPIC \
+		-shared \
+		-Wl,-soname,libboost_asio.so.${MAJOR_VER} \
+		${S}/boost_asio.cpp \
+		${LDFLAGS} \
+		-o ${B}/libboost_asio.so.${PV}
+}
+
+do_install() {
+	install -d ${D}${libdir}
+	install -m 0755 ${B}/libboost_asio.so.${PV} ${D}${libdir}/
+	ln -sf libboost_asio.so.${PV} ${D}${libdir}/libboost_asio.so.${MAJOR_VER}
+	ln -sf libboost_asio.so.${MAJOR_VER} ${D}${libdir}/libboost_asio.so
+}
+
+BBCLASSEXTEND = "native"
Signature · 1 line
2.43.0
#1 lore raw
Quoted 5 lines · Gustav Lindberg via lists.openembedded.org

This is needed to build boost asio as a shared library rather than a header-only library, which is needed to save memory.

---

Hi Gustav,

Thanks for the new version. This looks better on the tests, but you need to add yourself as a maintainer in meta/conf/distro/include/maintainers.inc.

Thanks,
Mathieu

Signature · 3 lines
Mathieu Dubois-Briand, Bootlin
Embedded Linux and Kernel engineering
https://bootlin.com