Skip to contentSkip to conversation

nghttp2: fix UPSTREAM_CHECK_URI

PATCH New André Draszik 1 participant 4 messages Nov 7, 2019

lore
Share & tools
lore
#0 lore raw

PATCH 1/4 nghttp2: fix UPSTREAM_CHECK_URI

This was added incorrectly in the previous recipe update and doesn't actually work.

---
 meta-networking/recipes-support/nghttp2/nghttp2_1.39.1.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)
meta-networking/recipes-support/nghttp2/nghttp2_1.39.1.bb +1 -1
index 6077daf76..913065a04 100644
@@ -4,7 +4,7 @@ SECTION = "libs"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "file://COPYING;md5=764abdf30b2eadd37ce47dcbce0ea1ec"
 
-+UPSTREAM_CHECK_URI = "https://github.com/nghttp2/nghttp2/releases"
+UPSTREAM_CHECK_URI = "https://github.com/nghttp2/nghttp2/releases"
 
 SRC_URI = "https://github.com/nghttp2/nghttp2/releases/download/v${PV}/nghttp2-${PV}.tar.xz"
 SRC_URI[md5sum] = "02b015cb178c46f27dd87228e33db35f"
Signature · 1 line
2.23.0.rc1
#1 lore raw

PATCH 2/4 nghttp2: update to 1.39.2

---
 .../nghttp2/{nghttp2_1.39.1.bb => nghttp2_1.39.2.bb}          | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)
 rename meta-networking/recipes-support/nghttp2/{nghttp2_1.39.1.bb => nghttp2_1.39.2.bb} (75%)
meta-networking/recipes-support/nghttp2/nghttp2_1.39.2.bb renamed from meta-networking/recipes-support/nghttp2/nghttp2_1.39.1.bb +2 -2
similarity index 75%
rename from meta-networking/recipes-support/nghttp2/nghttp2_1.39.1.bb
rename to meta-networking/recipes-support/nghttp2/nghttp2_1.39.2.bb
index 913065a04..c3f06a714 100644
@@ -7,8 +7,8 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=764abdf30b2eadd37ce47dcbce0ea1ec"
 UPSTREAM_CHECK_URI = "https://github.com/nghttp2/nghttp2/releases"
 
 SRC_URI = "https://github.com/nghttp2/nghttp2/releases/download/v${PV}/nghttp2-${PV}.tar.xz"
-SRC_URI[md5sum] = "02b015cb178c46f27dd87228e33db35f"
-SRC_URI[sha256sum] = "679160766401f474731fd60c3aca095f88451e3cc4709b72306e4c34cf981448"
+SRC_URI[md5sum] = "de52cd6b587b76486346745514972995"
+SRC_URI[sha256sum] = "a2d216450abd2beaf4e200c168957968e89d602ca4119338b9d7ab059fd4ce8b"
 
 DEPENDS = "libxml2 openssl zlib jansson cunit c-ares"
 
Signature · 1 line
2.23.0.rc1
#2 lore raw

PATCH 3/4 nghttp2: build more of this & fix packaging

In reply to André Draszik

nghttp2 also provides http client, server, and proxy. Add the necessary DEPENDS and build flags to enable those.

They are all packaged into individual packages, with 'nghttp2' being a meta-package now and pulling in all of the above three applications.

The shared library itself (the only part that this recipe had been building so far), is also being split into its own package, meaning existing users shouldn't be affected, as nobody should have an RDEPENDS on 'nghttp2' at the moment (due to bitbake's shlibs dependency tracking).

The deflatehd and inflatehd binaries have been completely dropped, as they are (header) test applications for HTTP/2. Debian doesn't ship them either.

The python script fetch-ocsp-response is (only) needed by the proxy, and itself calls out to openssl. We can easily make this python3 using a simple patch, though.

Minor additional fixes:
* sort DEPENDS alphabetically
* drop python-dir, this is implied by pythonnative
* inherit manpages so as to benefit from man-db processing (note that manpages are not generated here, we just want the automatic update of the package index caches) We need to add a PACKAGECONFIG, as manpages.bbclass requires it to be present, even though nghttp2 unconditionally installs them

---
 ...0001-fetch-ocsp-response-use-python3.patch | 27 +++++++++++++++++
 .../recipes-support/nghttp2/nghttp2_1.39.2.bb | 29 +++++++++++++++++--
 2 files changed, 53 insertions(+), 3 deletions(-)
 create mode 100644 meta-networking/recipes-support/nghttp2/nghttp2/0001-fetch-ocsp-response-use-python3.patch
