Skip to contentSkip to conversation

python3-calver: Add recipe

PATCH Superseded Trevor Gamblin 1 participant 1 message May 9, 2023

v7 of 8 Superseded Latest is v8 →

lore
Share & tools
lore
#0 lore raw

PATCH v7 1/1 python3-calver: Add recipe

calver is "a setuptools extension for automatically defining your Python package version as a calendar version." It is required for python3-trove-classifiers (another new recipe), which in turn is required for the upgrade of python3-hatchling from 1.13.0 to work.

v7 removes the unnecessary sha256sum from the recipe.
v6 addresses reproducibility by patching the source code, and fixes issues with that were missed from previous reviews.
v5 moves these revision notes to the correct place.
v4 adds the run-ptest script and adds maintainer info.
v3 clarifies that the recipe now includes ptests, where v2 didn't make this clear and v1 didn't have them at all.

---
 meta/conf/distro/include/maintainers.inc      |  1 +
 .../distro/include/ptest-packagelists.inc     |  1 +
 .../0001-setup.py-hard-code-version.patch     | 32 +++++++++++++++++++
 .../python/python3-calver/run-ptest           |  3 ++
 .../python/python3-calver_2022.6.26.bb        | 28 ++++++++++++++++
 5 files changed, 65 insertions(+)
 create mode 100644 meta/recipes-devtools/python/python3-calver/0001-setup.py-hard-code-version.patch
 create mode 100644 meta/recipes-devtools/python/python3-calver/run-ptest
 create mode 100644 meta/recipes-devtools/python/python3-calver_2022.6.26.bb
meta/conf/distro/include/maintainers.inc +1 -0
index e24d8545ba..0ee465fe1f 100644
@@ -607,6 +607,7 @@ RECIPE_MAINTAINER:pn-python3-attrs = "Tim Orling <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-babel = "Tim Orling <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-bcrypt = "Tim Orling <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-build = "Ross Burton <[email protected]>"
+RECIPE_MAINTAINER:pn-python3-calver = "Trevor Gamblin <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-certifi = "Tim Orling <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-cffi = "Tim Orling <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-chardet = "Tim Orling <[email protected]>"
meta/conf/distro/include/ptest-packagelists.inc +1 -0
index 2f83132aeb..bd95a13ff6 100644
@@ -56,6 +56,7 @@ PTESTS_FAST = "\
     popt \
     python3-atomicwrites \
     python3-bcrypt \
+    python3-calver \
     python3-hypothesis \
     python3-jinja2 \
     python3-jsonpointer \
meta/recipes-devtools/python/python3-calver/0001-setup.py-hard-code-version.patch new file +32 -0
new file mode 100644
index 0000000000..43f8a78ef0
@@ -0,0 +1,32 @@
+From 390a233ed969f82b2ef209b23bfb523e785603f9 Mon Sep 17 00:00:00 2001
+From: Trevor Gamblin <[email protected]>
+Date: Tue, 9 May 2023 10:19:41 -0400
+Subject: [PATCH] setup.py: hard-code version
+
+setup.py is pulling the build version from the current date rather than
+a release tag or other predictable method, causing reproducibility 
+issues in builds. Patch this to make reproducible builds work while
+discussing this with upstream maintainer (or developing a patch that can
+make calver rely on a more standard pyproject.toml solution).
+
+Upstream-Status: Inappropriate (configuration)
+
+Signed-off-by: Trevor Gamblin <[email protected]>
+---
+ setup.py | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/setup.py b/setup.py
+index 73f6b10..2e27cf1 100644
+--- a/setup.py
++++ b/setup.py
+@@ -42,5 +42,5 @@ setup(
+             "use_calver = calver.integration:version",
+         ],
+     },
+-    version=calver_version(True),
++    version=calver_version("2022.6.26"),
+ )
+-- 
+2.40.0
+
meta/recipes-devtools/python/python3-calver/run-ptest new file +3 -0
new file mode 100644
index 0000000000..8d2017d39c
@@ -0,0 +1,3 @@
+#!/bin/sh
+
+pytest --automake
meta/recipes-devtools/python/python3-calver_2022.6.26.bb new file +28 -0
new file mode 100644
index 0000000000..58b33f19ff
@@ -0,0 +1,28 @@
+SUMMARY = "Setuptools extension for CalVer package versions"
+HOMEPAGE = "https://github.com/di/calver"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRC_URI = " \
+    git://github.com/di/calver;branch=master;protocol=https \
+    file://run-ptest \
+    file://0001-setup.py-hard-code-version.patch \
+"
+SRCREV = "3268d8acf2c345f32a1c5f08ba25dc67f76cca81"
+
+inherit python_setuptools_build_meta ptest
+
+S = "${WORKDIR}/git"
+
+RDEPENDS:${PN}-ptest += " \
+    ${PYTHON_PN}-pretend \
+    ${PYTHON_PN}-pytest \
+    ${PYTHON_PN}-unittest-automake-output \
+"
+
+do_install_ptest() {
+        install -d ${D}${PTEST_PATH}/tests
+        cp -rf ${S}/tests ${D}${PTEST_PATH}/
+}
+
+BBCLASSEXTEND = "native nativesdk"
Signature · 1 line
2.40.0