Skip to contentSkip to conversation

sparc64: Optimize fls, fls64 and __fls

PATCH Superseded Vijay Kumar 4 participants 10 messages Sep 27, 2017

Subsystems (2)

v2 of 4 Superseded Latest is v4 →

lore
Share & tools
lore
#0 lore raw

v2 cover sparc64: Optimize fls, fls64 and __fls

SPARC provides lzcnt instruction (with VIS3) which can be used to optimize fls, fls64 and __fls functions. For the systems that supports lzcnt instruction, we now do boot time patching to use sparc optimized fls, fls64 and __fls functions.

v1->v2:
- Fixed delay slot issue pointed by Rob Gardner in patch 2/2.

Vijay Kumar (2):
sparc64: Define SPARC default fls and __fls
sparc64: Use lzcnt instruction for fls and __fls

 arch/sparc/Makefile                |    1 +
 arch/sparc/include/asm/bitops_64.h |    7 +-
 arch/sparc/kernel/head_64.S        |    2 +
 arch/sparc/lib/Makefile            |    4 +
 arch/sparc/lib/NG4fls.S            |   31 +++++++++
 arch/sparc/lib/NG4patch.S          |    9 +++
 arch/sparc/lib/fls.S               |  126 ++++++++++++++++++++++++++++++++++++
 7 files changed, 177 insertions(+), 3 deletions(-)
 create mode 100644 arch/sparc/lib/NG4fls.S
 create mode 100644 arch/sparc/lib/fls.S
#1 lore raw

PATCH v2 1/2 sparc64: Define SPARC default fls and __fls

fls and __fls will now require boot time patching on T4 and above. Redefining these functions under arc/sparc/lib.

---
 arch/sparc/include/asm/bitops_64.h |    7 +-
 arch/sparc/lib/Makefile            |    1 +
 arch/sparc/lib/fls.S               |  126 ++++++++++++++++++++++++++++++++++++
 3 files changed, 131 insertions(+), 3 deletions(-)
arch/sparc/include/asm/bitops_64.h +4 -3
index 2d52240..946c236 100644
@@ -22,11 +22,12 @@
 void clear_bit(unsigned long nr, volatile unsigned long *addr);
 void change_bit(unsigned long nr, volatile unsigned long *addr);
 
+#define fls64(word)  (((word)?(__fls(word) + 1):0))
+int fls(unsigned int word);
+int __fls(unsigned long word);
+
 #include <asm-generic/bitops/non-atomic.h>
 
-#include <asm-generic/bitops/fls.h>
-#include <asm-generic/bitops/__fls.h>
-#include <asm-generic/bitops/fls64.h>
 
 #ifdef __KERNEL__
 
arch/sparc/lib/Makefile +1 -0
index 07c03e7..eefbb9c 100644
@@ -16,6 +16,7 @@ lib-$(CONFIG_SPARC64) += atomic_64.o
 lib-$(CONFIG_SPARC32) += lshrdi3.o ashldi3.o
 lib-$(CONFIG_SPARC32) += muldi3.o bitext.o cmpdi2.o
 lib-$(CONFIG_SPARC64) += multi3.o
+lib-$(CONFIG_SPARC64) += fls.o
 
 lib-$(CONFIG_SPARC64) += copy_page.o clear_page.o bzero.o
 lib-$(CONFIG_SPARC64) += csum_copy.o csum_copy_from_user.o csum_copy_to_user.o
arch/sparc/lib/fls.S new file +126 -0

126 lines not on this page · raw message

Signature · 1 line
1.7.1
#2 lore raw

Re: [PATCH v2 1/2] sparc64: Define SPARC default fls and __fls

Hi Vijay.

Some feedback - see below.
The comment about ENTRY() ENDPROC() is also valid for patch 2/2

Sam

arch/sparc/include/asm/bitops_64.h line 25

Quoted 10 lines
arch/sparc/include/asm/bitops_64.h +1 -0
index 2d52240..946c236 100644
@@ -22,11 +22,12 @@
 void clear_bit(unsigned long nr, volatile unsigned long *addr);
 void change_bit(unsigned long nr, volatile unsigned long *addr);
 
+#define fls64(word)  (((word)?(__fls(word) + 1):0))

This macro could result in unwanted sideeffects.
If I use:

	fls64(i++)

