Skip to contentSkip to conversation

mesa: Replace ugly fix with PACKAGECONFIG

PATCH In review Andrei Gherzan 2 participants 3 messages Feb 25, 2014

lore
Share & tools
lore
#0 lore raw

PATCH 1/1 mesa: Replace ugly fix with PACKAGECONFIG

Use "%" as version because this append should be applied on any mesa version.

Change-Id I5ed3c50a0a794f8ea63cc1906f0139ec47459fa6
---
 recipes-graphics/mesa/mesa_%.bbappend     |  6 ++++++
 recipes-graphics/mesa/mesa_9.2.5.bbappend | 36 -------------------------------
 2 files changed, 6 insertions(+), 36 deletions(-)
 create mode 100644 recipes-graphics/mesa/mesa_%.bbappend
 delete mode 100644 recipes-graphics/mesa/mesa_9.2.5.bbappend
recipes-graphics/mesa/mesa_%.bbappend new file +6 -0
new file mode 100644
index 0000000..6ea5a8f
@@ -0,0 +1,6 @@
+# EGL and GLES are provided by userland package
+PACKAGECONFIG_remove_raspberrypi = "egl gles"
+PROVIDES_remove_raspberrypi = "\
+    virtual/libgles1 \
+    virtual/libgles2 \
+    virtual/egl"
recipes-graphics/mesa/mesa_9.2.5.bbappend deleted +0 -36
deleted file mode 100644
index 34da98f..0000000
@@ -1,36 +0,0 @@
-PRINC := "${@int(PRINC) + 2}"
-
-#
-# FIXME
-# We need a way to disable EGL and GL ES2, these are provided by userland package
-#
-python __anonymous () {
-    import re
-
-    machine = d.getVar('MACHINE', True)
-    if machine == 'raspberrypi':
-        # Remove egl and gles2 configure options
-        extra_oeconf = d.getVar('EXTRA_OECONF', True).split()
-        take_out = ['--enable-egl', '--enable-gles2', '--enable-gles1']
-        put_in = ['--disable-egl', '--disable-gles2', '--disable-gles1']
-        pattern = re.compile("--with-egl-platforms")
-        new_extra_oeconf = []
-        for i in extra_oeconf:
-            if i not in take_out and not pattern.match(i):
-                new_extra_oeconf.append(i)
-        for i in put_in:
-            new_extra_oeconf.append(i)
-        d.setVar('EXTRA_OECONF', ' '.join(new_extra_oeconf))
-
-        # Remove egl and gles2 from provides
-        provides = d.getVar('PROVIDES', True).split()
-        take_out = ['virtual/libgles2', 'virtual/egl', 'virtual/libgles1']
-        new_provides = []
-        for i in provides:
-            if i not in take_out:
-                new_provides.append(i)
-        d.setVar('PROVIDES', ' '.join(new_provides))
-
-        # We are now machine specific
-        d.setVar('PACKAGE_ARCH', d.getVar('MACHINE_ARCH'))
-}
Signature · 1 line
1.8.1.4
#1 lore raw

recipes-graphics/mesa/mesa_%.bbappend line 6

Quoted 6 lines · Andrei Gherzan
recipes-graphics/mesa/mesa_%.bbappend new file +6 -0
+# EGL and GLES are provided by userland package
+PACKAGECONFIG_remove_raspberrypi = "egl gles"
+PROVIDES_remove_raspberrypi = "\
+    virtual/libgles1 \
+    virtual/libgles2 \
+    virtual/egl"

Are you aware of mesa-gl? This recipe builds a GL-only Mesa (no gles or egl), and is designed to sit alongside binary drivers that provide EGL and GLES to avoid exactly this sort of hackery to Mesa.

Ross

#2 lore raw
Quoted 12 lines · Ross

recipes-graphics/mesa/mesa_%.bbappend line 6

Quoted 6 lines · Andrei Gherzan
recipes-graphics/mesa/mesa_%.bbappend new file +6 -0
+# EGL and GLES are provided by userland package
+PACKAGECONFIG_remove_raspberrypi = "egl gles"
+PROVIDES_remove_raspberrypi = "\
+    virtual/libgles1 \
+    virtual/libgles2 \
+    virtual/egl"

Are you aware of mesa-gl? This recipe builds a GL-only Mesa (no gles or egl), and is designed to sit alongside binary drivers that provide EGL and GLES to avoid exactly this sort of hackery to Mesa.

Good hint. Thanks.

Signature · 1 line
*ag*