Skip to contentSkip to conversation

powerpc: Add VDSO version of time

RFC PATCH In review Adhemerval Zanella 4 participants 11 messages Mar 19, 2013 – Apr 22, 2013 PowerPC

lore
Share & tools
lore
#0 lore raw

RFC PATCH 1/1 powerpc: Add VDSO version of time

Hi all,

This patch implement the time syscall as vDSO. I have a glibc patch to use it as IFUNC (as latest gettimeofday patch). Below the perf numbers:

Baseline PPC32: 380 nsec
Baseline PPC64: 352 nsec
vdso PPC32:      20 nsec
vdso PPC64:      20 nsec

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

Any tips, advices, comments?

--

arch/powerpc/kernel/vdso.c +4 -0
index 1b2076f..d4f463a 100644
@@ -113,6 +113,10 @@ static struct vdso_patch_def vdso_patches[] = {
 		CPU_FTR_USE_TB, 0,
 		"__kernel_get_tbfreq", NULL
 	},
+	{
+		CPU_FTR_USE_TB, 0,
+		"__kernel_time", NULL
+	},
 };
 
 /*
arch/powerpc/kernel/vdso32/gettimeofday.S +29 -0
index 4ee09ee..9a60a87 100644
@@ -181,6 +181,35 @@ V_FUNCTION_END(__kernel_clock_getres)
 
 
 /*
+ * Exact prototype of time()
+ *
+ * time_t time(time *t);
+ *
+ */
+V_FUNCTION_BEGIN(__kernel_time)
+  .cfi_startproc
+	mflr	r12
+  .cfi_register lr,r12
+
+	mr	r11,r3			/* r11 holds t */
+	bl	__get_datapage@local
+	mr	r9, r3			/* datapage ptr in r9 */
+
+1:	lwz	r8,(CFG_TB_UPDATE_COUNT+LOPART)(r9)
+	lwz	r3,STAMP_XTIME+TSPEC_TV_SEC(r9)
+	andi.	r0,r8,1			/* pending update ? loop */
+	bne-	1b
+
+	cmplwi	r11,0			/* check if t is NULL */
+	beq	2f
+	stw	r3,0(r11)		/* store result at *t */
+2:	mtlr	r12
+	crclr	cr0*4+so
+	blr
+  .cfi_endproc
+V_FUNCTION_END(__kernel_time)
+
+/*
  * This is the core of clock_gettime() and gettimeofday(),
  * it returns the current time in r3 (seconds) and r4.
  * On entry, r7 gives the resolution of r4, either USEC_PER_SEC
arch/powerpc/kernel/vdso32/vdso32.lds.S +1 -0
index 43200ba..f223409 100644
@@ -150,6 +150,7 @@ VERSION
 #ifdef CONFIG_PPC64
 		__kernel_getcpu;
 #endif
+		__kernel_time;
 
 	local: *;
 	};
arch/powerpc/kernel/vdso64/gettimeofday.S +29 -0
index e97a9a0..f05aa68 100644
@@ -164,6 +164,35 @@ V_FUNCTION_BEGIN(__kernel_clock_getres)
   .cfi_endproc
 V_FUNCTION_END(__kernel_clock_getres)
 
+/*
+ * Exact prototype of time()
+ *
+ * time_t time(time *t);
+ *
+ */
+V_FUNCTION_BEGIN(__kernel_time)
+  .cfi_startproc
+	mflr	r12
+  .cfi_register lr,r12
+
+	mr	r11,r3			/* r11 holds t */
+	bl	V_LOCAL_FUNC(__get_datapage)
+
+1:	ld	r8,CFG_TB_UPDATE_COUNT(r3)
+	ld	r4,STAMP_XTIME+TSPC64_TV_SEC(r3)
+	andi.	r0,r8,1			/* pending update ? loop */
+	bne-	1b
+
+	cmpldi	r11,0			/* check if t is NULL */
+	beq	2f
+	std	r4,0(r11)		/* store result at *t */
+2:	mtlr	r12
+	crclr	cr0*4+so
+	mr	r3,r4
+	blr
+  .cfi_endproc
+V_FUNCTION_END(__kernel_time)
+
 
 /*
  * This is the core of clock_gettime() and gettimeofday(),
arch/powerpc/kernel/vdso64/vdso64.lds.S +1 -0
index e6c1758..e486381 100644
@@ -147,6 +147,7 @@ VERSION
 		__kernel_sync_dicache_p5;
 		__kernel_sigtramp_rt64;
 		__kernel_getcpu;
+		__kernel_time;
 
 	local: *;
 	};
#1 lore raw
Quoted 3 lines · Adhemerval Zanella

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

You did provide both 32 and 64-bit VDSO implementations so 32-bit kernels should be covered.

Cheers,
Ben.

#2 lore raw
Quoted 5 lines · Benjamin Herrenschmidt
Quoted 2 lines · Adhemerval Zanella

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

You did provide both 32 and 64-bit VDSO implementations so 32-bit kernels should be covered.

Indeed and thanks for the reply. Any objection or request about including it?

Thanks.

#3 lore raw

Hi all,

Just sending a ping about this patch.

Quoted 15 lines · Adhemerval Zanella
Quoted 5 lines · Benjamin Herrenschmidt
Quoted 2 lines · Adhemerval Zanella

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

You did provide both 32 and 64-bit VDSO implementations so 32-bit kernels should be covered.

Indeed and thanks for the reply. Any objection or request about including it?

Thanks.

_______________________________________________
Linuxppc-dev mailing list
[email protected]
https://lists.ozlabs.org/listinfo/linuxppc-dev

#4 lore raw
In reply to Benjamin Herrenschmidt

Hi Benjamin,

Any objection or request about this patch?

Quoted 15 lines · Benjamin Herrenschmidt
Quoted 2 lines · Adhemerval Zanella

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

You did provide both 32 and 64-bit VDSO implementations so 32-bit kernels should be covered.

Cheers,
Ben.

_______________________________________________
Linuxppc-dev mailing list
[email protected]
https://lists.ozlabs.org/listinfo/linuxppc-dev

#5 lore raw
In reply to Adhemerval Zanella
Quoted 6 lines · Adhemerval Zanella

Hi all,

This patch implement the time syscall as vDSO. I have a glibc patch to use it as IFUNC (as latest gettimeofday patch). Below the perf numbers:

Quoted 7 lines
Baseline PPC32: 380 nsec
Baseline PPC64: 352 nsec
vdso PPC32:      20 nsec
vdso PPC64:      20 nsec

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

You did provide a 32-bit implementation. I take it you haven't tested that though? Can you test it?

What happens if I don't have the glibc patch?

cheers

#6 lore raw
Quoted 12 lines · Michael Ellerman
Quoted 11 lines · Adhemerval Zanella

Hi all,

This patch implement the time syscall as vDSO. I have a glibc patch to use it as IFUNC (as latest gettimeofday patch). Below the perf numbers:

Baseline PPC32: 380 nsec
Baseline PPC64: 352 nsec
vdso PPC32:      20 nsec
vdso PPC64:      20 nsec
Quoted 4 lines
Quoted 2 lines

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

You did provide a 32-bit implementation. I take it you haven't tested that though? Can you test it?

I haven't test it yet and I believe it won't be troublesome to do so.

Quoted 2 lines

What happens if I don't have the glibc patch?

GLIBC current behavior is to use the syscall.

Quoted 7 lines

cheers
_______________________________________________
Linuxppc-dev mailing list
[email protected]
https://lists.ozlabs.org/listinfo/linuxppc-dev

#7 lore raw
In reply to Michael Ellerman
Quoted 12 lines · Michael Ellerman
Quoted 11 lines · Adhemerval Zanella

Hi all,

This patch implement the time syscall as vDSO. I have a glibc patch to use it as IFUNC (as latest gettimeofday patch). Below the perf numbers:

Baseline PPC32: 380 nsec
Baseline PPC64: 352 nsec
vdso PPC32:      20 nsec
vdso PPC64:      20 nsec
Quoted 4 lines
Quoted 2 lines

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

You did provide a 32-bit implementation. I take it you haven't tested that though? Can you test it?

Hi,

I didn't build a 32 bit kernel, but I tested 32 bits binaries (that uses the VDSO32 implantation) without any issue. Performance gains are similar.

#8 lore raw
Quoted 15 lines · Adhemerval Zanella
Quoted 14 lines · Michael Ellerman
Quoted 13 lines · Adhemerval Zanella

Hi all,

This patch implement the time syscall as vDSO. I have a glibc patch to use it as IFUNC (as latest gettimeofday patch). Below the perf numbers:

Baseline PPC32: 380 nsec
Baseline PPC64: 352 nsec
vdso PPC32:      20 nsec
vdso PPC64:      20 nsec

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

Quoted 7 lines
Quoted 2 lines

You did provide a 32-bit implementation. I take it you haven't tested that though? Can you test it?

Hi,

I didn't build a 32 bit kernel, but I tested 32 bits binaries (that uses the VDSO32 implantation) without any issue. Performance gains are similar.

OK. Please send an updated version of the patch which a changelog describing the testing you've done, and add your Signed-off-by to the patch.

cheers

Acked-by on v1 1/1
#9 lore raw
In reply to Adhemerval Zanella

Hi Adhemerval,

Quoted 8 lines

This patch implement the time syscall as vDSO. I have a glibc patch to use it as IFUNC (as latest gettimeofday patch). Below the perf numbers:

Baseline PPC32: 380 nsec
Baseline PPC64: 352 nsec
vdso PPC32:      20 nsec
vdso PPC64:      20 nsec

Very nice speedup. One small performance improvement:

+1: ld r8,CFG_TB_UPDATE_COUNT(r3)
+ ld r4,STAMP_XTIME+TSPC64_TV_SEC(r3)
+ andi. r0,r8,1 /* pending update ? loop */
+ bne- 1b