for some obscure reason, then i will be incremented twice if i != 0. Using the asm-generic version would be better.

Quoted 43 lines
arch/sparc/include/asm/bitops_64.h +3 -3
+int fls(unsigned int word);
+int __fls(unsigned long word);
+
 #include <asm-generic/bitops/non-atomic.h>
 
-#include <asm-generic/bitops/fls.h>
-#include <asm-generic/bitops/__fls.h>
-#include <asm-generic/bitops/fls64.h>
 
 #ifdef __KERNEL__
 
arch/sparc/lib/Makefile +1 -0
index 07c03e7..eefbb9c 100644
@@ -16,6 +16,7 @@ lib-$(CONFIG_SPARC64) += atomic_64.o
 lib-$(CONFIG_SPARC32) += lshrdi3.o ashldi3.o
 lib-$(CONFIG_SPARC32) += muldi3.o bitext.o cmpdi2.o
 lib-$(CONFIG_SPARC64) += multi3.o
+lib-$(CONFIG_SPARC64) += fls.o
 
 lib-$(CONFIG_SPARC64) += copy_page.o clear_page.o bzero.o
 lib-$(CONFIG_SPARC64) += csum_copy.o csum_copy_from_user.o csum_copy_to_user.o
arch/sparc/lib/fls.S new file +14 -0
new file mode 100644
index 0000000..a19bff2
@@ -0,0 +1,126 @@
+/* fls.S: SPARC default fls and __fls definitions.
+ *
+ * SPARC default fls and __fls definitions, which follows the same
+ * algorithm as in generic fls() and __fls(). These functions will
+ * be boot time patched on T4 and onward.
+ */
+
+#include <asm/bitsperlong.h>
+#include <asm/export.h>
+
+	.text
+	.align	32
+
+	.global	fls, __fls

arch/sparc/lib/fls.S line 24

Quoted 10 lines
arch/sparc/lib/fls.S new file +10 -0
+	.type	fls,	#function
+	.type	__fls,	#function
+
+	.register	%g2, #scratch
+	.register	%g3, #scratch
+
+EXPORT_SYMBOL(__fls)
+EXPORT_SYMBOL(fls)
+
+fls:

Use ENTRY(), ENDPROC() for assembler functions.

Quoted 44 lines
arch/sparc/lib/fls.S new file +44 -0
+	brz,pn	%o0, 6f
+	 mov	0, %o1
+	sethi	%hi(0xffff0000), %g3
+	mov	%o0, %g2
+	andcc	%o0, %g3, %g0
+	be,pt	%icc, 8f
+	 mov	32, %o1
+	sethi	%hi(0xff000000), %g3
+	andcc	%g2, %g3, %g0
+	bne,pt	%icc, 3f
+	 sethi	%hi(0xf0000000), %g3
+	sll	%o0, 8, %o0
+1:
+	add	%o1, -8, %o1
+	sra	%o0, 0, %o0
+	mov	%o0, %g2
+2:
+	sethi	%hi(0xf0000000), %g3
+3:
+	andcc	%g2, %g3, %g0
+	bne,pt	%icc, 4f
+	 sethi	%hi(0xc0000000), %g3
+	sll	%o0, 4, %o0
+	add	%o1, -4, %o1
+	sra	%o0, 0, %o0
+	mov	%o0, %g2
+4:
+	andcc	%g2, %g3, %g0
+	be,a,pt	%icc, 7f
+	 sll	%o0, 2, %o0
+5:
+	xnor	%g0, %o0, %o0
+	srl	%o0, 31, %o0
+	sub	%o1, %o0, %o1
+6:
+	jmp	%o7 + 8
+	 sra	%o1, 0, %o0
+7:
+	add	%o1, -2, %o1
+	ba,pt	%xcc, 5b
+	 sra	%o0, 0, %o0
+8:
+	sll	%o0, 16, %o0
+	sethi	%hi(0xff000000), %g3

arch/sparc/lib/fls.S line 78

Quoted 10 lines
arch/sparc/lib/fls.S new file +10 -0
+	sra	%o0, 0, %o0
+	mov	%o0, %g2
+	andcc	%g2, %g3, %g0
+	bne,pt	%icc, 2b
+	 mov	16, %o1
+	ba,pt	%xcc, 1b
+	 sll	%o0, 8, %o0
+	.size	fls, .-fls
+
+__fls:

