Skip to contentSkip to conversation

recipies-ti: Add TI K3 Security Development Package

PATCH New Andrew Davis 1 participant 3 messages Aug 12, 2022

lore
Share & tools
lore
#0 lore raw

PATCH 1/3 recipies-ti: Add TI K3 Security Development Package

---
 recipes-ti/includes/ti-paths.inc      |  2 ++
 recipes-ti/secdev/ti-k3-secdev_git.bb | 36 +++++++++++++++++++++++++++
 2 files changed, 38 insertions(+)
 create mode 100644 recipes-ti/secdev/ti-k3-secdev_git.bb
recipes-ti/includes/ti-paths.inc +2 -0
index 52a93cf5..44731a4e 100644
@@ -61,6 +61,7 @@ export TI_CGT6X_7_INSTALL_DIR_RECIPE   = "${installdir}/cgt6x-7"
 export GCC_LINARO_BAREMETAL_TOOLCHAIN_RECIPE          = "${installdir}/gcc-linaro-baremetal"
 export GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN_RECIPE  = "${installdir}/gcc-linaro-baremetal-aarch64"
 export TI_CGT7X_INSTALL_DIR_RECIPE        = "${installdir}/cgt-c7x"
+export TI_K3_SECDEV_INSTALL_DIR_RECIPE = "${installdir}/ti-k3-secdev"
 
 
 # This is where the tools will end up in sysroot
@@ -116,6 +117,7 @@ export TI_CGT6X_7_INSTALL_DIR   = "${STAGING_DIR_NATIVE}${TI_CGT6X_7_INSTALL_DIR
 export GCC_LINARO_BAREMETAL_TOOLCHAIN         =  "${STAGING_DIR_NATIVE}${GCC_LINARO_BAREMETAL_TOOLCHAIN_RECIPE}"
 export GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN =  "${STAGING_DIR_NATIVE}${GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN_RECIPE}"
 export TI_CGT7X_INSTALL_DIR        = "${STAGING_DIR_NATIVE}${TI_CGT7X_INSTALL_DIR_RECIPE}"
+export TI_K3_SECDEV_INSTALL_DIR = "${STAGING_DIR_NATIVE}${TI_K3_SECDEV_INSTALL_DIR_RECIPE}"
 
 
 DSPSUFFIX_omapl137 = "x674"