Since you are only reading one long you shouldn't need to check the update count and loop, you will always see a consistent value. The system call version of time() just does an unprotected load for example.

Quoted 4 lines

I focused on 64 bit kernel, do I need to provide a scheme for 32 bits as well?

Any tips, advices, comments?

With the above change and with Michael's comments covered (decent changelog entry and Signed-off-by):

Anton

author Acked-by Anton Blanchard
#10 lore raw
Quoted 3 lines · Anton Blanchard

Since you are only reading one long you shouldn't need to check the update count and loop, you will always see a consistent value. The system call version of time() just does an unprotected load for example.

Fixed.

Quoted 4 lines

With the above change and with Michael's comments covered (decent changelog entry and Signed-off-by):

Thanks for the review, below the updated patch:

From: Adhemerval Zanella <[email protected]>

This patch implement the time syscall as vDSO. The performance speedups are:

Baseline PPC32: 380 nsec
Baseline PPC64: 350 nsec
vdso PPC32:      20 nsec
vsdo PPC64:      20 nsec

Tested on 64 bit build with both 32 bit and 64 bit userland.

---
 arch/powerpc/kernel/vdso.c                |    4 ++++
 arch/powerpc/kernel/vdso32/gettimeofday.S |   26 ++++++++++++++++++++++++++
 arch/powerpc/kernel/vdso32/vdso32.lds.S   |    1 +
 arch/powerpc/kernel/vdso64/gettimeofday.S |   26 ++++++++++++++++++++++++++
 arch/powerpc/kernel/vdso64/vdso64.lds.S   |    1 +
 5 files changed, 58 insertions(+), 0 deletions(-)