Same here, use ENTRY(), ENDPROC()

arch/sparc/lib/fls.S line 86

Quoted 8 lines
arch/sparc/lib/fls.S new file +8 -0
+#if BITS_PER_LONG = 64
+	mov	-1, %g2
+	sllx	%g2, 32, %g2
+	and	%o0, %g2, %g2
+	brnz,pt	%g2, 1f
+	 mov	63, %g1
+	sllx	%o0, 32, %o0
+#endif

Testign for BITS_PER_LONG seems not necessary as long as this is sparc64 only. And sparc32 has no optimized bit operations not even LEON
so this would not make sense in sparc32 land anyway.

arch/sparc/lib/fls.S line 90

Quoted 4 lines
arch/sparc/lib/fls.S new file +4 -0
+	mov	31, %g1
+1:
+	mov	-1, %g2
+	sllx	%g2, (BITS_PER_LONG-16), %g2

spaces around operators please. It is no excuse that the source did not have so.

Quoted 36 lines
arch/sparc/lib/fls.S new file +36 -0
+	and	%o0, %g2, %g2
+	brnz,pt	%g2, 2f
+	 mov	-1, %g2
+	sllx	%o0, 16, %o0
+	add	%g1, -16, %g1
+2:
+	mov	-1, %g2
+	sllx	%g2, (BITS_PER_LONG-8), %g2
+	and	%o0, %g2, %g2
+	brnz,pt	%g2, 3f
+	 mov	-1, %g2
+	sllx	%o0, 8, %o0
+	add	%g1, -8, %g1
+3:
+	sllx	%g2, (BITS_PER_LONG-4), %g2
+	and	%o0, %g2, %g2
+	brnz,pt	%g2, 4f
+	 mov	-1, %g2
+	sllx	%o0, 4, %o0
+	add	%g1, -4, %g1
+4:
+	sllx	%g2, (BITS_PER_LONG-2), %g2
+	and	%o0, %g2, %g2
+	brnz,pt	%g2, 5f
+	 mov	-1, %g3
+	sllx	%o0, 2, %o0
+	add	%g1, -2, %g1
+5:
+	mov	0, %g2
+	sllx	%g3, (BITS_PER_LONG-1), %g3
+	and	%o0, %g3, %o0
+	movre	%o0, 1, %g2
+	sub	%g1, %g2, %g1
+	jmp	%o7+8
+	 sra	%g1, 0, %o0
+	.size	__fls, .-__fls
#3 lore raw

Re: [PATCH v2 1/2] sparc64: Define SPARC default fls and __fls

Quoted 6 lines

arch/sparc/lib/fls.S line 24

Quoted 5 lines
arch/sparc/lib/fls.S new file +5 -0
+
+EXPORT_SYMBOL(__fls)
+EXPORT_SYMBOL(fls)
+
+fls:

Use ENTRY(), ENDPROC() for assembler functions.

And locate EXPORT_SYMBOL() right after ENDPROC().

Sam

#4 lore raw

PATCH v2 2/2 sparc64: Use lzcnt instruction for fls and __fls

In reply to Vijay Kumar

For T4 and above, patch fls and __fls functions
at the boot time to use lzcnt instruction.

---
 arch/sparc/Makefile         |    1 +
 arch/sparc/kernel/head_64.S |    2 ++
 arch/sparc/lib/Makefile     |    3 +++
 arch/sparc/lib/NG4fls.S     |   30 ++++++++++++++++++++++++++++++
 arch/sparc/lib/NG4patch.S   |    9 +++++++++
 5 files changed, 45 insertions(+), 0 deletions(-)
arch/sparc/Makefile +1 -0
index 8496a07..0763cd8 100644
@@ -48,6 +48,7 @@ KBUILD_CFLAGS += -ffixed-g4 -ffixed-g5 -fcall-used-g7 -Wno-sign-compare
 KBUILD_CFLAGS += -Wa,--undeclared-regs
 KBUILD_CFLAGS += $(call cc-option,-mtune=ultrasparc3)
 KBUILD_AFLAGS += -m64 -mcpu=ultrasparc -Wa,--undeclared-regs
+KBUILD_AFLAGS += -Wa,-Asparc4
 
 ifeq ($(CONFIG_MCOUNT),y)
   KBUILD_CFLAGS += -pg