meta-networking/recipes-support/nghttp2/nghttp2/0001-fetch-ocsp-response-use-python3.patch new file +27 -0
new file mode 100644
index 000000000..e4db09638
@@ -0,0 +1,27 @@
+From 73ec79432fc557a8be4f1500982b1c0f5fdf12a9 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andr=C3=A9=20Draszik?= <[email protected]>
+Date: Thu, 7 Nov 2019 09:58:52 +0000
+Subject: [PATCH] fetch-ocsp-response: use python3
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+Upstream-Status: Inappropriate [oe specific]
+Signed-off-by: André Draszik <[email protected]>
+---
+ script/fetch-ocsp-response | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/script/fetch-ocsp-response b/script/fetch-ocsp-response
+index 0ff7461..185116b 100755
+--- a/script/fetch-ocsp-response
++++ b/script/fetch-ocsp-response
+@@ -1,4 +1,4 @@
+-#!/usr/bin/env python
++#!/usr/bin/env python3
+ # -*- coding: utf-8 -*-
+ 
+ # nghttp2 - HTTP/2 C Library
+-- 
+2.23.0.rc1
+
meta-networking/recipes-support/nghttp2/nghttp2_1.39.2.bb +26 -3
index c3f06a714..7a475050f 100644
@@ -3,13 +3,36 @@ HOMEPAGE = "https://nghttp2.org/"
 SECTION = "libs"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "file://COPYING;md5=764abdf30b2eadd37ce47dcbce0ea1ec"
+DEPENDS = "c-ares cunit jansson libev libevent libxml2 openssl zlib"
 
 UPSTREAM_CHECK_URI = "https://github.com/nghttp2/nghttp2/releases"
 
-SRC_URI = "https://github.com/nghttp2/nghttp2/releases/download/v${PV}/nghttp2-${PV}.tar.xz"
+SRC_URI = "\
+    https://github.com/nghttp2/nghttp2/releases/download/v${PV}/nghttp2-${PV}.tar.xz \
+    file://0001-fetch-ocsp-response-use-python3.patch \
+"
 SRC_URI[md5sum] = "de52cd6b587b76486346745514972995"
 SRC_URI[sha256sum] = "a2d216450abd2beaf4e200c168957968e89d602ca4119338b9d7ab059fd4ce8b"
 
-DEPENDS = "libxml2 openssl zlib jansson cunit c-ares"
+inherit cmake manpages pythonnative
+PACKAGECONFIG[manpages] = ""
 
-inherit cmake pythonnative python-dir
+# examples are never installed, and don't need to be built in the
+# first place
+EXTRA_OECMAKE = "-DENABLE_EXAMPLES=OFF -DENABLE_APP=ON"
+
+do_install_append() {
+	rm ${D}${bindir}/deflatehd ${D}${bindir}/inflatehd
+}
+
+PACKAGES =+ "lib${PN} ${PN}-client ${PN}-proxy ${PN}-server"
+
+RDEPENDS_${PN} = "${PN}-client (>= ${PV}) ${PN}-proxy (>= ${PV}) ${PN}-server (>= ${PV})"
+RDEPENDS_${PN}-proxy = "openssl python3-core python3-io python3-shell"
+
+ALLOW_EMPTY_${PN} = "1"
+FILES_${PN} = ""
+FILES_lib${PN} = "${libdir}/*${SOLIBS}"
+FILES_${PN}-client = "${bindir}/h2load ${bindir}/nghttp"
+FILES_${PN}-proxy = "${bindir}/nghttpx ${datadir}/${BPN}/fetch-ocsp-response"
+FILES_${PN}-server = "${bindir}/nghttpd"
Signature · 1 line
2.23.0.rc1
#3 lore raw

PATCH 4/4 nghttp2: allow to build a -native package

In reply to André Draszik

This will e.g. enable us to use it from nodejs-native.

---
 meta-networking/recipes-support/nghttp2/nghttp2_1.39.2.bb | 3 +++
 1 file changed, 3 insertions(+)
meta-networking/recipes-support/nghttp2/nghttp2_1.39.2.bb +3 -0
index 7a475050f..c27afdb55 100644
@@ -28,6 +28,7 @@ do_install_append() {
 PACKAGES =+ "lib${PN} ${PN}-client ${PN}-proxy ${PN}-server"
 
 RDEPENDS_${PN} = "${PN}-client (>= ${PV}) ${PN}-proxy (>= ${PV}) ${PN}-server (>= ${PV})"
+RDEPENDS_${PN}_class-native = ""
 RDEPENDS_${PN}-proxy = "openssl python3-core python3-io python3-shell"
 
 ALLOW_EMPTY_${PN} = "1"
@@ -36,3 +37,5 @@ FILES_lib${PN} = "${libdir}/*${SOLIBS}"
 FILES_${PN}-client = "${bindir}/h2load ${bindir}/nghttp"
 FILES_${PN}-proxy = "${bindir}/nghttpx ${datadir}/${BPN}/fetch-ocsp-response"
 FILES_${PN}-server = "${bindir}/nghttpd"
+
+BBCLASSEXTEND = "native"
Signature · 1 line
2.23.0.rc1