Skip to contentSkip to conversation

libsoup: add ptest support

PATCH Superseded Pratik Farkase 2 participants 3 messages Oct 13 – Oct 14

v1 of 4 Superseded Latest is v4 →

lore
Share & tools
lore
#0 lore raw

PATCH 1/1 libsoup: add ptest support

Build the installed-tests via the meson tests/installed_tests options (enabled through a new 'tests' PACKAGECONFIG when ptest is in DISTRO_FEATURES) and run them under ptest with gnome-desktop-testing-runner.

Tested on qemux86-64 with ptest-runner: 36 tests, all pass.

---
 .../distro/include/ptest-packagelists.inc     |  1 +
 .../recipes-support/libsoup/libsoup/run-ptest |  3 +++
 meta/recipes-support/libsoup/libsoup_3.8.0.bb | 27 ++++++++++++++++---
 3 files changed, 27 insertions(+), 4 deletions(-)
 create mode 100644 meta/recipes-support/libsoup/libsoup/run-ptest
meta/conf/distro/include/ptest-packagelists.inc +1 -0
index 2bd11b1706..992d3666b9 100644
@@ -138,6 +138,7 @@ PTESTS_SLOW = "\
     libmodule-build-perl \
     libpcap \
     libpng \
+    libsoup \
     ${@bb.utils.contains('DISTRO_FEATURES', 'seccomp', 'libseccomp', '',d)} \
     lttng-tools \
     lz4 \
meta/recipes-support/libsoup/libsoup/run-ptest new file +3 -0
new file mode 100644
index 0000000000..efe975cf3f
@@ -0,0 +1,3 @@
+#! /bin/sh
+
+gnome-desktop-testing-runner libsoup-3.0
meta/recipes-support/libsoup/libsoup_3.8.0.bb +23 -4
index 2a40eecaea..3db4f0edb3 100644
@@ -9,20 +9,23 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2"
 
 DEPENDS = "glib-2.0 glib-2.0-native libxml2 sqlite3 libpsl nghttp2"
 
-inherit gettext gnomebase upstream-version-is-even gobject-introspection gi-docgen vala
+inherit gettext gnomebase upstream-version-is-even gobject-introspection gi-docgen vala ptest-gnome
 
 SRC_URI[archive.sha256sum] = "bbf08fa3e03a88c31a3d27a0d87cb422e9490f2d08e149211103df6d638a2238"
 
+SRC_URI += "file://run-ptest"
+
 PROVIDES = "libsoup-3.0"
 
 GIR_MESON_ENABLE_FLAG = 'enabled'
 GIR_MESON_DISABLE_FLAG = 'disabled'
 
-PACKAGECONFIG ??= ""
+PACKAGECONFIG ??= "${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
 PACKAGECONFIG[brotli] = "-Dbrotli=enabled,-Dbrotli=disabled,brotli"
 PACKAGECONFIG[gssapi] = "-Dgssapi=enabled,-Dgssapi=disabled,krb5"
 PACKAGECONFIG[ntlm] = "-Dntlm=enabled,-Dntlm=disabled"
 PACKAGECONFIG[sysprof] = "-Dsysprof=enabled,-Dsysprof=disabled,sysprof"