arch/sparc/kernel/head_64.S +2 -0
index 78e0211..1165254 100644
@@ -628,6 +628,8 @@ niagara4_patch:
 	 nop
 	call	niagara4_patch_pageops
 	 nop
+	call	niagara4_patch_fls
+	 nop
 
 	ba,a,pt	%xcc, 80f
 	 nop
arch/sparc/lib/Makefile +3 -0
index eefbb9c..72d2d8c 100644
@@ -46,3 +46,6 @@ lib-$(CONFIG_SPARC64) += mcount.o ipcsum.o xor.o hweight.o ffs.o
 obj-$(CONFIG_SPARC64) += iomap.o
 obj-$(CONFIG_SPARC32) += atomic32.o ucmpdi2.o
 obj-$(CONFIG_SPARC64) += PeeCeeI.o
+
+obj-$(CONFIG_SPARC64) += fls.o
+obj-$(CONFIG_SPARC64) += NG4fls.o
arch/sparc/lib/NG4fls.S new file +30 -0
new file mode 100644
index 0000000..eb239aa
@@ -0,0 +1,30 @@
+/* NG4fls.S: SPARC optimized fls and __fls for T4 and above.
+ *
+ * Copyright (c) 2017, Oracle and/or its affiliates. All rights reserved.
+ */
+
+	.text
+	.align 32
+
+	.globl NG4fls
+	.globl __NG4fls
+	.type  NG4fls, #function
+	.type  __NG4fls, #function
+
+NG4fls:
+	lzcnt   %o0, %o1
+	mov     64, %o2
+	retl
+	 sub     %o2, %o1, %o0
+	.size   NG4fls, .-NG4fls
+
+__NG4fls:
+	brz,pn  %o0, 1f
+        mov	%o0, %o1
+	lzcnt	%o1, %o0
+	mov     63, %o2
+	sub     %o2, %o0, %o0
+1:
+	retl
+	 nop
+	.size   __NG4fls, .-__NG4fls
arch/sparc/lib/NG4patch.S +9 -0
index 3cc0f8c..1010d53 100644
@@ -52,3 +52,12 @@ niagara4_patch_pageops:
 	retl
 	 nop
 	.size	niagara4_patch_pageops,.-niagara4_patch_pageops
+
+	.globl	niagara4_patch_fls
+	.type	niagara4_patch_fls,#function
+niagara4_patch_fls:
+	NG_DO_PATCH(fls, NG4fls)
+	NG_DO_PATCH(__fls, __NG4fls)
+	retl
+	 nop
+	.size	niagara4_patch_fls,.-niagara4_patch_fls
Signature · 1 line
1.7.1
#5 lore raw

Re: [PATCH v2 2/2] sparc64: Use lzcnt instruction for fls and __fls

Hi Vijay.

Quoted 18 lines · Vijay Kumar

For T4 and above, patch fls and __fls functions
at the boot time to use lzcnt instruction.

---
 arch/sparc/Makefile         |    1 +
 arch/sparc/kernel/head_64.S |    2 ++
 arch/sparc/lib/Makefile     |    3 +++
 arch/sparc/lib/NG4fls.S     |   30 ++++++++++++++++++++++++++++++
 arch/sparc/lib/NG4patch.S   |    9 +++++++++
 5 files changed, 45 insertions(+), 0 deletions(-)
arch/sparc/Makefile +0 -0
index 8496a07..0763cd8 100644

arch/sparc/Makefile KBUILD_CFLAGS += -ffixed-g4 -ffixed-g5 -fcall-used-g7 -Wno-sign-compare · line 51

Quoted 4 lines
arch/sparc/Makefile +1 -0
@@ -48,6 +48,7 @@ KBUILD_CFLAGS += -ffixed-g4 -ffixed-g5 -fcall-used-g7 -Wno-sign-compare
 KBUILD_CFLAGS += -Wa,--undeclared-regs
 KBUILD_CFLAGS += $(call cc-option,-mtune=ultrasparc3)
 KBUILD_AFLAGS += -m64 -mcpu=ultrasparc -Wa,--undeclared-regs
+KBUILD_AFLAGS += -Wa,-Asparc4

This change is not justified anywhere??

Quoted 35 lines
arch/sparc/Makefile +0 -0
 ifeq ($(CONFIG_MCOUNT),y)
   KBUILD_CFLAGS += -pg