arch/powerpc/kernel/vdso.c +4 -0
index 1b2076f..d4f463a 100644
@@ -113,6 +113,10 @@ static struct vdso_patch_def vdso_patches[] = {
 		CPU_FTR_USE_TB, 0,
 		"__kernel_get_tbfreq", NULL
 	},
+	{
+		CPU_FTR_USE_TB, 0,
+		"__kernel_time", NULL
+	},
 };
 
 /*
arch/powerpc/kernel/vdso32/gettimeofday.S +26 -0
index 4ee09ee..27e2f62 100644
@@ -181,6 +181,32 @@ V_FUNCTION_END(__kernel_clock_getres)
 
 
 /*
+ * Exact prototype of time()
+ *
+ * time_t time(time *t);
+ *
+ */
+V_FUNCTION_BEGIN(__kernel_time)
+  .cfi_startproc
+	mflr	r12
+  .cfi_register lr,r12
+
+	mr	r11,r3			/* r11 holds t */
+	bl	__get_datapage@local
+	mr	r9, r3			/* datapage ptr in r9 */
+
+	lwz	r3,STAMP_XTIME+TSPEC_TV_SEC(r9)
+
+	cmplwi	r11,0			/* check if t is NULL */
+	beq	2f
+	stw	r3,0(r11)		/* store result at *t */
+2:	mtlr	r12
+	crclr	cr0*4+so
+	blr
+  .cfi_endproc
+V_FUNCTION_END(__kernel_time)
+
+/*
  * This is the core of clock_gettime() and gettimeofday(),
  * it returns the current time in r3 (seconds) and r4.
  * On entry, r7 gives the resolution of r4, either USEC_PER_SEC
arch/powerpc/kernel/vdso32/vdso32.lds.S +1 -0
index 43200ba..f223409 100644
@@ -150,6 +150,7 @@ VERSION
 #ifdef CONFIG_PPC64
 		__kernel_getcpu;
 #endif
+		__kernel_time;
 
 	local: *;
 	};
arch/powerpc/kernel/vdso64/gettimeofday.S +26 -0
index e97a9a0..a76b4af 100644
@@ -164,6 +164,32 @@ V_FUNCTION_BEGIN(__kernel_clock_getres)
   .cfi_endproc
 V_FUNCTION_END(__kernel_clock_getres)
 
+/*
+ * Exact prototype of time()
+ *
+ * time_t time(time *t);
+ *
+ */
+V_FUNCTION_BEGIN(__kernel_time)
+  .cfi_startproc
+	mflr	r12
+  .cfi_register lr,r12
+
+	mr	r11,r3			/* r11 holds t */
+	bl	V_LOCAL_FUNC(__get_datapage)
+
+	ld	r4,STAMP_XTIME+TSPC64_TV_SEC(r3)
+
+	cmpldi	r11,0			/* check if t is NULL */
+	beq	2f
+	std	r4,0(r11)		/* store result at *t */
+2:	mtlr	r12
+	crclr	cr0*4+so
+	mr	r3,r4
+	blr
+  .cfi_endproc
+V_FUNCTION_END(__kernel_time)
+
 
 /*
  * This is the core of clock_gettime() and gettimeofday(),
arch/powerpc/kernel/vdso64/vdso64.lds.S +1 -0
index e6c1758..e486381 100644
@@ -147,6 +147,7 @@ VERSION
 		__kernel_sync_dicache_p5;
 		__kernel_sigtramp_rt64;
 		__kernel_getcpu;
+		__kernel_time;
 
 	local: *;
 	};