+PACKAGECONFIG[tests] = "-Dtests=true -Dinstalled_tests=true,-Dtests=false -Dinstalled_tests=false"
 
 # Tell libsoup where the target ntlm_auth is installed
 do_write_config:append:class-target() {
@@ -34,13 +37,25 @@ EOF
 EXTRA_OEMESON:append:class-target = " --cross-file ${WORKDIR}/soup.cross"
 
 EXTRA_OEMESON += "-Dtls_check=false"
-# Disable the test suites
-EXTRA_OEMESON += "-Dtests=false -Dautobahn=disabled -Dpkcs11_tests=disabled"
+# tests are controlled via the 'tests' PACKAGECONFIG (enabled for ptest)
+EXTRA_OEMESON += "-Dautobahn=disabled -Dpkcs11_tests=disabled"
 
 GIDOCGEN_MESON_OPTION = 'docs'
 GIDOCGEN_MESON_ENABLE_FLAG = 'enabled'
 GIDOCGEN_MESON_DISABLE_FLAG = 'disabled'
 
+# Exclude two tests that fail under ptest and leave the binaries in place:
+# - header-parsing-test aborts in do_param_list_tests(): a
+#   g_hash_table_size() assertion on a parsed parameter list does not hold
+#   (soup_header_parse_semi_param_list() returns one entry instead of three)
+#   with the current glib.
+# - logger-test's long-invalid-body-length case tries to allocate ~2 GiB and
+#   aborts under g_malloc() when the ptest machine lacks that much memory.
+do_install_ptest:append() {
+    rm -f ${D}${datadir}/installed-tests/libsoup-3.0/header-parsing-test.test
+    rm -f ${D}${datadir}/installed-tests/libsoup-3.0/logger-test.test
+}
+
 # When built without gnome support, libsoup will contain only one shared lib
 # and will therefore become subject to renaming by debian.bbclass. Prevent
 # renaming in order to keep the package name consistent regardless of whether
@@ -50,6 +65,10 @@ DEBIAN_NOAUTONAME:${PN} = "1"
 # glib-networking is needed for SSL, proxies, etc.
 RRECOMMENDS:${PN} = "glib-networking"
 
+# The TLS-based tests (ssl, server-auth, websocket, hsts) need a glib TLS
+# backend at runtime.
+RDEPENDS:${PN}-ptest += "glib-networking"
+
 BBCLASSEXTEND = "native nativesdk"
 
 CVE_STATUS[CVE-2026-1467] = "fixed-version: fixed in 3.6.6"
Signature · 1 line
2.43.0
#1 lore raw
Quoted 9 lines · Pratik Farkase

Build the installed-tests via the meson tests/installed_tests options (enabled through a new 'tests' PACKAGECONFIG when ptest is in DISTRO_FEATURES) and run them under ptest with gnome-desktop-testing-runner.

Tested on qemux86-64 with ptest-runner: 36 tests, all pass.

---

Hi Pratik,

Thanks for the rebase.

So not it looks like one of the tests is failing:

Failed ptests:
{'libsoup': ['libsoup-3.0/http2-body-stream-test.test']}

https://autobuilder.yoctoproject.org/valkyrie/#/builders/61/builds/4711
https://autobuilder.yoctoproject.org/valkyrie/#/builders/73/builds/4739
https://autobuilder.yoctoproject.org/valkyrie/#/builders/109/builds/1374
https://autobuilder.yoctoproject.org/valkyrie/#/builders/110/builds/1361

Can you have a look at the issue?

Thanks,
Mathieu

Signature · 3 lines
Mathieu Dubois-Briand, Bootlin
Embedded Linux and Kernel engineering
https://bootlin.com
#2 lore raw

Hi Mathieu,

Saw these failures, these are OOM's. Sent a v2 to allocate more memory.

Best Regards,
Pratik

________________________________________
From: Mathieu Dubois-Briand <[email protected]>
Sent: Tuesday, October 13, 2026 9:01 PM
To: Pratik Farkase; [email protected]
Cc: [email protected]
Subject: Re: [OE-core][PATCH] libsoup: add ptest support

Quoted 9 lines · Pratik Farkase

Build the installed-tests via the meson tests/installed_tests options (enabled through a new 'tests' PACKAGECONFIG when ptest is in DISTRO_FEATURES) and run them under ptest with gnome-desktop-testing-runner.

Tested on qemux86-64 with ptest-runner: 36 tests, all pass.

---

Hi Pratik,

Thanks for the rebase.

So not it looks like one of the tests is failing:

Failed ptests:
{'libsoup': ['libsoup-3.0/http2-body-stream-test.test']}

https://autobuilder.yoctoproject.org/valkyrie/#/builders/61/builds/4711
https://autobuilder.yoctoproject.org/valkyrie/#/builders/73/builds/4739
https://autobuilder.yoctoproject.org/valkyrie/#/builders/109/builds/1374
https://autobuilder.yoctoproject.org/valkyrie/#/builders/110/builds/1361

Can you have a look at the issue?

Thanks,
Mathieu

--
Mathieu Dubois-Briand, Bootlin
Embedded Linux and Kernel engineering
https://bootlin.com