arch/sparc/kernel/head_64.S +2 -0
index 78e0211..1165254 100644
@@ -628,6 +628,8 @@ niagara4_patch:
 	 nop
 	call	niagara4_patch_pageops
 	 nop
+	call	niagara4_patch_fls
+	 nop
 
 	ba,a,pt	%xcc, 80f
 	 nop
arch/sparc/lib/Makefile +3 -0
index eefbb9c..72d2d8c 100644
@@ -46,3 +46,6 @@ lib-$(CONFIG_SPARC64) += mcount.o ipcsum.o xor.o hweight.o ffs.o
 obj-$(CONFIG_SPARC64) += iomap.o
 obj-$(CONFIG_SPARC32) += atomic32.o ucmpdi2.o
 obj-$(CONFIG_SPARC64) += PeeCeeI.o
+
+obj-$(CONFIG_SPARC64) += fls.o
+obj-$(CONFIG_SPARC64) += NG4fls.o
arch/sparc/lib/NG4fls.S new file +2 -0
new file mode 100644
index 0000000..eb239aa
@@ -0,0 +1,30 @@
+/* NG4fls.S: SPARC optimized fls and __fls for T4 and above.
+ *

arch/sparc/lib/NG4fls.S line 12

Quoted 10 lines
arch/sparc/lib/NG4fls.S new file +10 -0
+ * Copyright (c) 2017, Oracle and/or its affiliates. All rights reserved.
+ */
+
+	.text
+	.align 32
+
+	.globl NG4fls
+	.globl __NG4fls
+	.type  NG4fls, #function
+	.type  __NG4fls, #function

Use ENTRY(), ENDPROC() as already mentioned.

arch/sparc/lib/NG4fls.S line 23

Quoted 10 lines
arch/sparc/lib/NG4fls.S new file +10 -0
+NG4fls:
+	lzcnt   %o0, %o1
+	mov     64, %o2
+	retl
+	 sub     %o2, %o1, %o0
+	.size   NG4fls, .-NG4fls
+
+__NG4fls:
+	brz,pn  %o0, 1f
+        mov	%o0, %o1

Use tabs for indent, not spaces. In this case one tab + one space.

Quoted 14 lines
arch/sparc/lib/NG4fls.S new file +7 -0
+	lzcnt	%o1, %o0
+	mov     63, %o2
+	sub     %o2, %o0, %o0
+1:
+	retl
+	 nop
+	.size   __NG4fls, .-__NG4fls
arch/sparc/lib/NG4patch.S +0 -0
index 3cc0f8c..1010d53 100644
@@ -52,3 +52,12 @@ niagara4_patch_pageops:
 	retl
 	 nop

arch/sparc/lib/NG4patch.S niagara4_patch_pageops: · line 63

Quoted 10 lines
arch/sparc/lib/NG4patch.S +9 -0
 	.size	niagara4_patch_pageops,.-niagara4_patch_pageops
+
+	.globl	niagara4_patch_fls
+	.type	niagara4_patch_fls,#function
+niagara4_patch_fls:
+	NG_DO_PATCH(fls, NG4fls)
+	NG_DO_PATCH(__fls, __NG4fls)
+	retl
+	 nop
+	.size	niagara4_patch_fls,.-niagara4_patch_fls

Please path the remaining functions in this file with ENTRY(), ENDPROC() - in a separate patch.

Sam

#6 lore raw

Re: [PATCH v2 2/2] sparc64: Use lzcnt instruction for fls and __fls

Hi Sam,

Quoted 11 lines · Sam Ravnborg

arch/sparc/lib/NG4patch.S niagara4_patch_pageops: · line 63

Quoted 10 lines

.size niagara4_patch_pageops,.-niagara4_patch_pageops

arch/sparc/lib/NG4patch.S +9 -0
+
+	.globl	niagara4_patch_fls
+	.type	niagara4_patch_fls,#function
+niagara4_patch_fls:
+	NG_DO_PATCH(fls, NG4fls)
+	NG_DO_PATCH(__fls, __NG4fls)
+	retl
+	 nop
+	.size	niagara4_patch_fls,.-niagara4_patch_fls

Please path the remaining functions in this file with ENTRY(), ENDPROC() - in a separate patch.