recipes-ti/secdev/ti-k3-secdev_git.bb new file +36 -0
new file mode 100644
index 00000000..28dbe9ee
@@ -0,0 +1,36 @@
+DESCRIPTION = "Security development tools for High-Security(HS) TI K3 processors."
+HOMEPAGE = "https://git.ti.com/cgit/security-development-tools/core-secdev-k3"
+SECTION = "devel"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://manifest/k3-secdev-0.2-manifest.html;md5=f632a78870cc64550078d7b3cbac0892"
+
+# Native host tool only
+COMPATIBLE_MACHINE = "null"
+COMPATIBLE_MACHINE_class-native = "(.*)"
+COMPATIBLE_MACHINE_class-nativesdk = "(.*)"
+
+GIT_URI = "git://git.ti.com/git/security-development-tools/core-secdev-k3.git"
+GIT_PROTOCOL = "https"
+GIT_BRANCH = "master"
+GIT_SRCREV = "eb2c4d734487e5095b94cef3fd7213ee71d9e016"
+
+SRC_URI = "${GIT_URI};protocol=${GIT_PROTOCOL};branch=${GIT_BRANCH}"
+SRCREV = "${GIT_SRCREV}"
+
+S = "${WORKDIR}/git"
+
+do_install() {
+    CP_ARGS="-Prf --preserve=mode,links,timestamps --no-preserve=ownership"
+    install -d ${D}${TI_K3_SECDEV_INSTALL_DIR_RECIPE}
+    cp ${CP_ARGS} ${S}/* ${D}${TI_K3_SECDEV_INSTALL_DIR_RECIPE}
+}
+
+FILES_${PN} += "${TI_K3_SECDEV_INSTALL_DIR_RECIPE}"
+
+INSANE_SKIP_${PN} = "arch ldflags file-rdeps"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+
+BBCLASSEXTEND = "native nativesdk"
Signature · 1 line
2.36.1
#1 lore raw

PATCH 2/3 ti-sci-fw: Use ti-k3-secdev if TI_SECURE_DEV_PKG_K3 is not defined

---
 recipes-bsp/ti-sci-fw/ti-sci-fw_git.bb | 4 +++-
 1 file changed, 3 insertions(+), 1 deletion(-)
recipes-bsp/ti-sci-fw/ti-sci-fw_git.bb +3 -1
index 18652dd4..adf73a5e 100644
@@ -1,4 +1,5 @@
 require recipes-bsp/ti-linux-fw/ti-linux-fw.inc
+require recipes-ti/includes/ti-paths.inc
 
 DEPENDS = "openssl-native u-boot-mkimage-native dtc-native virtual/bootloader"
 DEPENDS_remove_am65xx-evm-k3r5 = " virtual/bootloader"
@@ -8,6 +9,7 @@ DEPENDS_remove_am65xx-hs-evm-k3r5-sr2 = " virtual/bootloader"
 DEPENDS_remove_j7-evm-k3r5 = " virtual/bootloader"
 DEPENDS_remove_j7-hs-evm-k3r5 = " virtual/bootloader"
 DEPENDS_remove_j7-hs-evm-k3r5-sr1-1 = " virtual/bootloader"
+DEPENDS_append = " ${@ '' if '${TI_SECURE_DEV_PKG_K3}' else 'ti-k3-secdev-native' }"
 
 CLEANBROKEN = "1"
 PR = "${INC_PR}.2"
@@ -18,7 +20,7 @@ COMPATIBLE_MACHINE_aarch64 = "null"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
-TI_SECURE_DEV_PKG ?= ""
+TI_SECURE_DEV_PKG = "${@ '${TI_SECURE_DEV_PKG_K3}' or '${TI_K3_SECDEV_INSTALL_DIR}' }"
 export TI_SECURE_DEV_PKG
 
 SYSFW_SOC ?= "unknown"
Signature · 1 line
2.36.1
#2 lore raw

PATCH 3/3 conf: machine: am64xx-evm: Make HS-SE the default

In reply to Andrew Davis

The HS-SE AM64xx machine can now be run on GP devices and built without needing the TI_SECURE_DEV_PKG for the same. AM64xx will only be available in the HS-FS type going forward. Make the HS-SE the default and remove the original GP machine.

---
 ...m-k3r5-gp.conf => am64xx-evm-k3r5-gp.conf} |  6 ++++-
 conf/machine/am64xx-evm-k3r5-hs-se.conf       | 14 +++++++++++
 conf/machine/am64xx-evm-k3r5.conf             | 11 --------
 conf/machine/am64xx-evm.conf                  |  6 +++++
 conf/machine/am64xx-hs-evm-k3r5.conf          | 12 ---------
 conf/machine/am64xx-hs-evm.conf               | 25 -------------------
 conf/machine/include/am64xx.inc               |  5 ++--
 conf/multiconfig/k3r5-hs-se.conf              |  3 +++
 .../trusted-firmware-a_%.bbappend             |  2 +-
 recipes-security/optee/optee-os_%.bbappend    |  2 +-
 10 files changed, 33 insertions(+), 53 deletions(-)
 rename conf/machine/{am64xx-hs-evm-k3r5-gp.conf => am64xx-evm-k3r5-gp.conf} (78%)
 create mode 100644 conf/machine/am64xx-evm-k3r5-hs-se.conf
 delete mode 100644 conf/machine/am64xx-evm-k3r5.conf
 delete mode 100644 conf/machine/am64xx-hs-evm-k3r5.conf
 delete mode 100644 conf/machine/am64xx-hs-evm.conf
 create mode 100644 conf/multiconfig/k3r5-hs-se.conf
conf/machine/am64xx-evm-k3r5-gp.conf renamed from conf/machine/am64xx-hs-evm-k3r5-gp.conf +5 -1
similarity index 78%
rename from conf/machine/am64xx-hs-evm-k3r5-gp.conf
rename to conf/machine/am64xx-evm-k3r5-gp.conf
index b255dca8..c599ee47 100644
@@ -4,12 +4,16 @@
 
 # Booting GP requires different SYSFW, the rest is handled at runtime
 
-require conf/machine/am64xx-hs-evm-k3r5.conf
+require conf/machine/include/k3r5.inc
 SOC_FAMILY_append = ":k3r5-gp"
 
+SYSFW_SOC = "am64x"
+SYSFW_CONFIG = "evm"
 SYSFW_SUFFIX = "gp"
 SYSFW_TIBOOT3_SYMLINK = ""
 
+UBOOT_MACHINE = "am64x_evm_r5_defconfig"
+
 SPL_BINARY = ""
 UBOOT_BINARY = "u-boot-spl.${UBOOT_SUFFIX}"
 UBOOT_IMAGE = "u-boot-r5spl-gp-${MAINMACHINE}-${PV}-${PR}.${UBOOT_SUFFIX}"
conf/machine/am64xx-evm-k3r5-hs-se.conf new file +14 -0
new file mode 100644
index 00000000..7cab7d15
@@ -0,0 +1,14 @@
+#@TYPE: Machine
+#@NAME: AM64xx HS-SE EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI AM64xx HS-SE EVM (R5F core)
+
+# Booting HS-SE requires different SYSFW, the rest is handled at runtime
+
+require conf/machine/include/k3r5.inc
+SOC_FAMILY_append = ":k3r5-hs-se"
+
+SYSFW_SOC = "am64x"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "hs"
+
+UBOOT_MACHINE = "am64x_evm_r5_defconfig"
conf/machine/am64xx-evm-k3r5.conf deleted +0 -11
deleted file mode 100644
index afd36b72..00000000
@@ -1,11 +0,0 @@
-#@TYPE: Machine
-#@NAME: AM64xx EVM (R5F)
-#@DESCRIPTION: Machine configuration for the TI AM64xx EVM (R5F core)
-
-require conf/machine/include/k3r5.inc
-
-SYSFW_SOC = "am64x"
-SYSFW_CONFIG = "evm"
-SYSFW_SUFFIX = "gp"
-
-UBOOT_MACHINE = "am64x_evm_r5_defconfig"
conf/machine/am64xx-evm.conf +6 -0
index 2cb7f55a..d6efdf52 100644
@@ -9,3 +9,9 @@ UBOOT_MACHINE = "am64x_evm_a53_defconfig"
 SPL_BINARY = "tispl.bin_HS"
 UBOOT_BINARY = "u-boot.img_HS"
 UBOOT_SYMLINK = "u-boot.img"
+
+# Since default tiboot3.bin on AM64x is for HS-SE, add a version for GP
+BBMULTICONFIG += "k3r5-gp"
+IMAGE_BOOT_FILES += " tiboot3-am64x-gp-evm.bin"
+do_image_wic[mcdepends] += "mc::k3r5-gp:ti-sci-fw:do_deploy"
+do_image_tar[mcdepends] += "mc::k3r5-gp:ti-sci-fw:do_deploy"
conf/machine/am64xx-hs-evm-k3r5.conf deleted +0 -12
deleted file mode 100644
index 95e68751..00000000
@@ -1,12 +0,0 @@
-#@TYPE: Machine
-#@NAME: AM64xx HS EVM (R5F)
-#@DESCRIPTION: Machine configuration for the TI AM64xx HS EVM (R5F core)
-
-require conf/machine/include/k3r5.inc
-
-SYSFW_SOC = "am64x"
-SYSFW_CONFIG = "evm"
-SYSFW_SUFFIX = "hs"
-SYSFW_SYMLINK = ""
-
-UBOOT_MACHINE = "am64x_evm_r5_defconfig"
conf/machine/am64xx-hs-evm.conf deleted +0 -25
deleted file mode 100644
index 1149d4c7..00000000
@@ -1,25 +0,0 @@
-#@TYPE: Machine
-#@NAME: AM64xx HS EVM
-#@DESCRIPTION: Machine configuration for the TI AM64xx HS EVM
-
-require conf/machine/include/am64xx.inc
-
-UBOOT_MACHINE = "am64x_evm_a53_defconfig"
-
-UBOOT_ENTRYPOINT =       "0x80080000"
-UBOOT_LOADADDRESS =      "0x80080000"
-UBOOT_RD_LOADADDRESS =   "0x84000000"
-UBOOT_RD_ENTRYPOINT =    "0x84000000"
-UBOOT_DTB_LOADADDRESS =  "0x83000000"
-UBOOT_DTBO_LOADADDRESS = "0x83080000"
-UBOOT_DTBO_OFFSET =      "0x00010000"
-
-SPL_BINARY = "tispl.bin_HS"
-UBOOT_BINARY = "u-boot.img_HS"
-UBOOT_SYMLINK = "u-boot.img"
-
-# Since default tiboot3.bin on AM64x is for HS, add a version for GP
-BBMULTICONFIG += "k3r5-gp"
-IMAGE_BOOT_FILES += " tiboot3-am64x-gp-evm.bin"
-do_image_wic[mcdepends] += "mc::k3r5-gp:ti-sci-fw:do_deploy"
-do_image_tar[mcdepends] += "mc::k3r5-gp:ti-sci-fw:do_deploy"
conf/machine/include/am64xx.inc +3 -2
index 930fba08..becc79d4 100644
@@ -14,8 +14,9 @@ KERNEL_DEVICETREE = " \
     ti/k3-am642-evm-nand.dtbo \
 "
 
-do_image_wic[mcdepends] = "mc::k3r5:ti-sci-fw:do_deploy"
-do_image_tar[mcdepends] = "mc::k3r5:ti-sci-fw:do_deploy"
+BBMULTICONFIG = "k3r5-hs-se"
+do_image_wic[mcdepends] = "mc::k3r5-hs-se:ti-sci-fw:do_deploy"
+do_image_tar[mcdepends] = "mc::k3r5-hs-se:ti-sci-fw:do_deploy"
 
 TFA_BOARD = "lite"
 OPTEEMACHINE = "k3-am64x"
conf/multiconfig/k3r5-hs-se.conf new file +3 -0
new file mode 100644
index 00000000..701f8e88
@@ -0,0 +1,3 @@
+require k3r5.conf
+
+MACHINE_append = "-hs-se"
recipes-bsp/trusted-firmware-a/trusted-firmware-a_%.bbappend +1 -1
index 81edac27..a1df380f 100644
@@ -27,7 +27,7 @@ do_compile_append_am65xx-hs-evm() {
 	tfa_sign_k3hs
 }
 
-do_compile_append_am64xx-hs-evm() {
+do_compile_append_am64xx-evm() {
 	tfa_sign_k3hs
 }
 
recipes-security/optee/optee-os_%.bbappend +1 -1
index 5a25bd99..8a429bbc 100644
@@ -66,7 +66,7 @@ do_compile_append_am65xx-hs-evm() {
     optee_sign_k3hs
 }
 
-do_compile_append_am64xx-hs-evm() {
+do_compile_append_am64xx-evm() {
     optee_sign_k3hs
 }
 
Signature · 1 line
2.36.1