Skip to contentSkip to conversation

gator-daemon: Add new package

PATCH New Clément Péron 1 participant 1 message Jun 23, 2021

lore
Share & tools
lore
#0 lore raw

PATCH v2 1/1 gator-daemon: Add new package

To communicate with the target device, Streamline requires the gator daemon, gatord, to be running on the device.

---

This patch has been first submitted to meta-oe, after discussion it's better to submit it to meta-arm.

Changes since v1:
- Rename gator to gator-daemon
- Bump to 7.7.0
- Remove merged patch
- Add compatible_host to aarch64
- Compile with V=1
- Update Description and add comment

Changes since meta-oe:
- Bump to 7.6.0
- Add upstream-status and signoff patch
- Add Kernel config requirement to summary
- Add Homepage
- Add all Licenses and checksums

 .../gator-daemon/gator-daemon_7.7.0.bb        | 32 +++++++++++++++++++
 1 file changed, 32 insertions(+)
 create mode 100644 meta-arm/recipes-devtools/gator-daemon/gator-daemon_7.7.0.bb
meta-arm/recipes-devtools/gator-daemon/gator-daemon_7.7.0.bb new file +32 -0
new file mode 100644
index 000000000000..61b173142829
@@ -0,0 +1,32 @@
+SUMMARY = "DS-5 Streamline Gator daemon"
+DESCRIPTION = "Target-side daemon gathering data for ARM Streamline \
+               Performance Analyzer."
+HOMEPAGE = "https://github.com/ARM-software/gator"
+
+# Note that Gator uses the Linux Perf API for
+# most of its data collection. Check that your Kernel follow the
+# configuration requirement specified here:
+# https://github.com/ARM-software/gator#kernel-configuration
+
+LICENSE = "GPLv2 & LGPLv2.1+ & Apache-2.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://libsensors/COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c \
+                    file://mxml/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327 \
+                    file://k/perf_event.h;endline=14;md5=e548bf30a60b2ed11ef2dcf7bfdac230 \
+                   "
+
+SRCREV = "9d8d75fa08352470c51abc23fe3b314879bd8b78"
+SRC_URI = "git://github.com/ARM-software/gator.git;protocol=http;branch=main"
+
+S = "${WORKDIR}/git/daemon"
+
+COMPATIBLE_HOST = "aarch64.*-linux"
+
+EXTRA_OEMAKE = "'CFLAGS=${CFLAGS} ${TARGET_CC_ARCH} -D_DEFAULT_SOURCE -DETCDIR=\"${sysconfdir}\"' \
+                'LDFLAGS=${LDFLAGS} ${TARGET_CC_ARCH}' 'CROSS_COMPILE=${TARGET_PREFIX}' \
+                'CXXFLAGS=${CXXFLAGS} ${TARGET_CC_ARCH} -fno-rtti' CC='${CC}' CXX='${CXX}' V=1"
+
+do_install() {
+        install -d ${D}${sbindir}
+        install -m 0755 ${S}/gatord ${D}${sbindir}/gatord
+}
Signature · 1 line
2.25.1