Thanks for your comment. Sure, I will make the changes and address other comments as well in my revised version.

- Vijay

maintainer
#7 lore raw

Re: [PATCH v2 2/2] sparc64: Use lzcnt instruction for fls and __fls

In reply to Sam Ravnborg

From: Sam Ravnborg <[email protected]>
Date: Wed, 27 Sep 2017 21:56:37 +0200

Quoted 16 lines

Hi Vijay.

Quoted 13 lines · Vijay Kumar

For T4 and above, patch fls and __fls functions
at the boot time to use lzcnt instruction.

---
 arch/sparc/Makefile         |    1 +
 arch/sparc/kernel/head_64.S |    2 ++
 arch/sparc/lib/Makefile     |    3 +++
 arch/sparc/lib/NG4fls.S     |   30 ++++++++++++++++++++++++++++++
 arch/sparc/lib/NG4patch.S   |    9 +++++++++
 5 files changed, 45 insertions(+), 0 deletions(-)
Quoted 10 lines

arch/sparc/Makefile KBUILD_CFLAGS += -ffixed-g4 -ffixed-g5 -fcall-used-g7 -Wno-sign-compare · line 51

Quoted 9 lines
arch/sparc/Makefile +1 -0
index 8496a07..0763cd8 100644
@@ -48,6 +48,7 @@ KBUILD_CFLAGS += -ffixed-g4 -ffixed-g5 -fcall-used-g7 -Wno-sign-compare
 KBUILD_CFLAGS += -Wa,--undeclared-regs
 KBUILD_CFLAGS += $(call cc-option,-mtune=ultrasparc3)
 KBUILD_AFLAGS += -m64 -mcpu=ultrasparc -Wa,--undeclared-regs
+KBUILD_AFLAGS += -Wa,-Asparc4

This change is not justified anywhere??

It also will likely break with older tools.

#8 lore raw

Re: [PATCH v2 2/2] sparc64: Use lzcnt instruction for fls and __fls

In reply to Sam Ravnborg
Quoted 19 lines · Sam Ravnborg

Hi Vijay.

Quoted 13 lines · Vijay Kumar

For T4 and above, patch fls and __fls functions
at the boot time to use lzcnt instruction.

---

arch/sparc/Makefile         |    1 +
arch/sparc/kernel/head_64.S |    2 ++
arch/sparc/lib/Makefile     |    3 +++
arch/sparc/lib/NG4fls.S     |   30 ++++++++++++++++++++++++++++++
arch/sparc/lib/NG4patch.S   |    9 +++++++++
5 files changed, 45 insertions(+), 0 deletions(-)
Quoted 10 lines
Quoted 9 lines
arch/sparc/Makefile +0 -0
index 8496a07..0763cd8 100644
@@ -48,6 +48,7 @@ KBUILD_CFLAGS += -ffixed-g4 -ffixed-g5 -fcall-used-g7 -Wno-sign-compare

KBUILD_CFLAGS += -Wa,--undeclared-regs KBUILD_CFLAGS += $(call cc-option,-mtune=ultrasparc3) KBUILD_AFLAGS += -m64 -mcpu=ultrasparc -Wa,--undeclared-regs +KBUILD_AFLAGS += -Wa,-Asparc4

This change is not justified anywhere??

It looks like this is to get the assembler to recognize the lzcnt instruction.

Vijay,
Older assemblers may not support this flag so you’ll need to hardcode the lzcnt instructions using .word directives.

Anthony

Quoted 92 lines
Quoted 36 lines

ifeq ($(CONFIG_MCOUNT),y)
KBUILD_CFLAGS += -pg

arch/sparc/kernel/head_64.S +2 -0
index 78e0211..1165254 100644
@@ -628,6 +628,8 @@ niagara4_patch:
 	 nop
 	call	niagara4_patch_pageops
 	 nop
+	call	niagara4_patch_fls
+	 nop
 
 	ba,a,pt	%xcc, 80f
 	 nop
arch/sparc/lib/Makefile +0 -0
index eefbb9c..72d2d8c 100644
@@ -46,3 +46,6 @@ lib-$(CONFIG_SPARC64) += mcount.o ipcsum.o xor.o hweight.o ffs.o

obj-$(CONFIG_SPARC64) += iomap.o
obj-$(CONFIG_SPARC32) += atomic32.o ucmpdi2.o
obj-$(CONFIG_SPARC64) += PeeCeeI.o

arch/sparc/lib/Makefile +3 -0
+
+obj-$(CONFIG_SPARC64) += fls.o
+obj-$(CONFIG_SPARC64) += NG4fls.o
arch/sparc/lib/NG4fls.S new file +2 -0
new file mode 100644
index 0000000..eb239aa
@@ -0,0 +1,30 @@
+/* NG4fls.S: SPARC optimized fls and __fls for T4 and above.
+ *

arch/sparc/lib/NG4fls.S line 12

Quoted 10 lines
arch/sparc/lib/NG4fls.S new file +10 -0
+ * Copyright (c) 2017, Oracle and/or its affiliates. All rights reserved.
+ */
+
+	.text
+	.align 32
+
+	.globl NG4fls
+	.globl __NG4fls
+	.type  NG4fls, #function
+	.type  __NG4fls, #function

Use ENTRY(), ENDPROC() as already mentioned.

arch/sparc/lib/NG4fls.S line 23

Quoted 10 lines
arch/sparc/lib/NG4fls.S new file +10 -0
+NG4fls:
+	lzcnt   %o0, %o1
+	mov     64, %o2
+	retl
+	 sub     %o2, %o1, %o0
+	.size   NG4fls, .-NG4fls
+
+__NG4fls:
+	brz,pn  %o0, 1f
+        mov	%o0, %o1

Use tabs for indent, not spaces. In this case one tab + one space.

Quoted 14 lines
arch/sparc/lib/NG4fls.S new file +7 -0
+	lzcnt	%o1, %o0
+	mov     63, %o2
+	sub     %o2, %o0, %o0
+1:
+	retl
+	 nop
+	.size   __NG4fls, .-__NG4fls
arch/sparc/lib/NG4patch.S +0 -0
index 3cc0f8c..1010d53 100644
@@ -52,3 +52,12 @@ niagara4_patch_pageops:
 	retl
 	 nop

arch/sparc/lib/NG4patch.S niagara4_patch_pageops: · line 63

Quoted 10 lines
arch/sparc/lib/NG4patch.S +9 -0
 	.size	niagara4_patch_pageops,.-niagara4_patch_pageops
+
+	.globl	niagara4_patch_fls
+	.type	niagara4_patch_fls,#function
+niagara4_patch_fls:
+	NG_DO_PATCH(fls, NG4fls)
+	NG_DO_PATCH(__fls, __NG4fls)
+	retl
+	 nop
+	.size	niagara4_patch_fls,.-niagara4_patch_fls

Please path the remaining functions in this file with ENTRY(), ENDPROC() - in a separate patch.

Sam
--
To unsubscribe from this list: send the line "unsubscribe sparclinux" in the body of a message to [email protected]
More majordomo info at http://vger.kernel.org/majordomo-info.html

maintainer
#9 lore raw

Re: [PATCH v2 2/2] sparc64: Use lzcnt instruction for fls and __fls

RnJvbTogQW50aG9ueSBZem5hZ2EgPGFudGhvbnkueXpuYWdhQG9yYWNsZS5jb20+DQpEYXRlOiBX ZWQsIDI3IFNlcCAyMDE3IDE0OjQ1OjM0IC0wNzAwDQoNCj4gVmlqYXksDQo+IE9sZGVyIGFzc2Vt YmxlcnMgbWF5IG5vdCBzdXBwb3J0IHRoaXMgZmxhZyBzbyB5b3WibGwgbmVlZCB0bw0KPiBoYXJk Y29kZSB0aGUgbHpjbnQgaW5zdHJ1Y3Rpb25zIHVzaW5nIC53b3JkIGRpcmVjdGl2ZXMuDQoNClJp Z2h0LCBvbGRlciBiaW51dGlscyBkbyBub3Qgc3VwcG9ydCB0aGUgVDQgaW5zdHJ1Y3Rpb25zLg0K DQpUaGlzIGlzIHdoeSB3ZSBoYXJkY29kZSB0aGUgb3Bjb2RlcyBmb3IgYWxsIG9mIHRoZSBjcnlw dG8NCmluc3RydWN0aW9ucyB1c2VkIHVuZGVyIGFyY2gvc3BhcmM2NC9jcnlwdG8vLCBmb3IgZXhh bXBsZS4NCg0K